vorticity.f90

Go to the documentation of this file.

! Copyright (c) 2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
 
module vorticity
  use num_types, only : rp, dp, sp
  use json_module, only : json_file
  use simulation_component, only : simulation_component_t
  use field_registry, only : neko_field_registry
  use field, only : field_t
  use operators, only : curl
  use case, only : case_t
  use fld_file_output, only : fld_file_output_t
  use json_utils, only : json_get, json_get_or_default
  use field_writer, only : field_writer_t
  implicit none
  private
 
  type, public, extends(simulation_component_t) :: vorticity_t
     type(field_t), pointer :: u
     type(field_t), pointer :: v
     type(field_t), pointer :: w
 
     type(field_t), pointer :: omega_x
     type(field_t), pointer :: omega_y
     type(field_t), pointer :: omega_z
 
     type(field_t) :: temp1
     type(field_t) :: temp2
 
     type(field_writer_t) :: writer
 
   contains
     procedure, pass(this) :: init => vorticity_init_from_json
     procedure, pass(this) :: init_from_attributes => &
        vorticity_init_from_attributes
     procedure, pass(this) :: free => vorticity_free
     procedure, pass(this) :: compute_ => vorticity_compute
  end type vorticity_t
 
contains
 
  subroutine vorticity_init_from_json(this, json, case)
    class(vorticity_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    class(case_t), intent(inout), target :: case
    character(len=20) :: fields(3)
 
    ! Add fields keyword to the json so that the field_writer picks it up.
    ! Will also add fields to the registry.
    fields(1) = "omega_x"
    fields(2) = "omega_y"
    fields(3) = "omega_z"
 
    call json%add("fields", fields)
 
    call this%init_base(json, case)
    call this%writer%init(json, case)
 
    call vorticity_init_from_attributes(this)
  end subroutine vorticity_init_from_json
 
  subroutine vorticity_init_from_attributes(this)
    class(vorticity_t), intent(inout) :: this
 
    this%u => neko_field_registry%get_field_by_name("u")
    this%v => neko_field_registry%get_field_by_name("v")
    this%w => neko_field_registry%get_field_by_name("w")
 
    this%omega_x => neko_field_registry%get_field_by_name("omega_x")
    this%omega_y => neko_field_registry%get_field_by_name("omega_y")
    this%omega_z => neko_field_registry%get_field_by_name("omega_z")
 
    call this%temp1%init(this%u%dof)
    call this%temp2%init(this%u%dof)
 
  end subroutine vorticity_init_from_attributes
 
  subroutine vorticity_free(this)
    class(vorticity_t), intent(inout) :: this
    call this%free_base()
    call this%writer%free()
    call this%temp1%free()
    call this%temp2%free()
 
    nullify(this%u)
    nullify(this%v)
    nullify(this%w)
    nullify(this%omega_x)
    nullify(this%omega_y)
    nullify(this%omega_z)
  end subroutine vorticity_free
 
  subroutine vorticity_compute(this, t, tstep)
    class(vorticity_t), intent(inout) :: this
    real(kind=rp), intent(in) :: t
    integer, intent(in) :: tstep
 
    call curl(this%omega_x, this%omega_y, this%omega_z, this%u, this%v, &
                 this%w, this%temp1, this%temp2, this%case%fluid%c_Xh)
  end subroutine vorticity_compute
 
end module vorticity