scalar_residual_cpu.f90

Go to the documentation of this file.

 
module scalar_residual_cpu
  use gather_scatter
  use scalar_residual
  use operators
  implicit none
  private
 
  type, public, extends(scalar_residual_t) :: scalar_residual_cpu_t
   contains
     procedure, nopass :: compute => scalar_residual_cpu_compute
  end type scalar_residual_cpu_t
 
contains
 
  subroutine scalar_residual_cpu_compute(Ax, s, s_res, f_Xh, c_Xh, msh, Xh, &
      lambda, rhocp, bd, dt, n)
    class(ax_t), intent(in) :: Ax
    type(mesh_t), intent(inout) :: msh
    type(space_t), intent(inout) :: Xh
    type(field_t), intent(inout) :: s
    type(field_t), intent(inout) :: s_res
    type(field_t), intent(inout) :: f_Xh
    type(coef_t), intent(inout) :: c_Xh
    real(kind=rp), intent(in) :: lambda
    real(kind=rp), intent(in) :: rhocp
    real(kind=rp), intent(in) :: bd
    real(kind=rp), intent(in) :: dt
    integer, intent(in) :: n
    integer :: i
 
    do i = 1, n
       c_xh%h1(i,1,1,1) = lambda
       ! todo :should not be just rho here.
       ! Tim M. 2023-12-19: What is this todo?
       c_xh%h2(i,1,1,1) = rhocp * (bd / dt)
    end do
    c_xh%ifh2 = .true.
 
    call ax%compute(s_res%x, s%x, c_xh, msh, xh)
 
    do i = 1, n
       s_res%x(i,1,1,1) = (-s_res%x(i,1,1,1)) + f_xh%x(i,1,1,1)
    end do
 
  end subroutine scalar_residual_cpu_compute
 
end module scalar_residual_cpu