deardorff.f90

Go to the documentation of this file.

! Copyright (c) 2025-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
module deardorff
  use utils, only : neko_error
  use num_types, only : rp
  use field, only : field_t
  use fluid_scheme_base, only : fluid_scheme_base_t
  use les_model, only : les_model_t
  use json_utils, only : json_get_or_default, json_get, json_get_or_lookup
  use json_module, only : json_file
  use neko_config, only : neko_bcknd_device
  use deardorff_cpu, only : deardorff_compute_cpu
  use deardorff_device, only : deardorff_compute_device
  use registry, only : neko_registry
  use logger, only : log_size, neko_log
  implicit none
  private
 
  type, public, extends(les_model_t) :: deardorff_t
     real(kind=rp) :: c_k
     real(kind=rp) :: t0
     real(kind=rp) :: g(3)
     character(len=:), allocatable :: temperature_field_name
     character(len=:), allocatable :: tke_field_name
     type(field_t), pointer :: temperature_alphat => null()
     type(field_t), pointer :: tke_alphat => null()
     type(field_t), pointer :: tke_source => null()
   contains
     procedure, pass(this) :: init => deardorff_init
     procedure, pass(this) :: init_from_components => &
          deardorff_init_from_components
     procedure, pass(this) :: free => deardorff_free
     procedure, pass(this) :: compute => deardorff_compute
  end type deardorff_t
 
contains
  subroutine deardorff_init(this, fluid, json)
    class(deardorff_t), intent(inout) :: this
    class(fluid_scheme_base_t), intent(inout), target :: fluid
    type(json_file), intent(inout) :: json
    character(len=:), allocatable :: temperature_field_name
    character(len=:), allocatable :: TKE_field_name
    character(len=:), allocatable :: nut_name
    character(len=:), allocatable :: temperature_alphat_name, TKE_alphat_name
    character(len=:), allocatable :: TKE_source_name
    character(len=:), allocatable :: delta_type
    real(kind=rp) :: c_k, t0
    real(kind=rp), allocatable :: g(:)
    logical :: if_ext
    character(len=LOG_SIZE) :: log_buf
 
    call json_get_or_default(json, "temperature_field", &
         temperature_field_name, "temperature")
    call json_get_or_default(json, "TKE_field", tke_field_name, "TKE")
    call json_get_or_default(json, "nut_field", nut_name, "nut")
    call json_get_or_default(json, "temperature_alphat_field", &
         temperature_alphat_name, "temperature_alphat")
    call json_get_or_default(json, "TKE_alphat_field", tke_alphat_name, &
         "TKE_alphat")
    call json_get_or_default(json, "TKE_source_field", tke_source_name, &
         "TKE_source")
    call json_get_or_default(json, "delta_type", delta_type, "pointwise")
    call json_get_or_default(json, "c_k", c_k, 0.10_rp)
    call json_get(json, "T0", t0)
    call json_get_or_lookup(json, "g", g)
    if (.not. size(g) == 3) then
       call neko_error("The gravity vector should have 3 components")
    end if
    call json_get_or_default(json, "extrapolation", if_ext, .false.)
 
    if (if_ext) then
       call neko_error("Extrapolation is not implemented for the " // &
            "Deardorff model.")
    end if
 
    call neko_log%section('LES model')
    write(log_buf, '(A)') 'Model : deardorff'
    call neko_log%message(log_buf)
    write(log_buf, '(A, A)') 'Delta evaluation : ', delta_type
    call neko_log%message(log_buf)
    write(log_buf, '(A, E15.7)') 'c_k : ', c_k
    call neko_log%message(log_buf)
    write(log_buf, '(A, L1)') 'extrapolation : ', if_ext
    call neko_log%message(log_buf)
    call neko_log%end_section()
 
    call deardorff_init_from_components(this, fluid, c_k, t0, &
         temperature_field_name, tke_field_name, nut_name, &
         temperature_alphat_name, tke_alphat_name, tke_source_name, g, &
         delta_type, if_ext)
 
    deallocate(temperature_field_name)
    deallocate(tke_field_name)
    deallocate(nut_name)
    deallocate(temperature_alphat_name)
    deallocate(tke_alphat_name)
    deallocate(tke_source_name)
    deallocate(delta_type)
    deallocate(g)
 
  end subroutine deardorff_init
 
  subroutine deardorff_init_from_components(this, fluid, &
       c_k, T0, temperature_field_name, TKE_field_name, nut_name, &
       temperature_alphat_name, TKE_alphat_name, TKE_source_name, g, &
       delta_type, if_ext)
    class(deardorff_t), intent(inout) :: this
    class(fluid_scheme_base_t), intent(inout), target :: fluid
    real(kind=rp), intent(in) :: c_k, t0
    character(len=*), intent(in) :: temperature_field_name
    character(len=*), intent(in) :: TKE_field_name
    character(len=*), intent(in) :: nut_name
    character(len=*), intent(in) :: temperature_alphat_name, TKE_alphat_name
    character(len=*), intent(in) :: TKE_source_name
    real(kind=rp), intent(in) :: g(3)
    character(len=*), intent(in) :: delta_type
    logical, intent(in) :: if_ext
 
    call this%free()
    call this%init_base(fluid, nut_name, delta_type, if_ext)
 
    call neko_registry%add_field(fluid%dm_Xh, &
         trim(temperature_alphat_name), .true.)
    call neko_registry%add_field(fluid%dm_Xh, trim(tke_alphat_name), .true.)
    call neko_registry%add_field(fluid%dm_Xh, trim(tke_source_name), .true.)
 
    this%temperature_alphat => &
         neko_registry%get_field(trim(temperature_alphat_name))
    this%TKE_alphat => neko_registry%get_field(trim(tke_alphat_name))
    this%TKE_source => neko_registry%get_field(trim(tke_source_name))
    this%c_k = c_k
    this%T0 = t0
    this%temperature_field_name = temperature_field_name
    this%TKE_field_name = tke_field_name
    this%g = -g
 
  end subroutine deardorff_init_from_components
 
  subroutine deardorff_free(this)
    class(deardorff_t), intent(inout) :: this
 
    nullify(this%temperature_alphat)
    nullify(this%TKE_alphat)
    nullify(this%TKE_source)
 
    if (allocated(this%temperature_field_name)) then
       deallocate(this%temperature_field_name)
    end if
 
    if (allocated(this%TKE_field_name)) then
       deallocate(this%TKE_field_name)
    end if
 
    call this%free_base()
  end subroutine deardorff_free
 
  subroutine deardorff_compute(this, t, tstep)
    class(deardorff_t), intent(inout) :: this
    real(kind=rp), intent(in) :: t
    integer, intent(in) :: tstep
 
    type(field_t), pointer :: u, v, w, u_e, v_e, w_e
 
    ! Compute the eddy viscosity field
    if (neko_bcknd_device .eq. 1) then
       call deardorff_compute_device(t, tstep, this%coef, &
            this%temperature_field_name, this%TKE_field_name, &
            this%nut, this%temperature_alphat, this%TKE_alphat, &
            this%TKE_source, this%delta, this%c_k, this%T0, this%g)
    else
       call deardorff_compute_cpu(t, tstep, this%coef, &
            this%temperature_field_name, this%TKE_field_name, &
            this%nut, this%temperature_alphat, this%TKE_alphat, &
            this%TKE_source, this%delta, this%c_k, this%T0, this%g)
    end if
 
  end subroutine deardorff_compute
 
end module deardorff