point_interpolator.f90

Go to the documentation of this file.

! Copyright (c) 2021-2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module point_interpolator
  use tensor, only: triple_tensor_product
  use space, only: space_t, gl, gll
  use num_types, only: rp
  use point, only: point_t
  use math, only: abscmp
  use fast3d, only: fd_weights_full
  use utils, only: neko_error
  use device
  use device_math, only: device_rzero
  use neko_config, only: neko_bcknd_device
  implicit none
  private
 
  type, public :: point_interpolator_t
     type(space_t), pointer :: xh => null()
   contains
     procedure, pass(this) :: init => point_interpolator_init
     procedure, pass(this) :: free => point_interpolator_free
     procedure, pass(this) :: compute_weights => point_interpolator_compute_weights
     procedure, pass(this) :: point_interpolator_interpolate_scalar
     procedure, pass(this) :: point_interpolator_interpolate_vector
     procedure, pass(this) :: point_interpolator_interpolate_jacobian
     procedure, pass(this) :: point_interpolator_interpolate_vector_jacobian
     generic :: interpolate => point_interpolator_interpolate_scalar, &
          point_interpolator_interpolate_vector
     generic :: jacobian => point_interpolator_interpolate_jacobian, &
          point_interpolator_interpolate_vector_jacobian
 
  end type point_interpolator_t
 
