jobctrl.f90

Go to the documentation of this file.

! Copyright (c) 2021-2025, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module jobctrl
  use num_types, only : rp, dp
  use signal, only : signal_timeout, signal_usr, signal_trap_usr, &
       signal_set_timeout, signal_trap_cpulimit
  use utils, only : neko_error, read_duration
  use mpi_f08, only : mpi_bcast, mpi_logical, mpi_wtime
  use comm, only : neko_comm
  use logger, only : neko_log, log_size, neko_log_quiet
  implicit none
  private
 
  interface jobctrl_set_time_limit
     module procedure jobctrl_set_time_limit_sec, jobctrl_set_time_limit_str
  end interface jobctrl_set_time_limit
 
  public :: jobctrl_init, jobctrl_set_time_limit, &
       jobctrl_time_limit, jobctrl_jobtime
 
contains
 
  subroutine jobctrl_init()
    real(kind=dp) :: jobtime
 
    ! Start the job clock
    jobtime = jobctrl_jobtime()
 
    ! Catch SIGXCPU
    call signal_trap_cpulimit()
 
    ! Catch SIGUSR1 and SIGUSR2
    call signal_trap_usr()
 
  end subroutine jobctrl_init
 
  subroutine jobctrl_set_time_limit_str(limit_str)
    character(len=*), intent(in) :: limit_str
    real(kind=rp) :: limit_sec
    integer :: ierr
 
    limit_sec = 0.0_rp
    call read_duration(limit_str, limit_sec)
    call jobctrl_set_time_limit_sec(int(limit_sec))
 
  end subroutine jobctrl_set_time_limit_str
 
  subroutine jobctrl_set_time_limit_sec(sec)
    integer :: sec
    integer :: jstop_sec
 
    if (sec .gt. 0) then
       jstop_sec = sec - jobctrl_jobtime()
       call signal_set_timeout(jstop_sec)
    end if
 
  end subroutine jobctrl_set_time_limit_sec
 
  function jobctrl_time_limit() result(jstop)
    logical :: jstop
    integer :: ierr
    character(len=LOG_SIZE) :: log_buf
 
    jstop = (signal_timeout() .or. signal_usr(1))
 
    if (jstop) then
       ! Todo: This might be a warning instead of a message?
       write(log_buf, '(A)') '! stop at job limit >>>'
       call neko_log%message(log_buf, neko_log_quiet)
    end if
 
    ! Let rank zero decide if we should stop
    call mpi_bcast(jstop, 1, mpi_logical, 0, neko_comm, ierr)
 
  end function jobctrl_time_limit
 
  function jobctrl_jobtime() result(jobtime)
    real(kind=rp), save :: stime
    real(kind=rp) :: jobtime
    logical, save :: init = .false.
 
    if (.not. init) then
       stime = mpi_wtime()
       init = .true.
    end if
 
    jobtime = mpi_wtime() - stime
  end function jobctrl_jobtime
 
end module jobctrl