field_list.f90

Go to the documentation of this file.

! Copyright (c) 2023-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module field_list
  use, intrinsic :: iso_fortran_env, only : error_unit
  use field, only : field_ptr_t, field_t
  use iso_c_binding, only : c_ptr
  use num_types, only : rp
  use space, only : space_t
  use dofmap, only : dofmap_t
  use mesh, only : mesh_t
  use utils, only : neko_error
  use comm, only : pe_rank
  implicit none
  private
 
  type, public :: field_list_t
     type(field_ptr_t), allocatable :: items(:)
   contains
     procedure, pass(this) :: init => field_list_init
     procedure, pass(this) :: free => field_list_free
     procedure, pass(this) :: append => field_list_append
     generic :: get => get_by_index, get_by_name
     procedure, pass(this) :: get_by_index => field_list_get_by_index
     procedure, pass(this) :: get_by_name => field_list_get_by_name
     generic :: assign => assign_to_ptr, assign_to_field_ptr, &
          assign_to_list
     procedure, pass(this) :: assign_to_ptr => field_list_assign_to_ptr
     procedure, pass(this) :: assign_to_field_ptr => &
          field_list_assign_to_field_ptr
     procedure, pass(this) :: assign_to_field => field_list_assign_to_field
     procedure, pass(this) :: assign_to_list => field_list_assign_to_field_list
 
     procedure, pass(this) :: x_d => field_list_x_d
     procedure, pass(this) :: x => field_list_x
     procedure, pass(this) :: size => field_list_size
     procedure, pass(this) :: item_size => field_list_item_size
     procedure, pass(this) :: dof => field_list_dof
     procedure, pass(this) :: xh => field_list_space
     procedure, pass(this) :: msh => field_list_msh
     procedure, pass(this) :: internal_dofmap => field_list_internal_dofmap
     procedure, pass(this) :: name => field_list_name
     procedure, pass(this) :: copy_from => field_list_copy_from
  end type field_list_t
 
