field.f90

Go to the documentation of this file.

! Copyright (c) 2018-2025, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module field
  use neko_config, only : neko_bcknd_device
  use device_math, only : device_add2, device_cadd, device_cfill, device_copy
  use num_types, only : rp, c_rp
  use device, only : device_map, device_free, device_memset, device_memcpy
  use math, only : add2, copy, cadd, cfill
  use mesh, only : mesh_t
  use space, only : space_t, operator(.ne.)
  use dofmap, only : dofmap_t
  use, intrinsic :: iso_c_binding
  implicit none
  private
 
  type, public :: field_t
     real(kind=rp), allocatable :: x(:,:,:,:) 
 
     type(space_t), pointer :: xh
     type(mesh_t), pointer :: msh
     type(dofmap_t), pointer :: dof
 
     logical :: internal_dofmap = .false. 
     character(len=80) :: name = ""
     type(c_ptr) :: x_d = c_null_ptr
   contains
     procedure, private, pass(this) :: init_common => field_init_common
     procedure, private, pass(this) :: init_external_dof => &
          field_init_external_dof
     procedure, private, pass(this) :: init_internal_dof => &
          field_init_internal_dof
     procedure, private, pass(this) :: assign_field => field_assign_field
     procedure, private, pass(this) :: assign_scalar => field_assign_scalar
     procedure, private, pass(this) :: add_field => field_add_field
     procedure, private, pass(this) :: add_scalar => field_add_scalar
     procedure, pass(this) :: copy_from => field_copy_from
     procedure, pass(this) :: free => field_free
     procedure, pass(this) :: size => field_size
     generic :: init => init_external_dof, init_internal_dof
     generic :: assignment(=) => assign_field, assign_scalar
     generic :: add => add_field, add_scalar
  end type field_t
 
  type, public :: field_ptr_t
     type(field_t), pointer :: ptr => null()
   contains
     procedure, pass(this) :: init => field_ptr_init
     procedure, pass(this) :: free => field_ptr_free
  end type field_ptr_t
 
  type, public :: field_wrapper_t
     type(field_t), pointer :: field => null()
   contains
     generic :: init => init_field, init_internal_dof, init_external_dof
     procedure, pass(this) :: init_field => field_wrapper_init_field
     procedure, pass(this) :: init_internal_dof => &
          field_wrapper_init_internal_dof
     procedure, pass(this) :: init_external_dof => &
          field_wrapper_init_external_dof
     procedure, pass(this) :: free => field_wrapper_free
  end type field_wrapper_t
 
