cai_sagaut_model_ii_kernel.h

Go to the documentation of this file.

#ifndef CAI_SAGAUT_MODEL_II_KERNEL_H
#define CAI_SAGAUT_MODEL_II_KERNEL_H
 
/*
 Copyright (c) 2026, The Neko Authors
 All rights reserved.
 
 Redistribution and use in source and binary forms, with or without
 modification, are permitted provided that the following conditions
 are met:
 
   * Redistributions of source code must retain the above copyright
     notice, this list of conditions and the following disclaimer.
 
   * Redistributions in binary form must reproduce the above
     copyright notice, this list of conditions and the following
     disclaimer in the documentation and/or other materials provided
     with the distribution.
 
   * Neither the name of the authors nor the names of its
     contributors may be used to endorse or promote products derived
     from this software without specific prior written permission.
 
 THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
 COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
 BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
 CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
 ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
 POSSIBILITY OF SUCH DAMAGE.
*/
 
#include <cfloat>
#include <algorithm>
#include <cmath>
 
template<typename T>
__global__ void cai_sagaut_model_ii_compute(const T * __restrict__ u_d,
                                           const T * __restrict__ v_d,
                                           const T * __restrict__ w_d,
                                           const int * __restrict__ ind_r_d,
                                           const int * __restrict__ ind_s_d,
                                           const int * __restrict__ ind_t_d,
                                           const int * __restrict__ ind_e_d,
                                           const T * __restrict__ n_x_d,
                                           const T * __restrict__ n_y_d,
                                           const T * __restrict__ n_z_d,
                                           const T * __restrict__ nu_d,
                                           const T * __restrict__ rho_w_d,
                                           const T * __restrict__ h_d,
                                           T * __restrict__ tau_x_d,
                                           T * __restrict__ tau_y_d,
                                           T * __restrict__ tau_z_d,
                                           const int n_nodes,
                                           const int lx,
                                           const T kappa,
                                           const T B,
                                           const T p,
                                           const T s) {
  const int idx = blockIdx.x * blockDim.x + threadIdx.x;
  const int str = blockDim.x * gridDim.x;
  const T one = static_cast<T>(1.0);
  const T eps = (sizeof(T) == sizeof(float)) ?
    static_cast<T>(FLT_EPSILON) :
    static_cast<T>(DBL_EPSILON);
  const T e_const = exp(kappa * B);
 
  for (int i = idx; i < n_nodes; i += str) {
    const int index = (ind_e_d[i] - 1) * lx * lx * lx +
      (ind_t_d[i] - 1) * lx * lx +
      (ind_s_d[i] - 1) * lx +
      (ind_r_d[i] - 1);
 
    T ui = u_d[index];
    T vi = v_d[index];
    T wi = w_d[index];
    const T rho = rho_w_d[i];
    const T nx = n_x_d[i];
    const T ny = n_y_d[i];
    const T nz = n_z_d[i];
 
    const T normu = ui * nx + vi * ny + wi * nz;
    ui -= normu * nx;
    vi -= normu * ny;
    wi -= normu * nz;
 
    const T magu = sqrt(ui * ui + vi * vi + wi * wi);
 
    if (magu < eps) {
      tau_x_d[i] = static_cast<T>(0.0);
      tau_y_d[i] = static_cast<T>(0.0);
      tau_z_d[i] = static_cast<T>(0.0);
      continue;
    }
 
    const T rey = magu * h_d[i] / nu_d[i];
    const T blend = exp(-pow(rey / s, p));
    const T warg = kappa * e_const * rey;
    const T a = one /
      (one + static_cast<T>(0.5) * log(one + warg));
    T wlam = log(one + a * warg);
    wlam = wlam / (one + wlam) * (one + log(warg / wlam));
    const T up = blend * sqrt(rey) +
      (one - blend) * wlam / kappa;
    const T utau = magu / (up + eps);
 
    tau_x_d[i] = -rho * utau * utau * ui / (magu + eps);
    tau_y_d[i] = -rho * utau * utau * vi / (magu + eps);
    tau_z_d[i] = -rho * utau * utau * wi / (magu + eps);
  }
}
 
#endif