usr_inflow.f90

Go to the documentation of this file.

! Copyright (c) 2020-2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module usr_inflow
  use num_types
  use coefs
  use inflow
  use device
  use device_inhom_dirichlet
  use utils
  implicit none
  private
 
  type, public, extends(inflow_t) :: usr_inflow_t
     type(coef_t), pointer :: c => null()
     procedure(usr_inflow_eval), nopass, pointer :: eval => null()
     type(c_ptr), private :: usr_x_d = c_null_ptr
     type(c_ptr), private :: usr_y_d = c_null_ptr
     type(c_ptr), private :: usr_z_d = c_null_ptr
   contains
     procedure, pass(this) :: apply_scalar => usr_inflow_apply_scalar
     procedure, pass(this) :: apply_vector => usr_inflow_apply_vector
     procedure, pass(this) :: validate => usr_inflow_validate
     procedure, pass(this) :: set_coef => usr_inflow_set_coef
     procedure, pass(this) :: set_eval => usr_inflow_set_eval
     procedure, pass(this) :: apply_vector_dev => usr_inflow_apply_vector_dev
     procedure, pass(this) :: apply_scalar_dev => usr_inflow_apply_scalar_dev
  end type usr_inflow_t
 
  abstract interface
 
     subroutine usr_inflow_eval(u, v, w, x, y, z, nx, ny, nz, &
                                ix, iy, iz, ie, t, tstep)
       import rp
       real(kind=rp), intent(inout) :: u
       real(kind=rp), intent(inout) :: v
       real(kind=rp), intent(inout) :: w
       real(kind=rp), intent(in) :: x
       real(kind=rp), intent(in) :: y
       real(kind=rp), intent(in) :: z
       real(kind=rp), intent(in) :: nx
       real(kind=rp), intent(in) :: ny
       real(kind=rp), intent(in) :: nz
       integer, intent(in) :: ix
       integer, intent(in) :: iy
       integer, intent(in) :: iz
       integer, intent(in) :: ie
       real(kind=rp), intent(in) :: t
       integer, intent(in) :: tstep
     end subroutine usr_inflow_eval
  end interface
 
  public :: usr_inflow_eval
 
