bc_list.f90

Go to the documentation of this file.

! Copyright (c) 2024-2025, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module bc_list
  use neko_config, only : neko_bcknd_device
  use num_types, only : rp
  use field, only : field_t
  use device, only : device_get_ptr, glb_cmd_queue
  use utils, only : neko_error
  use, intrinsic :: iso_c_binding, only : c_ptr
  use bc, only : bc_t, bc_ptr_t
  use time_state, only : time_state_t
  !$ use omp_lib
  implicit none
  private
 
  type, public :: bc_list_t
     ! The items of the list.
     class(bc_ptr_t), allocatable, private :: items(:)
     integer, private :: size_ = 0
     integer, private :: capacity
   contains
     procedure, pass(this) :: init => bc_list_init
     procedure, pass(this) :: free => bc_list_free
 
     procedure, pass(this) :: append => bc_list_append
     procedure, pass(this) :: get => bc_list_get
     procedure, pass(this) :: get_by_name => bc_list_get_by_name
     procedure, pass(this) :: get_by_zone_index => bc_list_get_by_zone_index
 
     procedure, pass(this) :: is_empty => bc_list_is_empty
     procedure, pass(this) :: strong => bc_list_strong
     procedure :: size => bc_list_size
 
     generic :: apply => apply_scalar, apply_vector, &
          apply_scalar_device, apply_vector_device, &
          apply_scalar_field, apply_vector_field
     procedure, pass(this) :: apply_scalar => bc_list_apply_scalar_array
     procedure, pass(this) :: apply_vector => bc_list_apply_vector_array
     procedure, pass(this) :: apply_scalar_device => bc_list_apply_scalar_device
     procedure, pass(this) :: apply_vector_device => bc_list_apply_vector_device
     procedure, pass(this) :: apply_scalar_field => bc_list_apply_scalar_field
     procedure, pass(this) :: apply_vector_field => bc_list_apply_vector_field
  end type bc_list_t
 
