csv_file.f90

Go to the documentation of this file.

! Copyright (c) 2020-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module csv_file
  use vector, only : vector_t
  use matrix, only : matrix_t
  use generic_file, only : generic_file_t
  use utils, only : neko_error
  use num_types, only : dp
  use logger, only : neko_log, log_size
  use comm
  implicit none
 
  type, public, extends(generic_file_t) :: csv_file_t
     character(len=:), allocatable :: header
     logical :: header_is_written = .false. 
   contains
     procedure :: write => csv_file_write
     procedure :: read => csv_file_read
     procedure :: set_header => csv_file_set_header
     procedure :: set_overwrite => csv_file_set_overwrite
     procedure :: count_lines => csv_file_count_lines
  end type csv_file_t
 
contains
 
  subroutine csv_file_write(this, data, t)
    class(csv_file_t), intent(inout) :: this
    class(*), target, intent(in) :: data
    real(kind=dp), intent(in), optional :: t
 
    type(vector_t), pointer :: vec
    type(matrix_t), pointer :: mat
 
    nullify(vec)
    nullify(mat)
 
    select type (data)
    type is (vector_t)
       if (.not. allocated(data%x)) then
          call neko_error("Vector is not allocated. Use &
          &vector%init() to associate your array &
          &with a vector_t object")
       end if
       vec => data
 
    type is (matrix_t)
       if (.not. allocated(data%x)) then
          call neko_error("Matrix is not allocated. Use &
          &matrix%init() to associate your array &
          &with a matrix_t object")
       end if
       mat => data
 
    class default
       call neko_error("Invalid data. Expected vector_t or &
       &matrix_t")
    end select
 
    ! Write is performed on rank 0
    if (pe_rank .eq. 0) then
 
       call neko_log%message("Writing to " // trim(this%get_fname()))
       if (associated(vec)) then
          call csv_file_write_vector(this, vec, t)
       else if (associated(mat)) then
          call csv_file_write_matrix(this, mat, t)
       end if
 
    end if
 
  end subroutine csv_file_write
 
  subroutine csv_file_write_vector(f, data, t)
    class(csv_file_t), intent(inout) :: f
    type(vector_t), intent(in) :: data
    real(kind=dp), intent(in), optional :: t
    integer :: file_unit, ierr, n
 
    ! Delete file if overwrite is enabled and header hasn't been written yet
    if (f%overwrite .and. .not. f%header_is_written) then
       open(newunit = file_unit, file = trim(f%get_fname()), status = "old", &
            iostat = ierr)
       if (ierr == 0) close(file_unit, status = "delete")
    end if
 
    open(file = trim(f%get_fname()), position = "append", iostat = ierr, &
         newunit = file_unit)
    if (ierr .ne. 0) then
       call neko_error("Error while opening " // trim(f%get_fname()))
    end if
 
    ! write header if not empty and if not already written
    if (allocated(f%header)) then
       if (f%header .ne. "" .and. .not. f%header_is_written) then
          write (file_unit, '(A)') trim(f%header)
          f%header_is_written = .true.
       end if
    end if
 
    ! Add time at the beginning if specified
    if (present(t)) write (file_unit, '(g0,",")', advance = "no") t
 
    n = data%size()
    write (file_unit, '(*(g0,","))', advance = "no") data%x(1:n-1)
    write (file_unit, '(g0)') data%x(n)
 
    close(file_unit)
 
  end subroutine csv_file_write_vector
 
  subroutine csv_file_write_matrix(f, data, t)
    class(csv_file_t), intent(inout) :: f
    type(matrix_t), intent(in) :: data
    real(kind=dp), intent(in), optional :: t
    integer :: file_unit, i, ierr, nc
 
    ! Delete file if overwrite is enabled and header hasn't been written yet
    if (f%overwrite .and. .not. f%header_is_written) then
       open(newunit = file_unit, file = trim(f%get_fname()), status = "old", &
            iostat = ierr)
       if (ierr == 0) close(file_unit, status = "delete")
    end if
 
    open(file = trim(f%get_fname()), position = "append", iostat = ierr, &
         newunit = file_unit)
    if (ierr .ne. 0) then
       call neko_error("Error while opening " // trim(f%get_fname()))
    end if
 
    ! write header if not empty and if not already written
    if (allocated(f%header)) then
       if (f%header .ne. "" .and. .not. f%header_is_written) then
          write (file_unit, '(A)') trim(f%header)
          f%header_is_written = .true.
       end if
    end if
 
    do i = 1, data%get_nrows()
       if (present(t)) write (file_unit, '(g0,",")', advance = "no") t
       nc = data%get_ncols()
       write (file_unit, '(*(g0,","))', advance = "no") &
            data%x(i, 1:nc-1)
       write (file_unit, '(g0)') data%x(i, nc)
    end do
 
    close(file_unit)
 
  end subroutine csv_file_write_matrix
 
  subroutine csv_file_read(this, data)
    class(csv_file_t) :: this
    class(*), target, intent(inout) :: data
    type(vector_t), pointer :: vec
    type(matrix_t), pointer :: mat
 
    call this%check_exists()
 
    nullify(vec)
    nullify(mat)
 
    select type (data)
    type is (vector_t)
       vec => data
       if (.not. allocated(data%x)) then
          call neko_error("Vector is not allocated. Use &
          &vector%init() to associate your array &
          &with a vector_t object")
       end if
 
    type is (matrix_t)
       mat => data
       if (.not. allocated(data%x)) then
          call neko_error("Matrix is not allocated. Use &
          &matrix%init() to associate your array &
          &with a matrix_t object")
       end if
 
 
    class default
       call neko_error("Invalid data type for csv_file (expected: vector_t, &
       &matrix_t)")
    end select
 
    if (pe_rank .eq. 0) then
 
       call neko_log%newline()
       call neko_log%message("Reading csv file " // trim(this%get_fname()))
       if (associated(vec)) then
          call csv_file_read_vector(this, vec)
       else if (associated(mat)) then
          call csv_file_read_matrix(this, mat)
       end if
 
    end if
 
  end subroutine csv_file_read
 
  subroutine csv_file_read_vector(f, vec)
    type(csv_file_t), intent(inout) :: f
    type(vector_t), intent(inout) :: vec
    integer :: ierr, file_unit, n_lines
    character(len=80) :: tmp
 
    n_lines = f%count_lines()
 
    open(file = trim(f%get_fname()), status = 'old', newunit = file_unit, &
         iostat = ierr)
    if (ierr .ne. 0) then
       call neko_error("Error while opening " // trim(f%get_fname()))
    end if
 
    ! If there is more than 1 line, assume that means there is a header
    if (n_lines .gt. 1) then
       read (file_unit, '(A)') tmp
       f%header = trim(tmp)
    end if
 
    read (file_unit,*) vec%x
    close(unit = file_unit)
 
 
  end subroutine csv_file_read_vector
 
  subroutine csv_file_read_matrix(f, mat)
    type(csv_file_t), intent(inout) :: f
    type(matrix_t), intent(inout) :: mat
    integer :: ierr, file_unit, i, n_lines
    character(len=80) :: tmp
 
    n_lines = f%count_lines()
 
    open(file = trim(f%get_fname()), status = 'old', newunit = file_unit, &
         iostat = ierr)
    if (ierr .ne. 0) then
       call neko_error("Error while opening " // trim(f%get_fname()))
    end if
 
    ! If the number of lines is larger than the number of rows in the
    ! matrix, assume that means there is a header
    if (n_lines .gt. mat%get_nrows()) then
       read (file_unit, '(A)') tmp
       f%header = trim(tmp)
    end if
 
    do i = 1, mat%get_nrows()
       read (file_unit,*) mat%x(i,:)
    end do
    close(unit = file_unit)
 
  end subroutine csv_file_read_matrix
 
  subroutine csv_file_set_header(this, hd)
    class(csv_file_t), intent(inout) :: this
    character(len=*), intent(in) :: hd
 
    this%header = trim(hd)
 
  end subroutine csv_file_set_header
 
  function csv_file_count_lines(this) result(n)
    class(csv_file_t), intent(in) :: this
 
    integer :: n
    integer :: ierr, file_unit
 
    call this%check_exists()
 
    open(file = trim(this%get_fname()), status = 'old', newunit = file_unit, &
         iostat = ierr)
    if (ierr .ne. 0) then
       call neko_error("Error while opening " // trim(this%get_fname()))
    end if
    rewind(file_unit)
 
    n = 0
 
    ! Keep reading (ierr = 0) until we reach the end (ierr != 0)
    do
       read (file_unit, *, iostat = ierr)
       if (ierr .ne. 0) exit
       n = n + 1
    end do
    rewind(file_unit)
    close(unit = file_unit)
 
  end function csv_file_count_lines
 
  subroutine csv_file_set_overwrite(this, overwrite)
    class(csv_file_t), intent(inout) :: this
    logical, intent(in) :: overwrite
 
    this%overwrite = overwrite
 
  end subroutine csv_file_set_overwrite
 
end module csv_file