cg_coupled.f90

Go to the documentation of this file.

! Copyright (c) 2024-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module cg_cpld
  use num_types, only : rp, xp
  use krylov, only : ksp_t, ksp_monitor_t, ksp_max_iter
  use precon, only : pc_t
  use ax_product, only : ax_t
  use field, only : field_t
  use coefs, only : coef_t
  use gather_scatter, only : gs_t, gs_op_add
  use scalar_bc_projector, only : scalar_bc_projector_t
  use vector_bc_projector, only : vector_bc_projector_t
  use scratch_registry, only : neko_scratch_registry
  use math, only : abscmp
  use comm, only : mpi_extra_precision, neko_comm
  use mpi_f08, only : mpi_allreduce, mpi_in_place, mpi_sum
  use utils, only : neko_error
  use operators, only : rotate_cyc
  implicit none
  private
 
  type, public, extends(ksp_t) :: cg_cpld_t
     real(kind=rp), pointer :: w1(:) => null()
     real(kind=rp), pointer :: w2(:) => null()
     real(kind=rp), pointer :: w3(:) => null()
     real(kind=rp), pointer :: r1(:) => null()
     real(kind=rp), pointer :: r2(:) => null()
     real(kind=rp), pointer :: r3(:) => null()
     real(kind=rp), pointer :: p1(:) => null()
     real(kind=rp), pointer :: p2(:) => null()
     real(kind=rp), pointer :: p3(:) => null()
     real(kind=rp), pointer :: z1(:) => null()
     real(kind=rp), pointer :: z2(:) => null()
     real(kind=rp), pointer :: z3(:) => null()
   contains
     procedure, pass(this) :: init => cg_cpld_init
     procedure, pass(this) :: free => cg_cpld_free
     procedure, pass(this) :: solve => cg_cpld_nop
     procedure, pass(this) :: solve_coupled => cg_cpld_solve
  end type cg_cpld_t
 