contains
 
  subroutine usr_inflow_free(this)
    type(usr_inflow_t), intent(inout) :: this
 
    if (c_associated(this%usr_x_d)) then
       call device_free(this%usr_x_d)
    end if
 
    if (c_associated(this%usr_y_d)) then
       call device_free(this%usr_y_d)
    end if
 
    if (c_associated(this%usr_z_d)) then
       call device_free(this%usr_z_d)
    end if
 
  end subroutine usr_inflow_free
 
  subroutine usr_inflow_apply_scalar(this, x, n, t, tstep)
    class(usr_inflow_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout),  dimension(n) :: x
    real(kind=rp), intent(in), optional :: t
    integer, intent(in), optional :: tstep
  end subroutine usr_inflow_apply_scalar
 
  subroutine usr_inflow_apply_scalar_dev(this, x_d, t, tstep)
    class(usr_inflow_t), intent(inout), target :: this
    type(c_ptr) :: x_d
    real(kind=rp), intent(in), optional :: t
    integer, intent(in), optional :: tstep
  end subroutine usr_inflow_apply_scalar_dev
 
  subroutine usr_inflow_apply_vector(this, x, y, z, n, t, tstep)
    class(usr_inflow_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout),  dimension(n) :: x
    real(kind=rp), intent(inout),  dimension(n) :: y
    real(kind=rp), intent(inout),  dimension(n) :: z
    real(kind=rp), intent(in), optional :: t
    integer, intent(in), optional :: tstep
    integer :: i, m, k, idx(4), facet, tstep_
    real(kind=rp) :: t_
 
    if (present(t)) then
       t_ = t
    else
       t_ = 0.0_rp
    end if
 
    if (present(tstep)) then
       tstep_ = tstep
    else
       tstep_ = 1
    end if
 
    associate(xc => this%c%dof%x, yc => this%c%dof%y, zc => this%c%dof%z, &
         nx => this%c%nx, ny => this%c%ny, nz => this%c%nz, &
         lx => this%c%Xh%lx)
      m = this%msk(0)
      do i = 1, m
         k = this%msk(i)
         facet = this%facet(i)
         idx = nonlinear_index(k, lx, lx, lx)
         select case(facet)
         case(1,2)
            call this%eval(x(k), y(k), z(k), &
                 xc(idx(1), idx(2), idx(3), idx(4)), &
                 yc(idx(1), idx(2), idx(3), idx(4)), &
                 zc(idx(1), idx(2), idx(3), idx(4)), &
                 nx(idx(2), idx(3), facet, idx(4)), &
                 ny(idx(2), idx(3), facet, idx(4)), &
                 nz(idx(2), idx(3), facet, idx(4)), &
                 idx(1), idx(2), idx(3), idx(4), &
                 t_, tstep_)
         case(3,4)
            call this%eval(x(k), y(k), z(k), &
                 xc(idx(1), idx(2), idx(3), idx(4)), &
                 yc(idx(1), idx(2), idx(3), idx(4)), &
                 zc(idx(1), idx(2), idx(3), idx(4)), &
                 nx(idx(1), idx(3), facet, idx(4)), &
                 ny(idx(1), idx(3), facet, idx(4)), &
                 nz(idx(1), idx(3), facet, idx(4)), &
                 idx(1), idx(2), idx(3), idx(4), &
                 t_, tstep_)
         case(5,6)
            call this%eval(x(k), y(k), z(k), &
                 xc(idx(1), idx(2), idx(3), idx(4)), &
                 yc(idx(1), idx(2), idx(3), idx(4)), &
                 zc(idx(1), idx(2), idx(3), idx(4)), &
                 nx(idx(1), idx(2), facet, idx(4)), &
                 ny(idx(1), idx(2), facet, idx(4)), &
                 nz(idx(1), idx(2), facet, idx(4)), &
                 idx(1), idx(2), idx(3), idx(4), &
                 t_, tstep_)
         end select
      end do
    end associate
 
  end subroutine usr_inflow_apply_vector
 
  subroutine usr_inflow_apply_vector_dev(this, x_d, y_d, z_d, t, tstep)
    class(usr_inflow_t), intent(inout), target :: this
    type(c_ptr) :: x_d
    type(c_ptr) :: y_d
    type(c_ptr) :: z_d
    real(kind=rp), intent(in), optional :: t
    integer, intent(in), optional :: tstep
    integer :: i, m, k, idx(4), facet, tstep_
    integer(c_size_t) :: s
    real(kind=rp) :: t_
    real(kind=rp), allocatable :: x(:)
    real(kind=rp), allocatable :: y(:)
    real(kind=rp), allocatable :: z(:)
 
    if (present(t)) then
       t_ = t
    else
       t_ = 0.0_rp
    end if
 
    if (present(tstep)) then
       tstep_ = tstep
    else
       tstep_ = 1
    end if
 
    associate(xc => this%c%dof%x, yc => this%c%dof%y, zc => this%c%dof%z, &
         nx => this%c%nx, ny => this%c%ny, nz => this%c%nz, &
         lx => this%c%Xh%lx, usr_x_d => this%usr_x_d, usr_y_d => this%usr_y_d, &
         usr_z_d => this%usr_z_d)
 
      m = this%msk(0)
 
 
      ! Pretabulate values during first call to apply
      if (.not. c_associated(usr_x_d)) then
         allocate(x(m), y(m), z(m)) ! Temp arrays
 
         s = m*rp
 
         call device_alloc(usr_x_d, s)
         call device_alloc(usr_y_d, s)
         call device_alloc(usr_z_d, s)
 
         associate(xc => this%c%dof%x, yc => this%c%dof%y, zc => this%c%dof%z, &
                   nx => this%c%nx, ny => this%c%ny, nz => this%c%nz, &
                   lx => this%c%Xh%lx)
           do i = 1, m
              k = this%msk(i)
              facet = this%facet(i)
              idx = nonlinear_index(k, lx, lx, lx)
              select case(facet)
              case(1,2)
                 call this%eval(x(i), y(i), z(i), &
                      xc(idx(1), idx(2), idx(3), idx(4)), &
                      yc(idx(1), idx(2), idx(3), idx(4)), &
                      zc(idx(1), idx(2), idx(3), idx(4)), &
                      nx(idx(2), idx(3), facet, idx(4)), &
                      ny(idx(2), idx(3), facet, idx(4)), &
                      nz(idx(2), idx(3), facet, idx(4)), &
                      idx(1), idx(2), idx(3), idx(4), &
                      t_, tstep_)
              case(3,4)
                 call this%eval(x(i), y(i), z(i), &
                      xc(idx(1), idx(2), idx(3), idx(4)), &
                      yc(idx(1), idx(2), idx(3), idx(4)), &
                      zc(idx(1), idx(2), idx(3), idx(4)), &
                      nx(idx(1), idx(3), facet, idx(4)), &
                      ny(idx(1), idx(3), facet, idx(4)), &
                      nz(idx(1), idx(3), facet, idx(4)), &
                      idx(1), idx(2), idx(3), idx(4), &
                      t_, tstep_)
              case(5,6)
                 call this%eval(x(i), y(i), z(i), &
                      xc(idx(1), idx(2), idx(3), idx(4)), &
                      yc(idx(1), idx(2), idx(3), idx(4)), &
                      zc(idx(1), idx(2), idx(3), idx(4)), &
                      nx(idx(1), idx(2), facet, idx(4)), &
                      ny(idx(1), idx(2), facet, idx(4)), &
                      nz(idx(1), idx(2), facet, idx(4)), &
                      idx(1), idx(2), idx(3), idx(4), &
                      t_, tstep_)
              end select
           end do
         end associate
        
         call device_memcpy(x, usr_x_d, m, host_to_device, sync=.false.)
         call device_memcpy(y, usr_y_d, m, host_to_device, sync=.false.)
         call device_memcpy(z, usr_z_d, m, host_to_device, sync=.true.)
 
         deallocate(x, y, z)
      end if
 
      call device_inhom_dirichlet_apply_vector(this%msk_d, x_d, y_d, z_d, &
           usr_x_d, usr_y_d, usr_z_d, m)
 
    end associate
 
  end subroutine usr_inflow_apply_vector_dev
 
  subroutine usr_inflow_set_coef(this, c)
    class(usr_inflow_t), intent(inout) :: this
    type(coef_t), target, intent(inout) :: c
    this%c => c
  end subroutine usr_inflow_set_coef
 
  subroutine usr_inflow_set_eval(this, usr_eval)
    class(usr_inflow_t), intent(inout) :: this
    procedure(usr_inflow_eval) :: usr_eval
    this%eval => usr_eval
  end subroutine usr_inflow_set_eval
 
  subroutine usr_inflow_validate(this)
    class(usr_inflow_t), intent(inout) :: this
    logical :: valid
 
    valid = .true. ! Assert it's going to be ok...
    if (.not. associated(this%c)) then
       call neko_warning('Missing coefficients')
       valid = .false.
    end if
 
    if (.not. associated(this%eval)) then
       call neko_warning('Missing eval function')
       valid = .false.
    end if
 
    if (.not. valid) then
       call neko_error('Invalid user defined inflow condition')
    end if
 
  end subroutine usr_inflow_validate
 
end module usr_inflow