scratch_registry.f90

Go to the documentation of this file.

! Copyright (c) 2018-2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module scratch_registry
  use field, only : field_t, field_ptr_t
  use dofmap, only : dofmap_t
  implicit none
  private
 
 
  type, public :: scratch_registry_t
     type(field_ptr_t), private, allocatable :: fields(:)
     logical, private, allocatable :: inuse(:)
     integer, private :: nfields
     integer, private :: nfields_inuse
     integer, private :: expansion_size
     type(dofmap_t), pointer :: dof => null()
   contains
     procedure, private, pass(this) :: expand
     procedure, pass(this) :: free => scratch_registry_free
     procedure, pass(this) :: get_nfields
     procedure, pass(this) :: get_nfields_inuse
     procedure, pass(this) :: get_expansion_size
     procedure, pass(this) :: get_size
     procedure, pass(this) :: get_inuse
     procedure, pass(this) :: request_field
     procedure, pass(this) :: relinquish_field_single
     procedure, pass(this) :: relinquish_field_multiple
     generic :: relinquish_field => relinquish_field_single, &
          relinquish_field_multiple
  end type scratch_registry_t
 
  interface scratch_registry_t
     procedure :: init
  end interface scratch_registry_t
 
  type(scratch_registry_t), public, target :: neko_scratch_registry
 
contains
 
  type(scratch_registry_t) function init(dof, size, expansion_size) result(this)
    type(dofmap_t), target, intent(in) :: dof
    integer, optional, intent(in) :: size
    integer, optional, intent(in) :: expansion_size
    integer :: i
 
    call this%free()
 
    this%dof => dof
 
    if (present(size)) then
       allocate (this%fields(size))
       do i= 1, size
          allocate(this%fields(i)%ptr)
       end do
       allocate (this%inuse(size))
    else
       allocate (this%fields(10))
       allocate (this%inuse(10))
    end if
 
    this%inuse(:) = .false.
    if (present(expansion_size)) then
       this%expansion_size = expansion_size
    else
       this%expansion_size = 10
    end if
 
    this%nfields = 0
    this%nfields_inuse = 0
  end function init
 
  subroutine scratch_registry_free(this)
    class(scratch_registry_t), intent(inout):: this
    integer :: i
 
    if (allocated(this%fields)) then
       do i=1, this%nfields
          call this%fields(i)%ptr%free()
          deallocate(this%fields(i)%ptr)
       end do
 
       deallocate(this%fields)
       deallocate(this%inuse)
    end if
 
    if (associated(this%dof)) then
       nullify(this%dof)
    end if
 
  end subroutine scratch_registry_free
 
 
  pure function get_nfields(this) result(n)
    class(scratch_registry_t), intent(in) :: this
    integer :: n
 
    n = this%nfields
  end function get_nfields
 
  pure function get_nfields_inuse(this) result(n)
    class(scratch_registry_t), intent(in) :: this
    integer :: n, i
 
    n = 0
    do i=1,this%get_size()
       if (this%inuse(i)) n = n + 1
    end do
  end function get_nfields_inuse
 
  pure function get_size(this) result(n)
    class(scratch_registry_t), intent(in) :: this
    integer :: n
 
    n = size(this%fields)
  end function get_size
 
  pure function get_expansion_size(this) result(n)
    class(scratch_registry_t), intent(in) :: this
    integer :: n
 
    n = this%expansion_size
  end function get_expansion_size
 
  subroutine expand(this)
    class(scratch_registry_t), intent(inout) :: this
    type(field_ptr_t), allocatable :: temp(:)
    logical, allocatable :: temp2(:)
    integer :: i
 
    allocate(temp(this%get_size() + this%expansion_size))
    temp(1:this%nfields) = this%fields(1:this%nfields)
 
    do i=this%nfields +1, size(temp)
       allocate(temp(i)%ptr)
    enddo
 
    call move_alloc(temp, this%fields)
 
    allocate(temp2(this%get_size() + this%expansion_size))
    temp2(1:this%nfields) = this%inuse(1:this%nfields)
    temp2(this%nfields+1:) = .false.
    this%inuse = temp2
  end subroutine expand
 
 
  subroutine request_field(this, f, index)
    class(scratch_registry_t), target, intent(inout) :: this
    type(field_t), pointer, intent(inout) :: f
    integer, intent(inout) :: index
    character(len=10) :: name
 
 
    associate(nfields => this%nfields, nfields_inuse => this%nfields_inuse)
 
      do index=1,this%get_size()
         if (this%inuse(index) .eqv. .false.) then
            write (name, "(A3,I0.3)") "wrk", index
 
            if (.not. allocated(this%fields(index)%ptr%x)) then
               call this%fields(index)%ptr%init(this%dof, trim(name))
               nfields = nfields + 1
            end if
            f => this%fields(index)%ptr
            this%inuse(index) = .true.
            this%nfields_inuse = this%nfields_inuse + 1
            return
         end if
      end do
      ! all existing fields in use, we need to expand to add a new one
      index = nfields +1
      call this%expand()
      nfields = nfields + 1
      nfields_inuse = nfields_inuse + 1
      this%inuse(nfields) = .true.
      write (name, "(A3,I0.3)") "wrk", index
      call this%fields(nfields)%ptr%init(this%dof, trim(name))
      f => this%fields(nfields)%ptr
 
    end associate
  end subroutine request_field
 
  subroutine relinquish_field_single(this, index)
    class(scratch_registry_t), target, intent(inout) :: this
    integer, intent(inout) :: index
 
    this%inuse(index) = .false.
    this%nfields_inuse = this%nfields_inuse - 1
  end subroutine relinquish_field_single
 
  subroutine relinquish_field_multiple(this, indices)
    class(scratch_registry_t), target, intent(inout) :: this
    integer, intent(inout) :: indices(:)
    integer :: i
 
    do i=1, size(indices)
       this%inuse(indices(i)) = .false.
    end do
    this%nfields_inuse = this%nfields_inuse - size(indices)
  end subroutine relinquish_field_multiple
 
  logical function get_inuse(this, index)
    class(scratch_registry_t), target, intent(inout) :: this
    integer, intent(inout) :: index
 
    get_inuse = this%inuse(index)
  end function get_inuse
 
end module scratch_registry