contains
 
  subroutine point_interpolator_init(this, Xh)
    class(point_interpolator_t), intent(inout), target :: this
    type(space_t), intent(in), target :: Xh
 
    if ((xh%t .eq. gl) .or. (xh%t .eq. gll)) then
    else
       call neko_error('Unsupported interpolation')
    end if
 
    this%Xh => xh
 
  end subroutine point_interpolator_init
 
  subroutine point_interpolator_free(this)
    class(point_interpolator_t), intent(inout) :: this
 
    if (associated(this%Xh)) this%Xh => null()
 
  end subroutine point_interpolator_free
 
  subroutine point_interpolator_compute_weights(this, r, s, t, wr, ws, wt)
    class(point_interpolator_t), intent(inout) :: this
    real(kind=rp), intent(in) :: r(:), s(:), t(:)
    real(kind=rp), intent(inout) :: wr(:,:), ws(:,:), wt(:,:)
 
    integer :: N, i, lx
    lx = this%Xh%lx
    n = size(r)
 
    do i = 1, n
       call fd_weights_full(r(i), this%Xh%zg(:,1), lx-1, 0, wr(:,i))
       call fd_weights_full(s(i), this%Xh%zg(:,2), lx-1, 0, ws(:,i))
       call fd_weights_full(t(i), this%Xh%zg(:,3), lx-1, 0, wt(:,i))
    end do
 
  end subroutine point_interpolator_compute_weights
 
  function point_interpolator_interpolate_scalar(this, rst, X) result(res)
    class(point_interpolator_t), intent(in) :: this
    type(point_t), intent(in) :: rst(:)
    real(kind=rp), intent(inout) :: x(this%Xh%lx, this%Xh%ly, this%Xh%lz)
    real(kind=rp), allocatable :: res(:)
 
    real(kind=rp) :: hr(this%Xh%lx), hs(this%Xh%ly), ht(this%Xh%lz)
    integer :: lx,ly,lz, i
    integer :: n
    lx = this%Xh%lx
    ly = this%Xh%ly
    lz = this%Xh%lz
 
    n = size(rst)
    allocate(res(n))
 
    !
    ! Compute weights and perform interpolation for the first point
    !
    call fd_weights_full(real(rst(1)%x(1), rp), this%Xh%zg(:,1), lx-1, 0, hr)
    call fd_weights_full(real(rst(1)%x(2), rp), this%Xh%zg(:,2), ly-1, 0, hs)
    call fd_weights_full(real(rst(1)%x(3), rp), this%Xh%zg(:,3), lz-1, 0, ht)
 
    ! And interpolate!
    call triple_tensor_product(res(1),x,lx,hr,hs,ht)
 
    if (n .eq. 1) return
 
    !
    ! Loop through the rest of the points
    !
    do i = 2, n
 
       ! If the coordinates are different, then recompute weights
       if ( .not. abscmp(rst(i)%x(1), rst(i-1)%x(1)) ) then
          call fd_weights_full(real(rst(i)%x(1), rp), &
                               this%Xh%zg(:,1), lx-1, 0, hr)
       end if
       if ( .not. abscmp(rst(i)%x(2), rst(i-1)%x(2)) ) then
          call fd_weights_full(real(rst(i)%x(2), rp), &
                               this%Xh%zg(:,2), ly-1, 0, hs)
       end if
       if ( .not. abscmp(rst(i)%x(3), rst(i-1)%x(3)) ) then
          call fd_weights_full(real(rst(i)%x(3), rp), &
                               this%Xh%zg(:,3), lz-1, 0, ht)
       end if
 
       ! And interpolate!
       call triple_tensor_product(res(i), x, lx, hr, hs, ht)
 
    end do
 
  end function point_interpolator_interpolate_scalar
 
  function point_interpolator_interpolate_vector(this, rst, X, Y, Z) result(res)
    class(point_interpolator_t), intent(in) :: this
    type(point_t), intent(in) :: rst(:)
    real(kind=rp), intent(inout) :: x(this%Xh%lx, this%Xh%ly, this%Xh%lz)
    real(kind=rp), intent(inout) :: y(this%Xh%lx, this%Xh%ly, this%Xh%lz)
    real(kind=rp), intent(inout) :: z(this%Xh%lx, this%Xh%ly, this%Xh%lz)
 
    type(point_t), allocatable :: res(:)
    real(kind=rp), allocatable :: tmp(:,:)
    real(kind=rp) :: hr(this%Xh%lx), hs(this%Xh%ly), ht(this%Xh%lz)
    integer :: lx,ly,lz, i
    integer :: n
    lx = this%Xh%lx
    ly = this%Xh%ly
    lz = this%Xh%lz
 
    n = size(rst)
    allocate(res(n))
    allocate(tmp(3, n))
 
    !
    ! Compute weights and perform interpolation for the first point
    !
    call fd_weights_full(real(rst(1)%x(1), rp), this%Xh%zg(:,1), lx-1, 0, hr)
    call fd_weights_full(real(rst(1)%x(2), rp), this%Xh%zg(:,2), ly-1, 0, hs)
    call fd_weights_full(real(rst(1)%x(3), rp), this%Xh%zg(:,3), lz-1, 0, ht)
 
    ! And interpolate!
    call triple_tensor_product(tmp(:,1), x, y, z, lx, hr, hs, ht)
 
    if (n .eq. 1) then
       res(1)%x = tmp(:, 1)
       return
    end if
 
 
    !
    ! Loop through the rest of the points
    !
    do i = 2, n
 
       ! If the coordinates are different, then recompute weights
       if ( .not. abscmp(rst(i)%x(1), rst(i-1)%x(1)) ) then
          call fd_weights_full(real(rst(i)%x(1), rp), &
                               this%Xh%zg(:,1), lx-1, 0, hr)
       end if
       if ( .not. abscmp(rst(i)%x(2), rst(i-1)%x(2)) ) then
          call fd_weights_full(real(rst(i)%x(2), rp), &
                               this%Xh%zg(:,2), ly-1, 0, hs)
       end if
       if ( .not. abscmp(rst(i)%x(3), rst(i-1)%x(3)) ) then
          call fd_weights_full(real(rst(i)%x(3), rp), &
                               this%Xh%zg(:,3), lz-1, 0, ht)
       end if
 
       ! And interpolate!
       call triple_tensor_product(tmp(:,i), x, y, z, lx, hr, hs, ht)
    end do
 
    ! Cast result to point_t dp
    do i = 1, n
       res(i)%x = tmp(:,i)
    end do
 
  end function point_interpolator_interpolate_vector
 
  function point_interpolator_interpolate_vector_jacobian(this, jac, rst, X, Y, Z) result(res)
    class(point_interpolator_t), intent(in) :: this
    real(kind=rp), intent(inout) :: jac(3,3)
    type(point_t), intent(in) :: rst
    real(kind=rp), intent(inout) :: x(this%Xh%lx, this%Xh%ly, this%Xh%lz)
    real(kind=rp), intent(inout) :: y(this%Xh%lx, this%Xh%ly, this%Xh%lz)
    real(kind=rp), intent(inout) :: z(this%Xh%lx, this%Xh%ly, this%Xh%lz)
 
    real(kind=rp) :: hr(this%Xh%lx, 2), hs(this%Xh%ly, 2), ht(this%Xh%lz, 2)
    type(point_t) :: res
    real(kind=rp) :: tmp(3)
 
    integer :: lx,ly,lz, i
    lx = this%Xh%lx
    ly = this%Xh%ly
    lz = this%Xh%lz
 
    !
    ! Compute weights
    !
    call fd_weights_full(real(rst%x(1), rp), this%Xh%zg(:,1), lx-1, 1, hr)
    call fd_weights_full(real(rst%x(2), rp), this%Xh%zg(:,2), ly-1, 1, hs)
    call fd_weights_full(real(rst%x(3), rp),this%Xh%zg(:,3), lz-1, 1, ht)
 
    !
    ! Interpolate
    !
    call triple_tensor_product(tmp, x, y, z, lx, hr(:,1), hs(:,1), ht(:,1))
    res%x = dble(tmp)! Cast from rp -> point_t dp
 
    !
    ! Build jacobian
    !
 
    ! d(x,y,z)/dr
    call triple_tensor_product(tmp, x,y,z, lx, hr(:,2), hs(:,1), ht(:,1))
    jac(1,:) = tmp
 
    ! d(x,y,z)/ds
    call triple_tensor_product(tmp, x,y,z, lx, hr(:,1), hs(:,2), ht(:,1))
    jac(2,:) = tmp
 
    ! d(x,y,z)/dt
    call triple_tensor_product(tmp, x,y,z, lx, hr(:,1), hs(:,1), ht(:,2))
    jac(3,:) = tmp
 
  end function point_interpolator_interpolate_vector_jacobian
 
  function point_interpolator_interpolate_jacobian(this, rst, X,Y,Z) result(jac)
    class(point_interpolator_t), intent(in) :: this
    type(point_t), intent(in) :: rst
    real(kind=rp), intent(inout) :: x(this%Xh%lx, this%Xh%ly, this%Xh%lz)
    real(kind=rp), intent(inout) :: y(this%Xh%lx, this%Xh%ly, this%Xh%lz)
    real(kind=rp), intent(inout) :: z(this%Xh%lx, this%Xh%ly, this%Xh%lz)
 
    real(kind=rp) :: jac(3,3)
    real(kind=rp) :: tmp(3)
 
    real(kind=rp) :: hr(this%Xh%lx, 2), hs(this%Xh%ly, 2), ht(this%Xh%lz, 2)
    integer :: lx, ly, lz
    lx = this%Xh%lx
    ly = this%Xh%ly
    lz = this%Xh%lz
 
    ! Weights
    call fd_weights_full(real(rst%x(1), rp), this%Xh%zg(:,1), lx-1, 1, hr)
    call fd_weights_full(real(rst%x(2), rp), this%Xh%zg(:,2), ly-1, 1, hs)
    call fd_weights_full(real(rst%x(3), rp), this%Xh%zg(:,3), lz-1, 1, ht)
 
    ! d(x,y,z)/dr
    call triple_tensor_product(tmp, x, y, z, lx, hr(:,2), hs(:,1), ht(:,1))
    jac(1,:) = tmp
 
    ! d(x,y,z)/ds
    call triple_tensor_product(tmp, x, y, z, lx, hr(:,1), hs(:,2), ht(:,1))
    jac(2,:) = tmp
 
    ! d(x,y,z)/dt
    call triple_tensor_product(tmp, x, y, z, lx, hr(:,1), hs(:,1), ht(:,2))
    jac(3,:) = tmp
 
  end function point_interpolator_interpolate_jacobian
 
end module point_interpolator