krylov_fctry.f90

Go to the documentation of this file.

! Copyright (c) 2021-2025, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
submodule(krylov) krylov_fctry
  use cg, only : cg_t
  use cg_sx, only : sx_cg_t
  use cg_cpld, only : cg_cpld_t
  use cg_device, only : cg_device_t
  use cg_cpld_device, only : cg_cpld_device_t
  use cacg, only : cacg_t
  use pipecg, only : pipecg_t
  use pipecg_sx, only : sx_pipecg_t
  use pipecg_device, only : pipecg_device_t
  use fusedcg_device, only : fusedcg_device_t
  use fusedcg_cpld_device, only : fusedcg_cpld_device_t
  use bicgstab, only : bicgstab_t
  use bicgstab_cpld, only : bicgstab_cpld_t
  use bicgstab_device, only : bicgstab_device_t
  use gmres, only : gmres_t
  use cheby, only : cheby_t
  use cheby_device, only : cheby_device_t
  use gmres_sx, only : sx_gmres_t
  use gmres_device, only : gmres_device_t
  use num_types, only : rp
  use precon, only : pc_t
  use utils, only : neko_type_error, neko_type_registration_error
  use neko_config, only : neko_bcknd_sx, neko_bcknd_opencl, neko_bcknd_metal
  implicit none
 
  ! List of all possible types created by the factory routine
  character(len=20) :: KSP_KNOWN_TYPES(10) = [character(len=20) :: &
       "cg", &
       "pipecg", &
       "fused_cg", &
       "cacg", &
       "gmres", &
       "cheby", &
       "bicgstab", &
       "coupled_bicgstab", &
       "fused_coupled_cg", &
       "coupled_cg"]
 
contains
 
  module subroutine krylov_solver_factory(object, n, type_name, &
       max_iter, abstol, m, monitor)
    class(ksp_t), allocatable, intent(inout) :: object
    integer, intent(in), value :: n
    character(len=*), intent(in) :: type_name
    integer, intent(in) :: max_iter
    real(kind=rp), optional :: abstol
    class(pc_t), optional, intent(in), target :: M
    logical, optional, intent(in) :: monitor
 
    call krylov_solver_allocator(object, type_name)
 
    call object%init(n, max_iter, m = m, abs_tol = abstol, monitor = monitor)
 
  end subroutine krylov_solver_factory
 
  module subroutine krylov_solver_allocator(object, type_name)
    class(ksp_t), allocatable, intent(inout) :: object
    character(len=*), intent(in) :: type_name
    integer :: i
 
    if (allocated(object)) then
       call object%free()
       deallocate(object)
    end if
 
    select case (trim(type_name))
    case ('cg')
       if (neko_bcknd_sx .eq. 1) then
          allocate(sx_cg_t::object)
       else if (neko_bcknd_device .eq. 1) then
          allocate(cg_device_t::object)
       else
          allocate(cg_t::object)
       end if
 
    case ('coupled_cg')
       if (neko_bcknd_device .eq. 1) then
          allocate(cg_cpld_device_t::object)
       else
          allocate(cg_cpld_t::object)
       end if
 
    case ('pipecg')
       if (neko_bcknd_sx .eq. 1) then
          allocate(sx_pipecg_t::object)
       else if (neko_bcknd_device .eq. 1) then
          if (neko_bcknd_opencl .eq. 1 .or. neko_bcknd_metal .eq. 1) then
             call neko_error('PipeCG not supported for OpenCL/Metal')
          end if
          allocate(pipecg_device_t::object)
       else
          allocate(pipecg_t::object)
       end if
 
    case ('fused_cg')
       if (neko_bcknd_device .eq. 1) then
          if (neko_bcknd_opencl .eq. 1 .or. neko_bcknd_metal .eq. 1) then
             call neko_error('FusedCG not supported for OpenCL/Metal')
          end if
          allocate(fusedcg_device_t::object)
       else
          call neko_error('FusedCG only supported for CUDA/HIP')
       end if
 
    case ('fused_coupled_cg')
       if (neko_bcknd_device .eq. 1) then
          if (neko_bcknd_opencl .eq. 1 .or. neko_bcknd_metal .eq. 1) then
             call neko_error('Coupled FusedCG not supported for OpenCL/Metal')
          end if
          allocate(fusedcg_cpld_device_t::object)
       else
          call neko_error('Coupled FusedCG only supported for CUDA/HIP')
       end if
 
    case ('cacg')
       allocate(cacg_t::object)
 
    case ('gmres')
       if (neko_bcknd_sx .eq. 1) then
          allocate(sx_gmres_t::object)
       else if (neko_bcknd_device .eq. 1) then
          allocate(gmres_device_t::object)
       else
          allocate(gmres_t::object)
       end if
 
    case ('cheby')
       if (neko_bcknd_device .eq. 1) then
          allocate(cheby_device_t::object)
       else
          allocate(cheby_t::object)
       end if
 
    case ('bicgstab')
       if (neko_bcknd_device .eq. 1) then
          allocate(bicgstab_device_t::object)
       else
          allocate(bicgstab_t::object)
       end if
 
    case ('coupled_bicgstab')
       if (neko_bcknd_device .eq. 1) then
          call neko_error('Coupled BiCGStab is not supported on devices')
       else
          allocate(bicgstab_cpld_t::object)
       end if
 
    case default
       do i = 1, krylov_registry_size
          if (trim(type_name) .eq. trim(krylov_registry(i)%type_name)) then
             call krylov_registry(i)%allocator(object)
             return
          end if
       end do
 
       call neko_type_error('Krylov solver', type_name, ksp_known_types)
    end select
 
  end subroutine krylov_solver_allocator
 
  module subroutine register_krylov(type_name, allocator)
    character(len=*), intent(in) :: type_name
    procedure(krylov_allocate), pointer, intent(in) :: allocator
    type(krylov_allocator_entry), allocatable :: temp(:)
    integer :: i
 
    do i = 1, size(ksp_known_types)
       if (trim(type_name) .eq. trim(ksp_known_types(i))) then
          call neko_type_registration_error("Krylov solver", type_name, &
               .true.)
       end if
    end do
 
    do i = 1, krylov_registry_size
       if (trim(type_name) .eq. trim(krylov_registry(i)%type_name)) then
          call neko_type_registration_error("Krylov solver", type_name, &
               .false.)
       end if
    end do
 
    if (krylov_registry_size .eq. 0) then
       allocate(krylov_registry(1))
    else
       allocate(temp(krylov_registry_size + 1))
       temp(1:krylov_registry_size) = krylov_registry
       call move_alloc(temp, krylov_registry)
    end if
 
    krylov_registry_size = krylov_registry_size + 1
    krylov_registry(krylov_registry_size)%type_name = type_name
    krylov_registry(krylov_registry_size)%allocator => allocator
  end subroutine register_krylov
 
end submodule krylov_fctry