avm.f90

Go to the documentation of this file.

! Copyright (c) 2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
module artificial_viscosity_model
  use num_types, only : rp
  use case, only : case_t
  use field, only : field_t
  use json_module, only : json_file
  use registry, only : neko_registry
  use coefs, only : coef_t
  use dofmap, only : dofmap_t
  use time_state, only : time_state_t
  implicit none
  private
 
  type, abstract, public :: avm_t
     type(field_t), pointer :: reg_coeff => null()
     type(coef_t), pointer :: coef => null()
     type(dofmap_t), pointer :: dof => null()
     integer :: les_model_registry_size = 0
   contains
     procedure, pass(this) :: init_base => avm_init_base
     procedure, pass(this) :: free_base => avm_free_base
     procedure(avm_init), pass(this), deferred :: init
     procedure(avm_free), pass(this), deferred :: free
     procedure(avm_preprocess), pass(this), deferred :: preprocess
     procedure(avm_compute), pass(this), deferred :: compute
     procedure, pass(this) :: restart => avm_restart
  end type avm_t
 
  abstract interface
 
     subroutine avm_preprocess(this, time)
       import avm_t, time_state_t
       class(avm_t), intent(inout) :: this
       type(time_state_t), intent(in) :: time
     end subroutine avm_preprocess
  end interface
 
  abstract interface
 
     subroutine avm_compute(this, time)
       import avm_t, time_state_t
       class(avm_t), intent(inout) :: this
       type(time_state_t), intent(in) :: time
     end subroutine avm_compute
  end interface
 
  abstract interface
 
     subroutine avm_init(this, case, json)
       import avm_t, json_file, case_t
       class(avm_t), intent(inout) :: this
       class(case_t), intent(inout), target :: case
       type(json_file), intent(inout) :: json
     end subroutine avm_init
  end interface
 
  abstract interface
 
     subroutine avm_free(this)
       import avm_t
       class(avm_t), intent(inout) :: this
     end subroutine avm_free
  end interface
 
  interface
 
     module subroutine avm_allocator(object, type_name)
       class(avm_t), allocatable, intent(inout) :: object
       character(len=*), intent(in) :: type_name
     end subroutine avm_allocator
  end interface
 
  !
  ! Machinery for injecting user-defined types
  !
 
  abstract interface
 
     subroutine avm_allocate(obj)
       import avm_t
       class(avm_t), allocatable, intent(inout) :: obj
     end subroutine avm_allocate
  end interface
 
  interface
 
     module subroutine register_avm(type_name, allocator)
       character(len=*), intent(in) :: type_name
       procedure(avm_allocate), pointer, intent(in) :: allocator
     end subroutine register_avm
  end interface
 
  type allocator_entry
     character(len=20) :: type_name
     procedure(avm_allocate), pointer, nopass :: allocator
  end type allocator_entry
 
  type(allocator_entry), allocatable :: avm_registry(:)
 
  integer :: avm_registry_size = 0
 
 
 
  interface
 
     module subroutine avm_factory(object, type_name, case, json)
       class(avm_t), allocatable, intent(inout) :: object
       character(len=*), intent(in) :: type_name
       class(case_t), intent(inout), target :: case
       type(json_file), intent(inout) :: json
     end subroutine avm_factory
  end interface
 
  public :: avm_factory, avm_allocator, register_avm, &
       avm_allocate
 
 
contains
  subroutine avm_init_base(this, dof, coef, reg_coeff_name)
    class(avm_t), intent(inout) :: this
    class(dofmap_t), intent(in), target :: dof
    class(coef_t), intent(in), target :: coef
    character(len=*), intent(in) :: reg_coeff_name
 
    call this%free_base()
 
    call neko_registry%add_field(dof, trim(reg_coeff_name), .true.)
 
    this%reg_coeff => neko_registry%get_field(trim(reg_coeff_name))
    this%coef => coef
    this%dof => dof
 
  end subroutine avm_init_base
 
  subroutine avm_restart(this, time)
    class(avm_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
 
    call this%compute(time)
 
  end subroutine avm_restart
 
  subroutine avm_free_base(this)
    class(avm_t), intent(inout) :: this
 
    nullify(this%reg_coeff)
    nullify(this%coef)
    nullify(this%dof)
 
  end subroutine avm_free_base
 
end module artificial_viscosity_model