simulation_component.f90

Go to the documentation of this file.

! Copyright (c) 2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
module simulation_component
  use num_types, only : rp
  use json_module, only : json_file
  use case, only : case_t
  use time_based_controller, only : time_based_controller_t
  use json_utils, only : json_get_or_default, json_get
  implicit none
  private
 
  type, abstract, public :: simulation_component_t
     type(case_t), pointer :: case
     type(time_based_controller_t) :: compute_controller
     type(time_based_controller_t) :: output_controller
     integer :: order
   contains
     procedure, pass(this) :: init_base => simulation_component_init_base
     procedure, pass(this) :: free_base => simulation_component_free_base
     procedure, pass(this) :: restart => simulation_component_restart_wrapper
     procedure, pass(this) :: compute => simulation_component_compute_wrapper
     procedure(simulation_component_init), pass(this), deferred :: init
     procedure(simulation_component_free), pass(this), deferred :: free
     procedure(simulation_component_compute), pass(this), deferred :: compute_
  end type simulation_component_t
 
  type, public :: simulation_component_wrapper_t
     class(simulation_component_t), allocatable :: simcomp
  end type simulation_component_wrapper_t
 
 
  abstract interface
 
     subroutine simulation_component_init(this, json, case)
       import simulation_component_t, json_file, case_t
       class(simulation_component_t), intent(inout) :: this
       type(json_file), intent(inout) :: json
       class(case_t), intent(inout), target :: case
     end subroutine simulation_component_init
  end interface
 
  abstract interface
 
     subroutine simulation_component_free(this)
       import simulation_component_t
       class(simulation_component_t), intent(inout) :: this
     end subroutine simulation_component_free
  end interface
 
  abstract interface
 
     subroutine simulation_component_compute(this, t, tstep)
       import simulation_component_t, rp
       class(simulation_component_t), intent(inout) :: this
       real(kind=rp), intent(in) :: t
       integer, intent(in) :: tstep
     end subroutine simulation_component_compute
  end interface
 
contains
  subroutine simulation_component_init_base(this, json, case)
    class(simulation_component_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    class(case_t), intent(inout), target :: case
    character(len=:), allocatable :: compute_control, output_control
    real(kind=rp) :: compute_value, output_value
    integer :: order
 
    this%case => case
    call json_get_or_default(json, "compute_control", compute_control, &
                             "tsteps")
    call json_get_or_default(json, "compute_value", compute_value, 1.0_rp)
 
    ! We default to output whenever we execute
    call json_get_or_default(json, "output_control", output_control, &
                             compute_control)
    call json_get_or_default(json, "output_value", output_value, &
                             compute_value)
 
 
    if (output_control == "global") then
       call json_get(this%case%params, 'case.fluid.output_control', &
                     output_control)
       call json_get(this%case%params, 'case.fluid.output_value', &
                     output_value)
    end if
 
    call json_get(json, "order", order)
    this%order = order
 
    call this%compute_controller%init(case%end_time, compute_control, &
                                        compute_value)
    call this%output_controller%init(case%end_time, output_control, &
                                     output_value)
 
  end subroutine simulation_component_init_base
 
  subroutine simulation_component_free_base(this)
    class(simulation_component_t), intent(inout) :: this
 
    nullify(this%case)
  end subroutine simulation_component_free_base
 
  subroutine simulation_component_compute_wrapper(this, t, tstep)
    class(simulation_component_t), intent(inout) :: this
    real(kind=rp), intent(in) :: t
    integer, intent(in) :: tstep
 
    if (this%compute_controller%check(t, tstep)) then
       call this%compute_(t, tstep)
       call this%compute_controller%register_execution()
    end if
  end subroutine simulation_component_compute_wrapper
 
  subroutine simulation_component_restart_wrapper(this, t)
    class(simulation_component_t), intent(inout) :: this
    real(kind=rp), intent(in) :: t
 
    call this%compute_controller%set_counter(t)
    call this%output_controller%set_counter(t)
 
  end subroutine simulation_component_restart_wrapper
 
end module simulation_component