fusedcg_aux.cu

Go to the documentation of this file.

/*
 Copyright (c) 2021-2025, The Neko Authors
 All rights reserved.
 
 Redistribution and use in source and binary forms, with or without
 modification, are permitted provided that the following conditions
 are met:
 
   * Redistributions of source code must retain the above copyright
     notice, this list of conditions and the following disclaimer.
 
   * Redistributions in binary form must reproduce the above
     copyright notice, this list of conditions and the following
     disclaimer in the documentation and/or other materials provided
     with the distribution.
 
   * Neither the name of the authors nor the names of its
     contributors may be used to endorse or promote products derived
     from this software without specific prior written permission.
 
 THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
 COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
 BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
 CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
 ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
 POSSIBILITY OF SUCH DAMAGE.
*/
 
#include "fusedcg_kernel.h"
#include <device/device_config.h>
#include <device/cuda/check.h>
#include <device/cuda/buffer.h>
 
#ifdef HAVE_NVSHMEM
#include <nvshmem.h>
#include <nvshmemx.h>
#endif
 
cuda_buffer_t fusedcg_redbuf = CUDA_BUFFER_INIT_SYMM;
 
extern "C" {
 
#include <math/bcknd/device/device_mpi_reduce.h>
#include <math/bcknd/device/device_mpi_op.h>
 
#ifdef HAVE_NCCL
#include <math/bcknd/device/device_nccl_reduce.h>
#include <math/bcknd/device/device_nccl_op.h>
#endif
 
  void cuda_fusedcg_update_p(void *p, void *z, void *po, real *beta, int *n) {
 
    const dim3 nthrds(1024, 1, 1);
    const dim3 nblcks(((*n)+1024 - 1)/ 1024, 1, 1);
    const cudaStream_t stream = (cudaStream_t) glb_cmd_queue;
 
    fusedcg_update_p_kernel<real>
      <<<nblcks, nthrds, 0, stream>>>((real *) p, (real *) z,
                                      (real *) po, *beta, *n);
    CUDA_CHECK(cudaGetLastError());
 
  }
 
  void cuda_fusedcg_update_x(void *x, void *p, void *alpha, int *p_cur, int *n) {
 
    const dim3 nthrds(1024, 1, 1);
    const dim3 nblcks(((*n)+1024 - 1)/ 1024, 1, 1);
    const cudaStream_t stream = (cudaStream_t) glb_cmd_queue;
 
    fusedcg_update_x_kernel<real>
      <<<nblcks, nthrds, 0, stream>>>((real *) x, (const real **) p,
                                      (const real *) alpha, *p_cur, *n);
    CUDA_CHECK(cudaGetLastError());
  }
 
 
  real cuda_fusedcg_part2(void *a, void *b, void *c,
                          void *alpha_d , real *alpha, int *p_cur, int * n) {
 
    const dim3 nthrds(1024, 1, 1);
    const dim3 nblcks(((*n)+1024 - 1)/ 1024, 1, 1);
    const int nb = ((*n) + 1024 - 1)/ 1024;
    const cudaStream_t stream = (cudaStream_t) glb_cmd_queue;
 
    /* nb + 1 to fit the two-element host staging area for any nb */
    cuda_buffer_reserve(&fusedcg_redbuf, (nb + 1)*sizeof(real));
    real *fusedcg_buf = (real *) fusedcg_redbuf.host;
    real *fusedcg_buf_d = (real *) fusedcg_redbuf.dev;
 
    /* Store alpha(p_cur) in pinned memory */
    fusedcg_buf[1] = (*alpha);
 
    /* Update alpha_d(p_cur) = alpha(p_cur) */
    real *alpha_d_p_cur = ((real *) alpha_d) + ((*p_cur - 1));
    CUDA_CHECK(cudaMemcpyAsync(alpha_d_p_cur, &fusedcg_buf[1], sizeof(real),
                               cudaMemcpyHostToDevice, stream));
 
 
    fusedcg_part2_kernel<real>
      <<<nblcks, nthrds, 0, stream>>>((real *) a, (real *) b,
                                      (real *) c, *alpha,
                                      (real *) fusedcg_buf_d, * n);
    CUDA_CHECK(cudaGetLastError());
 
    reduce_kernel<real><<<1, 1024, 0, stream>>>((real *) fusedcg_buf_d, nb);
    CUDA_CHECK(cudaGetLastError());
 
#ifdef HAVE_NCCL
    device_nccl_allreduce(fusedcg_buf_d, fusedcg_buf_d, 1, sizeof(real),
                          DEVICE_NCCL_SUM, stream);
    CUDA_CHECK(cudaMemcpyAsync(fusedcg_buf, fusedcg_buf_d, sizeof(real),
                               cudaMemcpyDeviceToHost, stream));
    cudaStreamSynchronize(stream);
#elif HAVE_NVSHMEM
    if (sizeof(real) == sizeof(float)) {
      nvshmemx_float_sum_reduce_on_stream(NVSHMEM_TEAM_WORLD,
                                           (float *) fusedcg_buf_d,
                                           (float *) fusedcg_buf_d, 1, stream);
    }
    else if (sizeof(real) == sizeof(double)) {
      nvshmemx_double_sum_reduce_on_stream(NVSHMEM_TEAM_WORLD,
                                           (double *) fusedcg_buf_d,
                                           (double *) fusedcg_buf_d, 1, stream);
 
    }
    CUDA_CHECK(cudaMemcpyAsync(fusedcg_buf, fusedcg_buf_d,
                               sizeof(real), cudaMemcpyDeviceToHost, stream));
    cudaStreamSynchronize(stream);
#elif HAVE_DEVICE_MPI
    cudaStreamSynchronize(stream);
    device_mpi_allreduce(fusedcg_buf_d, fusedcg_buf, 1,
                         sizeof(real), DEVICE_MPI_SUM);
#else
    CUDA_CHECK(cudaMemcpyAsync(fusedcg_buf, fusedcg_buf_d, sizeof(real),
                               cudaMemcpyDeviceToHost, stream));
    cudaStreamSynchronize(stream);
#endif
 
    return fusedcg_buf[0];
  }
}