vreman_device.f90

Go to the documentation of this file.

! Copyright (c) 2023-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module vreman_device
  use num_types, only : rp
  use math, only : neko_eps
  use scratch_registry, only : neko_scratch_registry
  use registry, only : neko_registry
  use field, only : field_t
  use operators, only : dudxyz
  use coefs, only : coef_t
  use gs_ops, only : gs_op_add
  use device_math, only : device_col2
  use device_vreman_nut, only : device_vreman_nut_compute, &
       device_vreman_nut_compute_buoy
 
  implicit none
  private
 
  public :: vreman_compute_device
 
contains
 
  subroutine vreman_compute_device(if_ext, t, tstep, coef, nut, delta, c,&
       if_corr, scalar_name, ri_c, ref_temp, g)
 
    logical, intent(in) :: if_ext
    real(kind=rp), intent(in) :: t
    integer, intent(in) :: tstep
    type(coef_t), intent(in) :: coef
    type(field_t), intent(inout) :: nut
    type(field_t), intent(in) :: delta
    real(kind=rp), intent(in) :: c
    logical, intent(in) :: if_corr
    character(len=*), intent(in) :: scalar_name
    real(kind=rp), intent(in) :: ri_c, ref_temp
    real(kind=rp), intent(in) :: g(3)
 
    ! This is the alpha tensor in the paper
    type(field_t), pointer :: a11, a12, a13, a21, a22, a23, a31, a32, a33
    type(field_t), pointer :: u, v, w
    type(field_t), pointer :: temperature, dtdx, dtdy, dtdz
 
    type(field_t), pointer :: beta11
    type(field_t), pointer :: beta12
    type(field_t), pointer :: beta13
    type(field_t), pointer :: beta22
    type(field_t), pointer :: beta23
    type(field_t), pointer :: beta33
    type(field_t), pointer :: b_beta
    type(field_t), pointer :: aijaij
    integer :: temp_indices(9), temp_indices_buoy(3)
    integer :: e, i
 
    if (if_ext .eqv. .true.) then
       u => neko_registry%get_field_by_name("u_e")
       v => neko_registry%get_field_by_name("v_e")
       w => neko_registry%get_field_by_name("w_e")
    else
       u => neko_registry%get_field_by_name("u")
       v => neko_registry%get_field_by_name("v")
       w => neko_registry%get_field_by_name("w")
    end if
 
    call neko_scratch_registry%request_field(a11, temp_indices(1), .false.)
    call neko_scratch_registry%request_field(a12, temp_indices(2), .false.)
    call neko_scratch_registry%request_field(a13, temp_indices(3), .false.)
    call neko_scratch_registry%request_field(a21, temp_indices(4), .false.)
    call neko_scratch_registry%request_field(a22, temp_indices(5), .false.)
    call neko_scratch_registry%request_field(a23, temp_indices(6), .false.)
    call neko_scratch_registry%request_field(a31, temp_indices(7), .false.)
    call neko_scratch_registry%request_field(a32, temp_indices(8), .false.)
    call neko_scratch_registry%request_field(a33, temp_indices(9), .false.)
 
    ! Compute the derivatives of the velocity (the alpha tensor)
    call dudxyz(a11%x_d, u%x_d, coef%drdx_d, coef%dsdx_d, coef%dtdx_d, coef)
    call dudxyz(a12%x_d, u%x_d, coef%drdy_d, coef%dsdy_d, coef%dtdy_d, coef)
    call dudxyz(a13%x_d, u%x_d, coef%drdz_d, coef%dsdz_d, coef%dtdz_d, coef)
 
    call dudxyz(a21%x_d, v%x_d, coef%drdx_d, coef%dsdx_d, coef%dtdx_d, coef)
    call dudxyz(a22%x_d, v%x_d, coef%drdy_d, coef%dsdy_d, coef%dtdy_d, coef)
    call dudxyz(a23%x_d, v%x_d, coef%drdz_d, coef%dsdz_d, coef%dtdz_d, coef)
 
    call dudxyz(a31%x_d, w%x_d, coef%drdx_d, coef%dsdx_d, coef%dtdx_d, coef)
    call dudxyz(a32%x_d, w%x_d, coef%drdy_d, coef%dsdy_d, coef%dtdy_d, coef)
    call dudxyz(a33%x_d, w%x_d, coef%drdz_d, coef%dsdz_d, coef%dtdz_d, coef)
 
    call coef%gs_h%op(a11, gs_op_add)
    call coef%gs_h%op(a12, gs_op_add)
    call coef%gs_h%op(a13, gs_op_add)
    call coef%gs_h%op(a21, gs_op_add)
    call coef%gs_h%op(a22, gs_op_add)
    call coef%gs_h%op(a23, gs_op_add)
    call coef%gs_h%op(a31, gs_op_add)
    call coef%gs_h%op(a32, gs_op_add)
    call coef%gs_h%op(a33, gs_op_add)
 
    if (if_corr) then
       temperature => neko_registry%get_field_by_name(scalar_name)
 
       call neko_scratch_registry%request_field(dtdx, temp_indices_buoy(1), &
            .false.)
       call neko_scratch_registry%request_field(dtdy, temp_indices_buoy(2), &
            .false.)
       call neko_scratch_registry%request_field(dtdz, temp_indices_buoy(3), &
            .false.)
 
       call dudxyz(dtdx%x_d, temperature%x_d, coef%drdx_d, coef%dsdx_d, &
            coef%dtdx_d, coef)
       call dudxyz(dtdy%x_d, temperature%x_d, coef%drdy_d, coef%dsdy_d, &
            coef%dtdy_d, coef)
       call dudxyz(dtdz%x_d, temperature%x_d, coef%drdz_d, coef%dsdz_d, &
            coef%dtdz_d, coef)
 
       call device_vreman_nut_compute_buoy(a11%x_d, a12%x_d, a13%x_d, &
            a21%x_d, a22%x_d, a23%x_d, &
            a31%x_d, a32%x_d, a33%x_d, &
            delta%x_d, nut%x_d, coef%mult_d, &
            c, neko_eps, a11%dof%size(), &
            dtdx%x_d, dtdy%x_d, dtdz%x_d, &
            g, ri_c, ref_temp)
       call neko_scratch_registry%relinquish_field(temp_indices_buoy)
    else
       call device_vreman_nut_compute(a11%x_d, a12%x_d, a13%x_d, &
            a21%x_d, a22%x_d, a23%x_d, &
            a31%x_d, a32%x_d, a33%x_d, &
            delta%x_d, nut%x_d, coef%mult_d, &
            c, neko_eps, a11%dof%size())
    end if
 
    call coef%gs_h%op(nut, gs_op_add)
    call device_col2(nut%x_d, coef%mult_d, nut%dof%size())
 
    call neko_scratch_registry%relinquish_field(temp_indices)
  end subroutine vreman_compute_device
 
end module vreman_device