contains
 
  subroutine field_init_internal_dof(this, msh, space, fld_name)
    class(field_t), intent(inout) :: this
    type(mesh_t), target, intent(in) :: msh
    type(space_t), target, intent(in) :: space
    character(len=*), optional :: fld_name
 
    call this%free()
 
    this%Xh => space
    this%msh => msh
 
    allocate(this%dof)
    call this%dof%init(this%msh, this%Xh)
    this%internal_dofmap = .true.
 
    if (present(fld_name)) then
       call this%init_common(fld_name)
    else
       call this%init_common()
    end if
 
  end subroutine field_init_internal_dof
 
  subroutine field_init_external_dof(this, dof, fld_name)
    class(field_t), intent(inout) :: this
    type(dofmap_t), target, intent(in) :: dof
    character(len=*), optional :: fld_name
 
    call this%free()
 
    this%dof => dof
    this%Xh => dof%Xh
    this%msh => dof%msh
 
    if (present(fld_name)) then
       call this%init_common(fld_name)
    else
       call this%init_common()
    end if
 
  end subroutine field_init_external_dof
 
  subroutine field_init_common(this, fld_name)
    class(field_t), intent(inout) :: this
    character(len=*), optional :: fld_name
    integer :: ierr
    integer :: n
 
    associate(lx => this%Xh%lx, ly => this%Xh%ly, &
         lz => this%Xh%lz, nelv => this%msh%nelv)
 
      if (.not. allocated(this%x)) then
         allocate(this%x(lx, ly, lz, nelv), stat = ierr)
         this%x = 0.0_rp
      end if
 
      if (present(fld_name)) then
         this%name = fld_name
      else
         this%name = "Field"
      end if
 
      if (neko_bcknd_device .eq. 1) then
         n = lx * ly * lz * nelv
         call device_map(this%x, this%x_d, n)
         block
           real(c_rp) :: rp_dummy
           integer(c_size_t) :: s
           s = c_sizeof(rp_dummy) * n
           call device_memset(this%x_d, 0, s, sync = .true.)
         end block
      end if
    end associate
 
  end subroutine field_init_common
 
  subroutine field_free(this)
    class(field_t), intent(inout) :: this
 
    this%name = ""
    if (allocated(this%x)) then
       deallocate(this%x)
    end if
 
    if (this%internal_dofmap) then
       call this%dof%free()
       deallocate(this%dof)
       this%internal_dofmap = .false.
    end if
 
    nullify(this%msh)
    nullify(this%Xh)
    nullify(this%dof)
 
    if (c_associated(this%x_d)) then
       call device_free(this%x_d)
    end if
 
  end subroutine field_free
 
  subroutine field_copy_from(this, memdir, sync)
    class(field_t), intent(inout) :: this
    integer, intent(in) :: memdir
    logical, intent(in) :: sync
 
    if (neko_bcknd_device .eq. 1) then
       call device_memcpy(this%x, this%x_d, this%size(), memdir, sync)
    end if
 
  end subroutine field_copy_from
 
 
  subroutine field_assign_field(this, g)
    class(field_t), intent(inout) :: this
    type(field_t), intent(in) :: g
 
    if (allocated(this%x)) then
       if (.not. associated(this%Xh, g%Xh)) then
          call this%free()
       end if
    end if
 
    this%Xh => g%Xh
    this%msh => g%msh
    if (len_trim(this%name) == 0) then
       this%name = g%name
    end if
 
    if (.not. g%internal_dofmap) then
       this%dof => g%dof
    else
       if (this%internal_dofmap) then
          call this%dof%free()
       else
          allocate(this%dof)
          this%internal_dofmap = .true.
       end if
       call this%dof%init(this%msh, this%Xh)
    end if
 
    if (.not. allocated(this%x)) then
 
       allocate(this%x(this%Xh%lx, this%Xh%ly, this%Xh%lz, this%msh%nelv))
 
       if (neko_bcknd_device .eq. 1) then
          call device_map(this%x, this%x_d, this%size())
       end if
 
    end if
 
    if (neko_bcknd_device .eq. 1) then
       call device_copy(this%x_d, g%x_d, this%size())
    else
       call copy(this%x, g%x, this%dof%size())
    end if
 
  end subroutine field_assign_field
 
  subroutine field_assign_scalar(this, a)
    class(field_t), intent(inout) :: this
    real(kind=rp), intent(in) :: a
 
    if (neko_bcknd_device .eq. 1) then
       call device_cfill(this%x_d, a, this%size())
    else
       call cfill(this%x, a, this%size())
    end if
 
  end subroutine field_assign_scalar
 
  subroutine field_add_field(this, g)
    class(field_t), intent(inout) :: this
    type(field_t), intent(in) :: g
 
    if (neko_bcknd_device .eq. 1) then
       call device_add2(this%x_d, g%x_d, this%size())
    else
       call add2(this%x, g%x, this%size())
    end if
 
  end subroutine field_add_field
 
 
  subroutine field_add_scalar(this, a)
    class(field_t), intent(inout) :: this
    real(kind=rp), intent(in) :: a
 
    if (neko_bcknd_device .eq. 1) then
       call device_cadd(this%x_d, a, this%size())
    else
       call cadd(this%x, a, this%size())
    end if
 
  end subroutine field_add_scalar
 
  pure function field_size(this) result(size)
    class(field_t), intent(in) :: this
    integer :: size
 
    size = this%dof%size()
  end function field_size
 
  ! ========================================================================== !
  ! Field pointer type subroutines
 
  subroutine field_ptr_init(this, ptr)
    class(field_ptr_t), intent(inout) :: this
    type(field_t), target, intent(in) :: ptr
 
    call this%free()
 
    this%ptr => ptr
 
  end subroutine field_ptr_init
 
  subroutine field_ptr_free(this)
    class(field_ptr_t), intent(inout) :: this
 
    if (associated(this%ptr)) then
       nullify(this%ptr)
    end if
 
  end subroutine field_ptr_free
 
  ! ========================================================================== !
  ! Field wrapper type subroutines
 
  subroutine field_wrapper_init_field(this, f)
    class(field_wrapper_t), intent(inout) :: this
    type(field_t), intent(in) :: f
 
    call this%free()
    allocate(this%field)
    this%field = f
 
  end subroutine field_wrapper_init_field
 
  subroutine field_wrapper_init_internal_dof(this, msh, space, fld_name)
    class(field_wrapper_t), intent(inout) :: this
    type(mesh_t), target, intent(in) :: msh
    type(space_t), target, intent(in) :: space
    character(len=*), optional :: fld_name
 
    call this%free()
    allocate(this%field)
    call this%field%init(msh, space, fld_name)
 
  end subroutine field_wrapper_init_internal_dof
 
  subroutine field_wrapper_init_external_dof(this, dof, fld_name)
    class(field_wrapper_t), intent(inout) :: this
    type(dofmap_t), target, intent(in) :: dof
    character(len=*), optional :: fld_name
 
    call this%free()
    allocate(this%field)
    call this%field%init(dof, fld_name)
 
  end subroutine field_wrapper_init_external_dof
 
  subroutine field_wrapper_free(this)
    class(field_wrapper_t), intent(inout) :: this
 
    if (associated(this%field)) then
       call this%field%free()
       deallocate(this%field)
    end if
 
  end subroutine field_wrapper_free
 
end module field