vector_series.f90

Go to the documentation of this file.

! Copyright (c) 2021-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module vector_series
  use num_types, only : rp
  use vector, only : vector_t
  implicit none
  private
 
  type, public :: vector_series_t
     type(vector_t), pointer :: v => null()
     type(vector_t), allocatable :: lv(:)
     integer, private :: len = 0
     integer, private :: n_filled = 0
   contains
     procedure, pass(this) :: init => vector_series_init
     procedure, pass(this) :: free => vector_series_free
     procedure, pass(this) :: update => vector_series_update
     procedure, pass(this) :: set => vector_series_set
     procedure, pass(this) :: reset => vector_series_reset
     procedure, pass(this) :: size => vector_series_size
     procedure, pass(this) :: filled_size => vector_series_filled_size
  end type vector_series_t
 
  type, public :: vector_series_ptr_t
     type(vector_series_t), pointer :: ptr => null()
  end type vector_series_ptr_t
 
contains
 
  subroutine vector_series_init(this, v, len)
    class(vector_series_t), intent(inout) :: this
    type(vector_t), intent(inout), target :: v
    integer :: len
    character(len=80) :: name
    character(len=5) :: id_str
    integer :: i
 
    call this%free()
 
    this%v => v
    this%len = len
    this%n_filled = 0
 
    allocate(this%lv(len))
 
    do i = 1, this%len
       write(id_str, '(I0)') i
       name = trim(this%v%name)//'_lag'//id_str
       call this%lv(i)%init(this%v%size(), name)
    end do
 
  end subroutine vector_series_init
 
  subroutine vector_series_free(this)
    class(vector_series_t), intent(inout) :: this
    integer :: i
 
    if (associated(this%v)) then
       nullify(this%v)
    end if
 
 
    if (allocated(this%lv)) then
       do i = 1, this%len
          call this%lv(i)%free()
       end do
 
       deallocate(this%lv)
    end if
 
    this%len = 0
    this%n_filled = 0
 
  end subroutine vector_series_free
 
  function vector_series_size(this) result(len)
    class(vector_series_t), intent(in) :: this
    integer :: len
    len = this%len
  end function vector_series_size
 
  function vector_series_filled_size(this) result(n_filled)
    class(vector_series_t), intent(in) :: this
    integer :: n_filled
 
    n_filled = this%n_filled
  end function vector_series_filled_size
 
  subroutine vector_series_update(this)
    class(vector_series_t), intent(inout) :: this
    integer :: i
 
    do i = this%len, 2, -1
       this%lv(i) = this%lv(i-1)
    end do
 
    this%lv(1) = this%v
    this%n_filled = min(this%n_filled + 1, this%len)
 
  end subroutine vector_series_update
 
  subroutine vector_series_set(this, g)
    class(vector_series_t), intent(inout) :: this
    type(vector_t), intent(in) :: g
    integer :: i
 
    do i = 1, this%len
       this%lv(i) = g
    end do
 
    this%n_filled = this%len
 
  end subroutine vector_series_set
 
  subroutine vector_series_reset(this)
    class(vector_series_t), intent(inout) :: this
    integer :: i
 
    do i = 1, this%len
       this%lv(i) = 0.0_rp
    end do
 
    this%n_filled = 0
  end subroutine vector_series_reset
 
end module vector_series