spalding_cpu.f90

Go to the documentation of this file.

! Copyright (c) 2025, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module spalding_cpu
  use num_types, only : rp
  use logger, only : neko_log, neko_log_debug, log_size
  implicit none
  private
 
  public :: spalding_compute_cpu
 
contains
  subroutine spalding_compute_cpu(u, v, w, &
       n_x, n_y, n_z, nu, rho_w, h, tau_x, tau_y, tau_z, n_nodes, &
       kappa, B, tstep)
    integer, intent(in) :: n_nodes, tstep
    real(kind=rp), dimension(n_nodes), intent(in) :: u, v, w
    real(kind=rp), dimension(n_nodes), intent(in) :: rho_w
    real(kind=rp), dimension(n_nodes), intent(in) :: n_x, n_y, n_z, h, nu
    real(kind=rp), dimension(n_nodes), intent(inout) :: tau_x, tau_y, tau_z
    real(kind=rp), intent(in) :: kappa, b
    integer :: i
    real(kind=rp) :: ui, vi, wi, magu, utau, normu, guess, rho
 
    !$omp parallel do private(i, ui, vi, wi, magu, utau, normu, guess, rho)
    do i=1, n_nodes
       ! Load the sampled velocity
       ui = u(i)
       vi = v(i)
       wi = w(i)
       rho = rho_w(i)
 
       ! Project on tangential direction
       normu = ui * n_x(i) + vi * n_y(i) + wi * n_z(i)
 
       ui = ui - normu * n_x(i)
       vi = vi - normu * n_y(i)
       wi = wi - normu * n_z(i)
 
       magu = sqrt(ui**2 + vi**2 + wi**2)
 
       ! Get initial guess for Newton solver
       if (tstep .eq. 1) then
          guess = sqrt(magu * nu(i) / h(i))
       else
          guess = tau_x(i)**2 + tau_y(i)**2 + tau_z(i)**2
          guess = sqrt(sqrt(guess))
       end if
 
       utau = solve_cpu(magu, h(i), guess, nu(i), kappa, b)
 
       ! Distribute according to the velocity vector
       tau_x(i) = -rho*utau**2 * ui / magu
       tau_y(i) = -rho*utau**2 * vi / magu
       tau_z(i) = -rho*utau**2 * wi / magu
    end do
    !$omp end parallel do
 
  end subroutine spalding_compute_cpu
 
  function solve_cpu(u, y, guess, nu, kappa, B) result(utau)
    real(kind=rp), intent(in) :: u
    real(kind=rp), intent(in) :: y
    real(kind=rp), intent(in) :: guess
    real(kind=rp), intent(in) :: nu, kappa, b
    real(kind=rp) :: yp, up, utau
    real(kind=rp) :: error, f, df, old
    integer :: niter, k, maxiter
    character(len=LOG_SIZE) :: log_msg
 
    utau = guess
 
    maxiter = 100
 
    do k = 1, maxiter
       up = u / utau
       yp = y * utau / nu
       niter = k
       old = utau
 
       ! Evaluate function and its derivative
       f = (up + exp(-kappa*b)* &
            (exp(kappa*up) - 1.0_rp - kappa*up - 0.5_rp*(kappa*up)**2 - &
            1.0_rp/6*(kappa*up)**3) - yp)
 
       df = (-y / nu - u/utau**2 - kappa*up/utau*exp(-kappa*b) * &
            (exp(kappa*up) - 1 - kappa*up - 0.5*(kappa*up)**2))
 
       ! Update solution
       utau = utau - f / df
 
       error = abs((old - utau)/old)
 
       if (error < 1e-3) then
          exit
       end if
 
    end do
 
    if (niter .eq. maxiter) then
       ! Called from inside an OpenMP loop, so serialise the log write.
       !$omp critical
       write(log_msg, *) "Newton not converged", error, f, utau
       call neko_log%message(log_msg, neko_log_debug)
       !$omp end critical
    end if
  end function solve_cpu
end module spalding_cpu