simulation_component.f90

Go to the documentation of this file.

! Copyright (c) 2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
module simulation_component
  use utils, only : neko_typename_len
  use num_types, only : dp
  use json_module, only : json_file
  use case, only : case_t
  use time_based_controller, only : time_based_controller_t
  use json_utils, only : json_get_or_default, json_get, &
       json_get_or_lookup_or_default, json_get_or_lookup
  use time_state, only : time_state_t
  implicit none
  private
 
  type, abstract, public :: simulation_component_t
     type(case_t), pointer :: case
     type(time_based_controller_t) :: preprocess_controller
     type(time_based_controller_t) :: compute_controller
     type(time_based_controller_t) :: output_controller
     integer :: order
     character(:), allocatable :: name
   contains
     procedure, pass(this) :: init_base => simulation_component_init_base
     generic :: init_base_from_components => &
          init_base_from_controllers_properties, &
          init_base_from_controllers
     procedure, pass(this) :: init_base_from_controllers => &
          simulation_component_init_base_from_controllers
     procedure, pass(this) :: init_base_from_controllers_properties => &
          simulation_component_init_base_from_controllers_properties
     procedure, pass(this) :: free_base => simulation_component_free_base
     procedure, pass(this) :: restart => simulation_component_restart_wrapper
     procedure, pass(this) :: preprocess => &
          simulation_component_preprocess_wrapper
     procedure, pass(this) :: compute => simulation_component_compute_wrapper
     procedure(simulation_component_init), pass(this), deferred :: init
     procedure(simulation_component_free), pass(this), deferred :: free
     procedure, pass(this) :: preprocess_
     procedure, pass(this) :: compute_
     procedure, pass(this) :: restart_
     procedure, pass(this) :: parse_json => simulation_component_parse_json
  end type simulation_component_t
 
  type, public :: simulation_component_wrapper_t
     class(simulation_component_t), allocatable :: simcomp
   contains
     procedure, pass(this) :: init => simulation_component_wrapper_init
     procedure, pass(this) :: free => simulation_component_wrapper_free
     procedure, pass(this) :: move_from => &
          simulation_component_wrapper_move_from
     procedure, pass(this) :: is_allocated => &
          simulation_component_wrapper_is_allocated
  end type simulation_component_wrapper_t
 
  abstract interface
 
     subroutine simulation_component_init(this, json, case)
       import simulation_component_t, json_file, case_t
       class(simulation_component_t), intent(inout), target :: this
       type(json_file), intent(inout) :: json
       class(case_t), intent(inout), target :: case
     end subroutine simulation_component_init
  end interface
 
  abstract interface
 
     subroutine simulation_component_free(this)
       import simulation_component_t
       class(simulation_component_t), intent(inout) :: this
     end subroutine simulation_component_free
  end interface
 
  interface
 
     module subroutine simulation_component_factory(object, json, case)
       class(simulation_component_t), allocatable, intent(inout) :: object
       type(json_file), intent(inout) :: json
       class(case_t), intent(inout), target :: case
     end subroutine simulation_component_factory
  end interface
 
  interface
 
     module subroutine simulation_component_allocator(object, type_name)
       class(simulation_component_t), allocatable, intent(inout) :: object
       character(len=*), intent(in):: type_name
     end subroutine simulation_component_allocator
  end interface
 
  !
  ! Machinery for injecting user-defined types
  !
 
  abstract interface
     subroutine simulation_component_allocate(obj)
       import simulation_component_t
       class(simulation_component_t), allocatable, intent(inout) :: obj
     end subroutine simulation_component_allocate
  end interface
 
  interface
 
     module subroutine register_simulation_component(type_name, allocator)
       character(len=*), intent(in) :: type_name
       procedure(simulation_component_allocate), pointer, intent(in) :: &
            allocator
     end subroutine register_simulation_component
  end interface
 
  ! A name-allocator pair for user-defined types. A helper type to define a
  ! registry of custom allocators.
  type allocator_entry
     character(len=NEKO_TYPENAME_LEN) :: type_name
     procedure(simulation_component_allocate), pointer, nopass :: allocator
  end type allocator_entry
 
  type(allocator_entry), allocatable :: simcomp_registry(:)
 
  integer :: simcomp_registry_size = 0
 
  public :: simulation_component_factory, simulation_component_allocator, &
       register_simulation_component, simulation_component_allocate
 
 
