field_dirichlet.f90

Go to the documentation of this file.

! Copyright (c) 2020-2024, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module field_dirichlet
  use num_types, only: rp
  use coefs, only: coef_t
  use dirichlet, only: dirichlet_t
  use bc, only: bc_list_t, bc_t
  use device, only: c_ptr, c_size_t
  use utils, only: split_string
  use field, only : field_t
  use field_list, only : field_list_t
  use math, only: masked_copy
  use device_math, only: device_masked_copy
  use dofmap, only : dofmap_t
  use utils, only: neko_error
  use field_list, only : field_list_t
  implicit none
  private
 
  type, public, extends(bc_t) :: field_dirichlet_t
     type(field_t) :: field_bc
     type(field_list_t) :: field_list
     procedure(field_dirichlet_update), nopass, pointer :: update => null()
   contains
     procedure, pass(this) :: init_field => field_dirichlet_init
     procedure, pass(this) :: apply_scalar => field_dirichlet_apply_scalar
     procedure, pass(this) :: apply_vector => field_dirichlet_apply_vector
     procedure, pass(this) :: apply_vector_dev => field_dirichlet_apply_vector_dev
     procedure, pass(this) :: apply_scalar_dev => field_dirichlet_apply_scalar_dev
     procedure, pass(this) :: free => field_dirichlet_free
 
  end type field_dirichlet_t
 
  abstract interface
     subroutine field_dirichlet_update(dirichlet_field_list, dirichlet_bc_list, coef, t, tstep, which_solver)
       import rp
       import field_list_t
       import bc_list_t
       import coef_t
       type(field_list_t), intent(inout) :: dirichlet_field_list
       type(bc_list_t), intent(inout) :: dirichlet_bc_list
       type(coef_t), intent(inout) :: coef
       real(kind=rp), intent(in) :: t
       integer, intent(in) :: tstep
       character(len=*), intent(in) :: which_solver
     end subroutine field_dirichlet_update
  end interface
 
  public :: field_dirichlet_update
 
contains
 
  subroutine field_dirichlet_init(this, bc_name)
    class(field_dirichlet_t), target, intent(inout) :: this
    character(len=*), intent(in) :: bc_name
 
    call this%field_bc%init(this%dof, bc_name)
    call this%field_list%init(1)
    call this%field_list%assign_to_field(1, this%field_bc)
 
  end subroutine field_dirichlet_init
 
  subroutine field_dirichlet_free(this)
    class(field_dirichlet_t), target, intent(inout) :: this
 
    call this%free_base
    call this%field_bc%free()
    call this%field_list%free()
 
    if (associated(this%update)) then
       this%update => null()
    end if
 
  end subroutine field_dirichlet_free
 
  subroutine field_dirichlet_apply_scalar(this, x, n, t, tstep)
    class(field_dirichlet_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout),  dimension(n) :: x
    real(kind=rp), intent(in), optional :: t
    integer, intent(in), optional :: tstep
 
    if (this%msk(0) .gt. 0) then
       call masked_copy(x, this%field_bc%x, this%msk, n, this%msk(0))
    end if
 
  end subroutine field_dirichlet_apply_scalar
 
  subroutine field_dirichlet_apply_scalar_dev(this, x_d, t, tstep)
    class(field_dirichlet_t), intent(inout), target :: this
    type(c_ptr) :: x_d
    real(kind=rp), intent(in), optional :: t
    integer, intent(in), optional :: tstep
 
    if (this%msk(0) .gt. 0) then
       call device_masked_copy(x_d, this%field_bc%x_d, this%msk_d, &
            this%field_bc%dof%size(), this%msk(0))
    end if
 
  end subroutine field_dirichlet_apply_scalar_dev
 
  subroutine field_dirichlet_apply_vector(this, x, y, z, n, t, tstep)
    class(field_dirichlet_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout),  dimension(n) :: x
    real(kind=rp), intent(inout),  dimension(n) :: y
    real(kind=rp), intent(inout),  dimension(n) :: z
    real(kind=rp), intent(in), optional :: t
    integer, intent(in), optional :: tstep
 
    call neko_error("field_dirichlet cannot apply vector BCs.&
&Use field_dirichlet_vector instead!")
 
  end subroutine field_dirichlet_apply_vector
 
  subroutine field_dirichlet_apply_vector_dev(this, x_d, y_d, z_d, t, tstep)
    class(field_dirichlet_t), intent(inout), target :: this
    type(c_ptr) :: x_d
    type(c_ptr) :: y_d
    type(c_ptr) :: z_d
    real(kind=rp), intent(in), optional :: t
    integer, intent(in), optional :: tstep
 
    call neko_error("field_dirichlet cannot apply vector BCs.&
&Use field_dirichlet_vector instead!")
 
  end subroutine field_dirichlet_apply_vector_dev
 
end module field_dirichlet