smagorinsky_cpu.f90

Go to the documentation of this file.

! Copyright (c) 2023-2024, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module smagorinsky_cpu
  use num_types, only : rp
  use field_list, only : field_list_t
  use scratch_registry, only : neko_scratch_registry
  use registry, only : neko_registry
  use field, only : field_t
  use operators, only : strain_rate
  use coefs, only : coef_t
  use gs_ops, only : gs_op_add
  use math, only : col2
  implicit none
  private
 
  public :: smagorinsky_compute_cpu
 
contains
 
  subroutine smagorinsky_compute_cpu(if_ext, t, tstep, coef, nut, delta, c_s)
    logical, intent(in) :: if_ext
    real(kind=rp), intent(in) :: t
    integer, intent(in) :: tstep
    type(coef_t), intent(in) :: coef
    type(field_t), intent(inout) :: nut
    type(field_t), intent(in) :: delta
    real(kind=rp), intent(in) :: c_s
    type(field_t), pointer :: u, v, w
    ! strain rate tensor
    type(field_t), pointer :: s11, s22, s33, s12, s13, s23
    real(kind=rp) :: s_abs
    integer :: temp_indices(6)
    integer :: e, i
 
    if (if_ext .eqv. .true.) then
       u => neko_registry%get_field_by_name("u_e")
       v => neko_registry%get_field_by_name("v_e")
       w => neko_registry%get_field_by_name("w_e")
    else
       u => neko_registry%get_field_by_name("u")
       v => neko_registry%get_field_by_name("v")
       w => neko_registry%get_field_by_name("w")
    end if
 
    call neko_scratch_registry%request_field(s11, temp_indices(1), .false.)
    call neko_scratch_registry%request_field(s22, temp_indices(2), .false.)
    call neko_scratch_registry%request_field(s33, temp_indices(3), .false.)
    call neko_scratch_registry%request_field(s12, temp_indices(4), .false.)
    call neko_scratch_registry%request_field(s13, temp_indices(5), .false.)
    call neko_scratch_registry%request_field(s23, temp_indices(6), .false.)
 
    ! Compute the strain rate tensor
    call strain_rate(s11%x, s22%x, s33%x, s12%x, s13%x, s23%x, &
         u%x, v%x, w%x, coef)
 
    call coef%gs_h%op(s11, gs_op_add)
    call coef%gs_h%op(s22, gs_op_add)
    call coef%gs_h%op(s33, gs_op_add)
    call coef%gs_h%op(s12, gs_op_add)
    call coef%gs_h%op(s13, gs_op_add)
    call coef%gs_h%op(s23, gs_op_add)
 
    !$omp parallel do private(e, i, s_abs)
    do e = 1, coef%msh%nelv
       !OCL NORECURRENCE, NOVREC, NOALIAS
       !DIR$ CONCURRENT
       !GCC$ ivdep
       do i = 1, coef%Xh%lxyz
          s_abs = sqrt(2.0_rp * (s11%x(i,1,1,e)*s11%x(i,1,1,e) + &
               s22%x(i,1,1,e)*s22%x(i,1,1,e) + &
               s33%x(i,1,1,e)*s33%x(i,1,1,e)) + &
               4.0_rp * (s12%x(i,1,1,e)*s12%x(i,1,1,e) + &
               s13%x(i,1,1,e)*s13%x(i,1,1,e) + &
               s23%x(i,1,1,e)*s23%x(i,1,1,e)))
 
          nut%x(i,1,1,e) = c_s**2 * delta%x(i,1,1,e)**2 * s_abs &
               * coef%mult(i,1,1,e)
       end do
    end do
    !$omp end parallel do
 
    call coef%gs_h%op(nut, gs_op_add)
    call col2(nut%x, coef%mult, nut%dof%size())
 
    call neko_scratch_registry%relinquish_field(temp_indices)
  end subroutine smagorinsky_compute_cpu
 
end module smagorinsky_cpu