mean_field.f90

Go to the documentation of this file.

! Copyright (c) 2021-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
module mean_field
  use neko_config, only : neko_bcknd_device
  use stats_quant, only : stats_quant_t
  use num_types, only : rp
  use registry, only : neko_registry
  use field, only : field_t
  use utils, only : neko_varname_len
  use field_math, only : field_cmult, field_add2s2, field_addcol3s2
  implicit none
  private
 
  type, public, extends(stats_quant_t) :: mean_field_t
     type(field_t), pointer :: f => null()
     type(field_t), pointer :: mf => null()
     real(kind=rp) :: time
   contains
     procedure, pass(this) :: init => mean_field_init
     procedure, pass(this) :: free => mean_field_free
     procedure, pass(this) :: update => mean_field_update
     procedure, pass(this) :: update_col3 => mean_field_update_col3
     procedure, pass(this) :: update_dot3 => mean_field_update_dot3
     procedure, pass(this) :: reset => mean_field_reset
  end type mean_field_t
 
contains
 
  subroutine mean_field_init(this, f, field_name)
    class(mean_field_t), intent(inout) :: this
    type(field_t), intent(in), target :: f
    character(len=*), optional, intent(in) :: field_name
    character(len=NEKO_VARNAME_LEN) :: name
 
    call this%free()
 
    this%f => f
    this%time = 0.0_rp
 
    if (present(field_name)) then
       name = field_name
    else
       write(name, '(A,A)') 'mean_', trim(f%name)
    end if
 
    call neko_registry%add_field(f%dof, trim(name))
    this%mf => neko_registry%get_field(trim(name))
 
  end subroutine mean_field_init
 
  subroutine mean_field_free(this)
    class(mean_field_t), intent(inout) :: this
 
    if (associated(this%f)) then
       nullify(this%f)
    end if
 
    if (associated(this%mf)) then
       nullify(this%mf)
    end if
 
  end subroutine mean_field_free
 
  subroutine mean_field_reset(this)
    class(mean_field_t), intent(inout) :: this
 
    this%time = 0.0
    this%mf = 0.0_rp
  end subroutine mean_field_reset
 
 
  subroutine mean_field_update(this, k)
    class(mean_field_t), intent(inout) :: this
    real(kind=rp), intent(in) :: k
 
    call field_cmult(this%mf, this%time, size(this%mf%x))
    call field_add2s2(this%mf, this%f, k, size(this%mf%x))
    this%time = this%time + k
    call field_cmult(this%mf, 1.0_rp / this%time, size(this%mf%x))
 
  end subroutine mean_field_update
 
  subroutine mean_field_update_col3(this, k, a, b)
    class(mean_field_t), intent(inout) :: this
    real(kind=rp), intent(in) :: k
    type(field_t), intent(in) :: a, b
 
    call field_cmult(this%mf, this%time, size(this%mf%x))
    call field_addcol3s2(this%mf, a, b, k, size(this%mf%x))
    this%time = this%time + k
    call field_cmult(this%mf, 1.0_rp / this%time, size(this%mf%x))
 
  end subroutine mean_field_update_col3
 
  subroutine mean_field_update_dot3(this, k, a1, a2, a3, b1, b2, b3)
    class(mean_field_t), intent(inout) :: this
    real(kind=rp), intent(in) :: k
    type(field_t), intent(in) :: a1, a2, a3, b1, b2, b3
 
    call field_cmult(this%mf, this%time, size(this%mf%x))
    call field_addcol3s2(this%mf, a1, b1, k, size(this%mf%x))
    call field_addcol3s2(this%mf, a2, b2, k, size(this%mf%x))
    call field_addcol3s2(this%mf, a3, b3, k, size(this%mf%x))
    this%time = this%time + k
    call field_cmult(this%mf, 1.0_rp / this%time, size(this%mf%x))
 
  end subroutine mean_field_update_dot3
 
end module mean_field