contains
 
  subroutine cg_cpld_init(this, n, max_iter, M, rel_tol, abs_tol, monitor)
    class(cg_cpld_t), target, intent(inout) :: this
    integer, intent(in) :: max_iter
    class(pc_t), optional, intent(in), target :: M
    integer, intent(in) :: n
    real(kind=rp), optional, intent(in) :: rel_tol
    real(kind=rp), optional, intent(in) :: abs_tol
    logical, optional, intent(in) :: monitor
 
    call this%free()
 
    if (present(m)) then
       this%M => m
    end if
 
    if (present(rel_tol) .and. present(abs_tol) .and. present(monitor)) then
       call this%ksp_init(max_iter, rel_tol, abs_tol, monitor = monitor)
    else if (present(rel_tol) .and. present(abs_tol)) then
       call this%ksp_init(max_iter, rel_tol, abs_tol)
    else if (present(monitor) .and. present(abs_tol)) then
       call this%ksp_init(max_iter, abs_tol = abs_tol, monitor = monitor)
    else if (present(rel_tol) .and. present(monitor)) then
       call this%ksp_init(max_iter, rel_tol, monitor = monitor)
    else if (present(rel_tol)) then
       call this%ksp_init(max_iter, rel_tol = rel_tol)
    else if (present(abs_tol)) then
       call this%ksp_init(max_iter, abs_tol = abs_tol)
    else if (present(monitor)) then
       call this%ksp_init(max_iter, monitor = monitor)
    else
       call this%ksp_init(max_iter)
    end if
 
  end subroutine cg_cpld_init
 
  subroutine cg_cpld_free(this)
    class(cg_cpld_t), intent(inout) :: this
 
    call this%ksp_free()
 
    nullify(this%w1, this%w2, this%w3)
    nullify(this%r1, this%r2, this%r3)
    nullify(this%p1, this%p2, this%p3)
    nullify(this%z1, this%z2, this%z3)
 
    nullify(this%M)
 
  end subroutine cg_cpld_free
 
  function cg_cpld_nop(this, Ax, x, f, n, coef, bc_projector, gs_h, niter) &
       result(ksp_results)
    class(cg_cpld_t), intent(inout) :: this
    class(ax_t), intent(in) :: ax
    type(field_t), intent(inout) :: x
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(in) :: f
    type(coef_t), intent(inout) :: coef
    class(scalar_bc_projector_t), intent(inout) :: bc_projector
    type(gs_t), intent(inout) :: gs_h
    type(ksp_monitor_t) :: ksp_results
    integer, optional, intent(in) :: niter
 
    call neko_error('The cpldcg solver is only defined for coupled solves')
 
    ksp_results%res_final = 0.0
    ksp_results%iter = 0
  end function cg_cpld_nop
 
  function cg_cpld_solve(this, Ax, x, y, z, fx, fy, fz, &
       n, coef, bc_projector, gs_h, niter) result(ksp_results)
    class(cg_cpld_t), intent(inout) :: this
    class(ax_t), intent(in) :: ax
    type(field_t), intent(inout) :: x
    type(field_t), intent(inout) :: y
    type(field_t), intent(inout) :: z
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(in) :: fx
    real(kind=rp), dimension(n), intent(in) :: fy
    real(kind=rp), dimension(n), intent(in) :: fz
    type(coef_t), intent(inout) :: coef
    class(vector_bc_projector_t), intent(inout) :: bc_projector
    type(gs_t), intent(inout) :: gs_h
    type(ksp_monitor_t), dimension(3) :: ksp_results
    integer, optional, intent(in) :: niter
    integer :: i, iter, max_iter, ierr
    real(kind=rp) :: rnorm, rtr, rtr0, rtz2, rtz1
    real(kind=rp) :: beta, pap, alpha, norm_fac
    real(kind=xp) :: tmp_xp, r1_xp, r2_xp, r3_xp, mult_xp
    integer :: temp_indices(12)
 
    if (present(niter)) then
       max_iter = niter
    else
       max_iter = this%max_iter
    end if
    norm_fac = 1.0_rp / sqrt(coef%volume)
 
    call neko_scratch_registry%request(this%w1, temp_indices(1), n, .false.)
    call neko_scratch_registry%request(this%w2, temp_indices(2), n, .false.)
    call neko_scratch_registry%request(this%w3, temp_indices(3), n, .false.)
    call neko_scratch_registry%request(this%r1, temp_indices(4), n, .false.)
    call neko_scratch_registry%request(this%r2, temp_indices(5), n, .false.)
    call neko_scratch_registry%request(this%r3, temp_indices(6), n, .false.)
    call neko_scratch_registry%request(this%p1, temp_indices(7), n, .false.)
    call neko_scratch_registry%request(this%p2, temp_indices(8), n, .false.)
    call neko_scratch_registry%request(this%p3, temp_indices(9), n, .false.)
    call neko_scratch_registry%request(this%z1, temp_indices(10), n, .false.)
    call neko_scratch_registry%request(this%z2, temp_indices(11), n, .false.)
    call neko_scratch_registry%request(this%z3, temp_indices(12), n, .false.)
 
    associate(p1 => this%p1, p2 => this%p2, p3 => this%p3, z1 => this%z1, &
         z2 => this%z2, z3 => this%z3, r1 => this%r1, r2 => this%r2, &
         r3 => this%r3, w1 => this%w1, w2 => this%w2, w3 => this%w3)
 
      rtz1 = 1.0_rp
      tmp_xp = 0.0_xp
      !$omp parallel do reduction(+:tmp_xp)
      do i = 1, n
         x%x(i,1,1,1) = 0.0_rp
         y%x(i,1,1,1) = 0.0_rp
         z%x(i,1,1,1) = 0.0_rp
         p1(i) = 0.0_rp
         p2(i) = 0.0_rp
         p3(i) = 0.0_rp
         z1(i) = 0.0_rp
         z2(i) = 0.0_rp
         z3(i) = 0.0_rp
         r1(i) = fx(i)
         r2(i) = fy(i)
         r3(i) = fz(i)
         tmp_xp = tmp_xp + (r1(i)**2 + r2(i)**2 + r3(i)**2) &
              * coef%mult(i,1,1,1)
      end do
      !$omp end parallel do
 
      call mpi_allreduce(mpi_in_place, tmp_xp, 1, mpi_extra_precision, &
           mpi_sum, neko_comm, ierr)
      rtr = tmp_xp
      rnorm = sqrt(rtr)*norm_fac
      ksp_results%res_start = rnorm
      ksp_results%res_final = rnorm
      ksp_results%iter = 0
      if (abscmp(rnorm, 0.0_rp)) then
         ksp_results%converged = .true.
         nullify(this%w1, this%w2, this%w3)
         nullify(this%r1, this%r2, this%r3)
         nullify(this%p1, this%p2, this%p3)
         nullify(this%z1, this%z2, this%z3)
         call neko_scratch_registry%relinquish_host_array(temp_indices)
         return
      end if
 
      call this%monitor_start('cpldCG')
      do iter = 1, max_iter
         call this%M%solve(z1, this%r1, n)
         call this%M%solve(z2, this%r2, n)
         call this%M%solve(z3, this%r3, n)
         rtz2 = rtz1
 
         tmp_xp = 0.0_xp
         !$omp parallel do reduction(+:tmp_xp)
         do i = 1, n
            tmp_xp = tmp_xp + (z1(i) * r1(i) &
                 + z2(i) * r2(i) &
                 + z3(i) * r3(i)) * coef%mult(i,1,1,1)
         end do
         !$omp end parallel do
 
         call mpi_allreduce(mpi_in_place, tmp_xp, 1, mpi_extra_precision, &
              mpi_sum, neko_comm, ierr)
         rtz1 = tmp_xp
 
         beta = rtz1 / rtz2
         if (iter .eq. 1) beta = 0.0_rp
         !$omp parallel do
         do i = 1, n
            p1(i) = p1(i) * beta + z1(i)
            p2(i) = p2(i) * beta + z2(i)
            p3(i) = p3(i) * beta + z3(i)
         end do
         !$omp end parallel do
 
         call ax%compute_vector(w1, w2, w3, p1, p2, p3, coef, x%msh, x%Xh)
 
         call rotate_cyc(w1, w2, w3, 1, coef)
         call gs_h%op(w1, w2, w3, n, gs_op_add)
         call rotate_cyc(w1, w2, w3, 0, coef)
 
         call bc_projector%apply(w1, w2, w3, n)
 
         tmp_xp = 0.0_xp
         !$omp parallel do reduction(+:tmp_xp)
         do i = 1, n
            tmp_xp = tmp_xp + (w1(i) * p1(i) &
                 + w2(i) * p2(i) &
                 + w3(i) * p3(i)) * coef%mult(i,1,1,1)
         end do
         !$omp end parallel do
 
         call mpi_allreduce(mpi_in_place, tmp_xp, 1, mpi_extra_precision, &
              mpi_sum, neko_comm, ierr)
         pap = tmp_xp
 
         alpha = rtz1 / pap
         tmp_xp = 0.0_xp
 
         !$omp parallel private (i, r1_xp, r2_xp, r3_xp, mult_xp)
         !$omp do
         do i = 1, n
            x%x(i,1,1,1) = x%x(i,1,1,1) + alpha * p1(i)
            y%x(i,1,1,1) = y%x(i,1,1,1) + alpha * p2(i)
            z%x(i,1,1,1) = z%x(i,1,1,1) + alpha * p3(i)
         end do
         !$omp end do nowait
 
         !$omp do reduction(+:tmp_xp)
         do i = 1, n
            r1(i) = r1(i) - alpha * w1(i)
            r2(i) = r2(i) - alpha * w2(i)
            r3(i) = r3(i) - alpha * w3(i)
            r1_xp = real(r1(i), kind=xp)
            r2_xp = real(r2(i), kind=xp)
            r3_xp = real(r3(i), kind=xp)
            mult_xp = real(coef%mult(i,1,1,1), kind=xp)
            tmp_xp = tmp_xp + &
                 (r1_xp * r1_xp + r2_xp * r2_xp + r3_xp * r3_xp) * mult_xp
         end do
         !$omp end do nowait
         !$omp end parallel
 
         call mpi_allreduce(mpi_in_place, tmp_xp, 1, mpi_extra_precision, &
              mpi_sum, neko_comm, ierr)
         rtr = tmp_xp
 
         if (iter .eq. 1) rtr0 = rtr
         rnorm = sqrt(rtr) * norm_fac
         call this%monitor_iter(iter, rnorm)
         if (rnorm .lt. this%abs_tol) then
            exit
         end if
      end do
    end associate
    nullify(this%w1, this%w2, this%w3)
    nullify(this%r1, this%r2, this%r3)
    nullify(this%p1, this%p2, this%p3)
    nullify(this%z1, this%z2, this%z3)
    call neko_scratch_registry%relinquish_host_array(temp_indices)
    call this%monitor_stop()
    ksp_results%res_final = rnorm
    ksp_results%iter = iter
    ksp_results%converged = this%is_converged(iter, rnorm)
  end function cg_cpld_solve
 
end module cg_cpld