contains
  subroutine field_list_init(this, size)
    class(field_list_t), intent(inout) :: this
    integer, intent(in) :: size
 
    call this%free()
    allocate(this%items(size))
 
  end subroutine field_list_init
 
  pure function field_list_size(this) result(n)
    class(field_list_t), intent(in) :: this
    integer :: n
 
    if (allocated(this%items)) then
       n = size(this%items)
    else
       n = 0
    end if
 
  end function field_list_size
 
  function field_list_get_by_index(this, i) result(f)
    class(field_list_t), intent(inout) :: this
    type(field_t), pointer :: f
    integer, intent(in) :: i
    f => this%items(i)%ptr
  end function field_list_get_by_index
 
  function field_list_get_by_name(this, name) result(f)
    class(field_list_t), intent(inout) :: this
    type(field_t), pointer :: f
    character(len=*), intent(in) :: name
    integer :: i
 
    nullify(f)
 
    do i = 1, this%size()
       if (this%name(i) .eq. trim(name)) then
          f => this%items(i)%ptr
          return
       end if
    end do
 
    if (pe_rank .eq. 0) then
       write(error_unit,*) "Current field list contents:"
 
       do i = 1, this%size()
          write(error_unit,*) "- ", this%name(i)
       end do
    end if
 
    call neko_error("No field with name " // trim(name) // " found in list")
  end function field_list_get_by_name
 
  subroutine field_list_append(this, f)
    class(field_list_t), intent(inout) :: this
    class(field_t), intent(in), target :: f
    type(field_ptr_t), allocatable :: tmp(:)
    integer :: len
 
    if (.not. allocated(this%items)) then
       allocate(this%items(1))
       call this%items(1)%init(f)
       return
    end if
 
    len = size(this%items)
 
    allocate(tmp(len+1))
    tmp(1:len) = this%items
    call move_alloc(tmp, this%items)
    call this%items(len+1)%init(f)
 
  end subroutine field_list_append
 
  subroutine field_list_free(this)
    class(field_list_t), intent(inout) :: this
    integer :: i, n_fields
 
    if (allocated(this%items)) then
       n_fields = this%size()
       do i = 1, n_fields
          call this%items(i)%free()
       end do
       deallocate(this%items)
    end if
 
  end subroutine field_list_free
 
  function field_list_x_d(this, i) result(ptr)
    class(field_list_t), intent(in) :: this
    integer, intent(in) :: i
    type(c_ptr) :: ptr
 
    ptr = this%items(i)%ptr%x_d
  end function field_list_x_d
 
  function field_list_x(this, i) result(x)
    class(field_list_t), target, intent(in) :: this
    real(kind=rp), pointer, contiguous :: x(:,:,:,:)
    integer, intent(in) :: i
    x => this%items(i)%ptr%x
  end function field_list_x
 
  function field_list_item_size(this, i) result(size)
    class(field_list_t), target, intent(in) :: this
    integer, intent(in) :: i
    integer :: size
 
    size = this%items(i)%ptr%size()
 
  end function field_list_item_size
 
  subroutine field_list_assign_to_ptr(this, i, ptr)
    class(field_list_t), intent(inout) :: this
    integer, intent(in) :: i
    type(field_t), pointer, intent(in) :: ptr
 
    call this%items(i)%init(ptr)
 
  end subroutine field_list_assign_to_ptr
 
  subroutine field_list_assign_to_field_ptr(this, i, ptr)
    class(field_list_t), intent(inout) :: this
    integer, intent(in) :: i
    type(field_ptr_t), target, intent(in) :: ptr
 
    call this%items(i)%init(ptr%ptr)
  end subroutine field_list_assign_to_field_ptr
 
  subroutine field_list_assign_to_field(this, i, fld)
    class(field_list_t), intent(inout) :: this
    integer, intent(in) :: i
    type(field_t), target, intent(in) :: fld
 
    call this%items(i)%init(fld)
  end subroutine field_list_assign_to_field
 
  subroutine field_list_assign_to_field_list(this, other)
    class(field_list_t), intent(inout) :: this
    type(field_list_t), intent(in) :: other
    integer :: i
 
    call this%free()
    call this%init(other%size())
    do i = 1, other%size()
       call this%assign(i, other%items(i)%ptr)
    end do
  end subroutine field_list_assign_to_field_list
 
  function field_list_dof(this, i) result(result)
    class(field_list_t), target, intent(in) :: this
    integer, intent(in) :: i
    type(dofmap_t), pointer :: result
 
    result => this%items(i)%ptr%dof
  end function field_list_dof
 
  function field_list_space(this, i) result(result)
    class(field_list_t), target, intent(in) :: this
    integer, intent(in) :: i
    type(space_t), pointer :: result
 
    result => this%items(i)%ptr%Xh
  end function field_list_space
 
  function field_list_msh(this, i) result(result)
    class(field_list_t), target, intent(in) :: this
    integer, intent(in) :: i
    type(mesh_t), pointer :: result
 
    result => this%items(i)%ptr%msh
  end function field_list_msh
 
  function field_list_internal_dofmap(this, i) result(result)
    class(field_list_t), target, intent(in) :: this
    integer, intent(in) :: i
    logical :: result
 
    result = this%items(i)%ptr%internal_dofmap
  end function field_list_internal_dofmap
 
  function field_list_name(this, i) result(result)
    class(field_list_t), target, intent(in) :: this
    integer, intent(in) :: i
    character(len=80) :: result
 
    result = this%items(i)%ptr%name
  end function field_list_name
 
  subroutine field_list_copy_from(this, memdir, sync)
    class(field_list_t), intent(inout) :: this
    integer, intent(in) :: memdir
    logical, intent(in) :: sync
    integer :: i, n
 
    n = this%size()
    if (n .eq. 0) return
 
    do i = 1, n - 1
       call this%items(i)%ptr%copy_from(memdir, .false.)
    end do
    call this%items(n)%ptr%copy_from(memdir, sync)
 
  end subroutine field_list_copy_from
 
end module field_list