contains
 
  subroutine bc_list_init(this, capacity)
    class(bc_list_t), intent(inout), target :: this
    integer, optional :: capacity
    integer :: n
 
    call this%free()
 
    n = 1
    if (present(capacity)) n = capacity
 
    allocate(this%items(n))
 
    this%size_ = 0
    this%capacity = n
 
  end subroutine bc_list_init
 
  subroutine bc_list_free(this)
    class(bc_list_t), intent(inout) :: this
    integer :: i
 
    if (allocated(this%items)) then
       do i = 1, this%size_
          this%items(i)%ptr => null()
       end do
 
       deallocate(this%items)
    end if
 
    this%size_ = 0
    this%capacity = 0
  end subroutine bc_list_free
 
  subroutine bc_list_append(this, bc)
    class(bc_list_t), intent(inout) :: this
    class(bc_t), intent(inout), target :: bc
    type(bc_ptr_t), allocatable :: tmp(:)
 
    if (this%size_ .ge. this%capacity) then
       this%capacity = this%capacity * 2
       allocate(tmp(this%capacity))
       tmp(1:this%size_) = this%items
       call move_alloc(tmp, this%items)
    end if
 
    this%size_ = this%size_ + 1
    this%items(this%size_)%ptr => bc
 
  end subroutine bc_list_append
 
  function bc_list_get(this, i) result(bc)
    class(bc_list_t), intent(in) :: this
    class(bc_t), pointer :: bc
    integer, intent(in) :: i
 
    if (i .lt. 1 .or. i .gt. this%size_) then
       call neko_error("Index out of bounds in bc_list_get")
    end if
 
    bc => this%items(i)%ptr
 
  end function bc_list_get
 
  function bc_list_get_by_name(this, name) result(bc)
    class(bc_list_t), intent(in) :: this
    class(bc_t), pointer :: bc
    character(len=*), intent(in) :: name
    integer :: i
 
    do i = 1, this%size_
       if (this%items(i)%ptr%name .eq. trim(name)) then
          bc => this%items(i)%ptr
          return
       end if
    end do
 
    ! If the function reaches this point, no item was found
    call neko_error("Name not found in bc_list")
 
  end function bc_list_get_by_name
 
  function bc_list_get_by_zone_index(this, zone_index) result(bc)
    class(bc_list_t), intent(in) :: this
    class(bc_t), pointer :: bc
    integer, intent(in) :: zone_index
    integer :: i, j
 
    do i = 1, this%size_
       do j = 1, size(this%items(i)%ptr%zone_indices)
          if (this%items(i)%ptr%zone_indices(j) == zone_index) then
             bc => this%items(i)%ptr
             return
          end if
       end do
    end do
 
    ! If the function reaches this point, no item was found
    call neko_error("Zone index not found in bc_list")
 
  end function bc_list_get_by_zone_index
 
  subroutine bc_list_apply_scalar_array(this, x, n, time, strong, strm)
    class(bc_list_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout), dimension(n) :: x
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout), optional :: strm
    type(c_ptr) :: x_d
    integer :: i
 
    if (neko_bcknd_device .eq. 1) then
 
       x_d = device_get_ptr(x)
 
       call this%apply_scalar_device(x_d, time = time, &
            strong = strong, strm = strm)
    else
       !$omp parallel
       do i = 1, this%size_
          call this%items(i)%ptr%apply_scalar(x, n, time = time, &
               strong = strong)
       end do
       !$omp end parallel
    end if
  end subroutine bc_list_apply_scalar_array
 
  subroutine bc_list_apply_vector_array(this, x, y, z, n, time, strong, strm)
    class(bc_list_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout), dimension(n) :: x
    real(kind=rp), intent(inout), dimension(n) :: y
    real(kind=rp), intent(inout), dimension(n) :: z
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout), optional :: strm
    type(c_ptr) :: x_d
    type(c_ptr) :: y_d
    type(c_ptr) :: z_d
    integer :: i
 
    if (neko_bcknd_device .eq. 1) then
 
       x_d = device_get_ptr(x)
       y_d = device_get_ptr(y)
       z_d = device_get_ptr(z)
 
       call this%apply_vector_device(x_d, y_d, z_d, time = time, &
            strong = strong, strm = strm)
    else
       !$omp parallel
       do i = 1, this%size_
          call this%items(i)%ptr%apply_vector(x, y, z, n, time = time, &
               strong = strong)
       end do
       !$omp end parallel
    end if
 
  end subroutine bc_list_apply_vector_array
 
  subroutine bc_list_apply_scalar_device(this, x_d, time, strong, strm)
    class(bc_list_t), intent(inout) :: this
    type(c_ptr), intent(inout) :: x_d
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout), optional :: strm
    type(c_ptr) :: strm_
    integer :: i
 
    if (present(strm)) then
       strm_ = strm
    else
       strm_ = glb_cmd_queue
    end if
 
    do i = 1, this%size_
       call this%items(i)%ptr%apply_scalar_dev(x_d, time = time, &
            strong = strong, strm = strm_)
    end do
 
  end subroutine bc_list_apply_scalar_device
 
  subroutine bc_list_apply_vector_device(this, x_d, y_d, z_d, time, strong, &
       strm)
    class(bc_list_t), intent(inout) :: this
    type(c_ptr), intent(inout) :: x_d
    type(c_ptr), intent(inout) :: y_d
    type(c_ptr), intent(inout) :: z_d
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout), optional :: strm
    type(c_ptr) :: strm_
    integer :: i
 
    if (present(strm)) then
       strm_ = strm
    else
       strm_ = glb_cmd_queue
    end if
 
    do i = 1, this%size_
       call this%items(i)%ptr%apply_vector_dev(x_d, y_d, z_d, time = time, &
            strong = strong, strm = strm_)
    end do
 
  end subroutine bc_list_apply_vector_device
 
  subroutine bc_list_apply_scalar_field(this, x, time, strong, strm)
    class(bc_list_t), intent(inout) :: this
    type(field_t), intent(inout) :: x
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout), optional :: strm
    integer :: i
 
    !$omp parallel if (.not. omp_in_parallel())
    do i = 1, this%size_
       call this%items(i)%ptr%apply_scalar_generic(x, time = time, &
            strong = strong, strm = strm)
    end do
    !$omp end parallel
 
  end subroutine bc_list_apply_scalar_field
 
  subroutine bc_list_apply_vector_field(this, x, y, z, time, strong, strm)
    class(bc_list_t), intent(inout) :: this
    type(field_t), intent(inout) :: x
    type(field_t), intent(inout) :: y
    type(field_t), intent(inout) :: z
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout), optional :: strm
    integer :: i
 
    !$omp parallel if (.not. omp_in_parallel())
    do i = 1, this%size_
       call this%items(i)%ptr%apply_vector_generic(x, y, z, time = time, &
            strong = strong, strm = strm)
    end do
    !$omp end parallel
 
  end subroutine bc_list_apply_vector_field
 
  pure function bc_list_strong(this, i) result(strong)
    class(bc_list_t), intent(in), target :: this
    integer, intent(in) :: i
    logical :: strong
 
    strong = this%items(i)%ptr%strong
  end function bc_list_strong
 
  function bc_list_is_empty(this) result(is_empty)
    class(bc_list_t), intent(in), target :: this
    logical :: is_empty
    integer :: i
 
    is_empty = .true.
    do i = 1, this%size_
 
       if (.not. allocated(this%items(i)%ptr%msk)) then
          call neko_error("bc not finalized, error in bc_list%is_empty")
       end if
 
       if (this%items(i)%ptr%msk(0) > 0) is_empty = .false.
 
    end do
  end function bc_list_is_empty
 
  pure function bc_list_size(this) result(size)
    class(bc_list_t), intent(in), target :: this
    integer :: size
 
    size = this%size_
  end function bc_list_size
 
end module bc_list