entropy_viscosity_cpu.f90

Go to the documentation of this file.

! Copyright (c) 2025, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module entropy_viscosity_cpu
  use num_types, only : rp
  implicit none
  private
 
  public :: entropy_viscosity_compute_residual_cpu, &
       entropy_viscosity_compute_viscosity_cpu, &
       entropy_viscosity_apply_element_max_cpu, &
       entropy_viscosity_clamp_to_low_order_cpu, &
       entropy_viscosity_smooth_divide_cpu
 
contains
 
  subroutine entropy_viscosity_compute_residual_cpu(entropy_residual, &
       S, S_lag1, S_lag2, S_lag3, bdf_coeffs, dt, n)
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(out) :: entropy_residual
    real(kind=rp), dimension(n), intent(in) :: s, s_lag1, s_lag2, s_lag3
    real(kind=rp), intent(in) :: bdf_coeffs(4)
    real(kind=rp), intent(in) :: dt
    integer :: i
 
    !OCL NORECURRENCE, NOVREC, NOALIAS
    !DIR$ CONCURRENT
    !DIR$ IVDEP
    !GCC$ ivdep
    !$omp parallel do simd
    do i = 1, n
       entropy_residual(i) = (bdf_coeffs(1) * s(i) &
            - bdf_coeffs(2) * s_lag1(i) &
            - bdf_coeffs(3) * s_lag2(i) &
            - bdf_coeffs(4) * s_lag3(i)) / dt
    end do
    !$omp end parallel do simd
 
  end subroutine entropy_viscosity_compute_residual_cpu
 
  subroutine entropy_viscosity_compute_viscosity_cpu(reg_coeff, &
       entropy_residual, h, c_avisc_entropy, n_S, n)
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(out) :: reg_coeff
    real(kind=rp), dimension(n), intent(in) :: entropy_residual, h
    real(kind=rp), intent(in) :: c_avisc_entropy, n_s
    integer :: i
 
    !OCL NORECURRENCE, NOVREC, NOALIAS
    !DIR$ CONCURRENT
    !DIR$ IVDEP
    !GCC$ ivdep
    !$omp parallel do simd
    do i = 1, n
       reg_coeff(i) = c_avisc_entropy * h(i) * h(i) * &
            entropy_residual(i) / n_s
    end do
    !$omp end parallel do simd
 
  end subroutine entropy_viscosity_compute_viscosity_cpu
 
  subroutine entropy_viscosity_apply_element_max_cpu(reg_coeff, lx, nelv)
    integer, intent(in) :: lx, nelv
    real(kind=rp), dimension(lx, lx, lx, nelv), intent(inout) :: reg_coeff
    integer :: i, j, k, el
    real(kind=rp) :: max_visc_el
 
    !$omp parallel do private(i, j, k, max_visc_el)
    do el = 1, nelv
       max_visc_el = 0.0_rp
 
       do k = 1, lx
          do j = 1, lx
             !OCL NORECURRENCE, NOVREC, NOALIAS
             !DIR$ CONCURRENT
             !DIR$ IVDEP
             !GCC$ ivdep
             !$omp simd reduction(max:max_visc_el)
             do i = 1, lx
                max_visc_el = max(max_visc_el, reg_coeff(i, j, k, el))
             end do
          end do
       end do
 
       do k = 1, lx
          do j = 1, lx
             !OCL NORECURRENCE, NOVREC, NOALIAS
             !DIR$ CONCURRENT
             !DIR$ IVDEP
             !GCC$ ivdep
             !$omp simd
             do i = 1, lx
                reg_coeff(i, j, k, el) = max_visc_el
             end do
          end do
       end do
    end do
    !$omp end parallel do
 
  end subroutine entropy_viscosity_apply_element_max_cpu
 
  subroutine entropy_viscosity_clamp_to_low_order_cpu(reg_coeff, &
       h, max_wave_speed, c_avisc_low, n)
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(inout) :: reg_coeff
    real(kind=rp), dimension(n), intent(in) :: h, max_wave_speed
    real(kind=rp), intent(in) :: c_avisc_low
    integer :: i
    real(kind=rp) :: low_order_visc
 
    !OCL NORECURRENCE, NOVREC, NOALIAS
    !DIR$ CONCURRENT
    !DIR$ IVDEP
    !GCC$ ivdep
    !$omp parallel do simd private(low_order_visc)
    do i = 1, n
       low_order_visc = c_avisc_low * h(i) * max_wave_speed(i)
       reg_coeff(i) = min(reg_coeff(i), low_order_visc)
    end do
    !$omp end parallel do simd
 
  end subroutine entropy_viscosity_clamp_to_low_order_cpu
 
  subroutine entropy_viscosity_smooth_divide_cpu(reg_coeff, &
       temp_field, mult_field, n)
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(out) :: reg_coeff
    real(kind=rp), dimension(n), intent(in) :: temp_field, mult_field
    integer :: i
 
    !OCL NORECURRENCE, NOVREC, NOALIAS
    !DIR$ CONCURRENT
    !DIR$ IVDEP
    !GCC$ ivdep
    !$omp parallel do simd
    do i = 1, n
       reg_coeff(i) = temp_field(i) / mult_field(i)
    end do
    !$omp end parallel do simd
 
  end subroutine entropy_viscosity_smooth_divide_cpu
 
end module entropy_viscosity_cpu