contains
  subroutine simulation_component_init_base(this, json, case)
    class(simulation_component_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    class(case_t), intent(inout), target :: case
    character(len=:), allocatable :: preprocess_control, compute_control, &
         output_control
    real(kind=dp) :: preprocess_value, compute_value, output_value
    integer :: order
 
    call this%parse_json(json, case%params, preprocess_control, &
         preprocess_value, compute_control, compute_value, output_control, &
         output_value)
 
    call json_get_or_default(json, "order", order, -1)
 
    call this%init_base_from_components(case, order, &
         preprocess_control, preprocess_value, compute_control, compute_value, &
         output_control, output_value)
 
  end subroutine simulation_component_init_base
 
  subroutine simulation_component_init_base_from_controllers_properties(this, &
       case, order, preprocess_control, preprocess_value, compute_control, &
       compute_value, output_control, output_value)
    class(simulation_component_t), intent(inout) :: this
    class(case_t), intent(inout), target :: case
    integer :: order
    character(len=*), intent(in) :: preprocess_control
    real(kind=dp), intent(in) :: preprocess_value
    character(len=*), intent(in) :: compute_control
    real(kind=dp), intent(in) :: compute_value
    character(len=*), intent(in) :: output_control
    real(kind=dp), intent(in) :: output_value
 
    this%case => case
    this%order = order
 
    call this%preprocess_controller%init(case%time%start_time, &
         case%time%end_time, preprocess_control, preprocess_value)
    call this%compute_controller%init(case%time%start_time, case%time%end_time,&
         compute_control, compute_value)
    call this%output_controller%init(case%time%start_time, case%time%end_time, &
         output_control, output_value)
 
  end subroutine simulation_component_init_base_from_controllers_properties
 
  subroutine simulation_component_init_base_from_controllers(this, case, order,&
       preprocess_controller, compute_controller, output_controller)
    class(simulation_component_t), intent(inout) :: this
    class(case_t), intent(inout), target :: case
    integer :: order
    type(time_based_controller_t), intent(in) :: preprocess_controller
    type(time_based_controller_t), intent(in) :: compute_controller
    type(time_based_controller_t), intent(in) :: output_controller
 
    this%case => case
    this%order = order
    this%preprocess_controller = preprocess_controller
    this%compute_controller = compute_controller
    this%output_controller = output_controller
  end subroutine simulation_component_init_base_from_controllers
 
  subroutine simulation_component_parse_json(this, json, case_params, &
       preprocess_control, preprocess_value, compute_control, compute_value, &
       output_control, output_value)
    class(simulation_component_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(json_file), intent(inout) :: case_params
    character(len=:), allocatable, intent(inout) :: preprocess_control
    real(kind=dp), intent(out) :: preprocess_value
    character(len=:), allocatable, intent(inout) :: compute_control
    real(kind=dp), intent(out) :: compute_value
    character(len=:), allocatable, intent(inout) :: output_control
    real(kind=dp), intent(out) :: output_value
    integer :: preprocess_value_int, compute_value_int, output_value_int
    character(len=:), allocatable :: json_path
    type(json_file) :: json_object
 
    !
    ! Preprocess
    !
 
    ! Get the preprocess control, defaulting to tsteps, pin to fluid if
    ! requested
    call json_get_or_default(json, "preprocess_control", preprocess_control, &
         "tsteps")
 
    json_path = "preprocess_value"
    json_object = json
    if (preprocess_control .eq. "fluid_output") then
       call json_get(case_params, 'case.fluid.output_control', &
            preprocess_control)
       json_path = "case.fluid.output_value"
       json_object = case_params
    end if
 
    ! Read preprocess value based on control type
    if ((preprocess_control .eq. "tsteps") .or. &
         (preprocess_control .eq. "nsamples")) then
       ! Read it is an interger, and convert to real
       call json_get_or_lookup_or_default(json_object, json_path, &
            preprocess_value_int, 1)
       preprocess_value = real(preprocess_value_int, kind=dp)
    else if (preprocess_control .eq. "simulationtime") then
       ! Read as real
       call json_get_or_lookup_or_default(json_object, json_path, &
            preprocess_value, 1.0_dp)
    else if (preprocess_control .eq. "never") then
       ! Dummy value
       preprocess_value = 0.0_dp
    end if
 
    !
    ! Compute
    !
 
    ! Get the compute control, defaulting to tsteps, pin to fluid if
    ! requested
    call json_get_or_default(json, "compute_control", compute_control, &
         "tsteps")
 
    json_path = "compute_value"
    json_object = json
    if (compute_control .eq. "fluid_output") then
       call json_get(case_params, 'case.fluid.output_control', &
            compute_control)
       json_path = "case.fluid.output_value"
       json_object = case_params
    end if
 
    ! Read compute value based on control type
    if ((compute_control .eq. "tsteps") .or. &
         (compute_control .eq. "nsamples")) then
       ! Read it is an interger, and convert to real
       call json_get_or_lookup_or_default(json_object, json_path, &
            compute_value_int, 1)
       compute_value = real(compute_value_int, kind=dp)
    else if (compute_control .eq. "simulationtime") then
       ! Read as real
       call json_get_or_lookup_or_default(json_object, json_path, &
            compute_value, 1.0_dp)
       compute_value_int = int(compute_value)
    else if (compute_control .eq. "never") then
       ! Dummy value
       compute_value = 0.0_dp
       compute_value_int = 0
    end if
 
    !
    ! Output
    !
 
    ! We default to output whenever we execute, pin to fluid if requested
    call json_get_or_default(json, "output_control", output_control, &
         compute_control)
 
    json_path = "output_value"
    json_object = json
    if (output_control .eq. "global") then
       call json_get(case_params, 'case.fluid.output_control', &
            output_control)
       json_path = "case.fluid.output_value"
       json_object = case_params
    end if
 
 
    ! Read output value based on control type. We default to compute_value
    if ((output_control .eq. "tsteps") .or. &
         (output_control .eq. "nsamples")) then
       ! Read it is an interger, and convert to real
       call json_get_or_lookup_or_default(json_object, json_path, &
            output_value_int, compute_value_int)
       output_value = real(output_value_int, kind=dp)
    else if (output_control .eq. "simulationtime") then
       ! Read as real
       call json_get_or_lookup_or_default(json_object, json_path, &
            output_value, compute_value)
    else if (output_control .eq. "never") then
       ! Dummy value
       output_value = 0.0_dp
    end if
 
    deallocate(json_path)
  end subroutine simulation_component_parse_json
 
  subroutine simulation_component_free_base(this)
    class(simulation_component_t), intent(inout) :: this
 
    nullify(this%case)
 
    if (allocated(this%name)) then
       deallocate(this%name)
    end if
 
    call this%preprocess_controller%free()
    call this%compute_controller%free()
    call this%output_controller%free()
  end subroutine simulation_component_free_base
 
  subroutine simulation_component_preprocess_wrapper(this, time)
    class(simulation_component_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
 
    if (this%preprocess_controller%check(time)) then
       call this%preprocess_(time)
       call this%preprocess_controller%register_execution(time)
    end if
  end subroutine simulation_component_preprocess_wrapper
 
  subroutine simulation_component_compute_wrapper(this, time)
    class(simulation_component_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
 
    if (this%compute_controller%check(time)) then
       call this%compute_(time)
       call this%compute_controller%register_execution(time)
    end if
  end subroutine simulation_component_compute_wrapper
 
  subroutine simulation_component_restart_wrapper(this, time)
    class(simulation_component_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
 
    call this%preprocess_controller%set_counter(time)
    call this%compute_controller%set_counter(time)
    call this%output_controller%set_counter(time)
    call this%restart_(time)
 
  end subroutine simulation_component_restart_wrapper
 
  subroutine restart_(this, time)
    class(simulation_component_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
 
    ! Do nothing
  end subroutine restart_
 
  subroutine preprocess_(this, time)
    class(simulation_component_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
 
    ! Do nothing
  end subroutine preprocess_
 
  subroutine compute_(this, time)
    class(simulation_component_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
 
    ! Do nothing
  end subroutine compute_
 
  ! ========================================================================== !
  ! Simulation component wrapper type methods
 
  subroutine simulation_component_wrapper_init(this, json, case)
    class(simulation_component_wrapper_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    class(case_t), intent(inout), target :: case
 
    call this%free()
    call simulation_component_factory(this%simcomp, json, case)
 
  end subroutine simulation_component_wrapper_init
 
  subroutine simulation_component_wrapper_free(this)
    class(simulation_component_wrapper_t), intent(inout) :: this
 
    if (allocated(this%simcomp)) then
       call this%simcomp%free()
       deallocate(this%simcomp)
    end if
 
  end subroutine simulation_component_wrapper_free
 
  subroutine simulation_component_wrapper_move_from(this, other)
    class(simulation_component_wrapper_t), intent(inout) :: this
    class(simulation_component_wrapper_t), intent(inout) :: other
 
    ! Move the pointer
    call move_alloc(other%simcomp, this%simcomp)
 
  end subroutine simulation_component_wrapper_move_from
 
  function simulation_component_wrapper_is_allocated(this) result(is_alloc)
    class(simulation_component_wrapper_t), intent(in) :: this
    logical :: is_alloc
    is_alloc = allocated(this%simcomp)
  end function simulation_component_wrapper_is_allocated
 
end module simulation_component