data_streamer.F90

Go to the documentation of this file.

! Copyright (c) 2020-2025, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module data_streamer
  use num_types, only : rp, c_rp
  use field, only : field_t
  use coefs, only : coef_t
  use utils, only : neko_warning
  use comm, only : neko_comm
  use mpi_f08, only : mpi_comm
  use logger, only : neko_log, neko_log_debug
  use, intrinsic :: iso_c_binding
  implicit none
  private
 
  type, public :: data_streamer_t
     integer :: if_asynch
     integer, allocatable :: lglel(:)
   contains
     procedure, pass(this) :: init => data_streamer_init
     procedure, pass(this) :: free => data_streamer_free
     procedure, pass(this) :: stream => data_streamer_stream
     procedure, pass(this) :: recieve => data_streamer_recieve
 
  end type data_streamer_t
 
contains
 
  subroutine data_streamer_init(this, coef, timeout_seconds)
    class(data_streamer_t), intent(inout) :: this
    type(coef_t), intent(inout) :: coef
    integer, intent(in), optional :: timeout_seconds
    integer :: nelb, nelv, nelgv, npts, gdim, timeout
 
    !Assign the set up parameters
    nelv = coef%msh%nelv
    npts = coef%Xh%lx*coef%Xh%ly*coef%Xh%lz
    nelgv = coef%msh%glb_nelv
    nelb = coef%msh%offset_el
    gdim = coef%msh%gdim
    if (present(timeout_seconds)) then
       timeout = timeout_seconds
    else
       timeout = 300
    end if
 
#ifdef HAVE_ADIOS2
    call neko_log%message("Initializing ADIOS2", lvl = neko_log_debug)
    call fortran_adios2_initialize(npts, nelv, nelb, nelgv, gdim, neko_comm, &
         timeout)
    call neko_log%message("Done initializing ADIOS2", lvl = neko_log_debug)
#else
    call neko_warning('Is not being built with ADIOS2 support.')
    call neko_warning('Not able to use stream/compression functionality')
#endif
 
 
  end subroutine data_streamer_init
 
  subroutine data_streamer_free(this)
    class(data_streamer_t), intent(inout) :: this
 
#ifdef HAVE_ADIOS2
    call neko_log%message("Finalizing ADIOS2", lvl = neko_log_debug)
    call fortran_adios2_finalize()
    call neko_log%message("Done finalizing ADIOS2", lvl = neko_log_debug)
#else
    call neko_warning('Is not being built with ADIOS2 support.')
    call neko_warning('Not able to use stream/compression functionality')
#endif
 
  end subroutine data_streamer_free
 
  subroutine data_streamer_stream(this, fld)
    class(data_streamer_t), intent(inout) :: this
    real(kind=rp), dimension(:,:,:,:), intent(inout) :: fld
 
#ifdef HAVE_ADIOS2
    call neko_log%message("Streaming data", lvl = neko_log_debug)
    call fortran_adios2_stream(fld)
    call neko_log%message("Done streaming data", lvl = neko_log_debug)
#else
    call neko_warning('Is not being built with ADIOS2 support.')
    call neko_warning('Not able to use stream/compression functionality')
#endif
 
  end subroutine data_streamer_stream
 
  subroutine data_streamer_recieve(this, fld)
    class(data_streamer_t), intent(inout) :: this
    real(kind=rp), dimension(:,:,:,:), intent(inout) :: fld
 
#ifdef HAVE_ADIOS2
    call neko_log%message("Receiving data", lvl = neko_log_debug)
    call fortran_adios2_recieve(fld)
    call neko_log%message("Done receiving data", lvl = neko_log_debug)
#else
    call neko_warning('Is not being built with ADIOS2 support.')
    call neko_warning('Not able to use stream/compression functionality')
#endif
 
  end subroutine data_streamer_recieve
 
 
#ifdef HAVE_ADIOS2
 
  subroutine fortran_adios2_initialize(npts, nelv, nelb, nelgv, gdim, &
       comm, timeout)
    use, intrinsic :: iso_c_binding
    implicit none
    integer, intent(in) :: npts, nelv, nelb, nelgv, gdim
    integer, intent(in) :: timeout
    type(mpi_comm) :: comm
 
    interface
 
       subroutine c_adios2_initialize(npts, nelv, nelb, nelgv, gdim, &
            comm, timeout) bind(C, name = "adios2_initialize_")
         use, intrinsic :: iso_c_binding
         import c_rp
         implicit none
         integer(kind=C_INT) :: npts
         integer(kind=C_INT) :: nelv
         integer(kind=C_INT) :: nelb
         integer(kind=C_INT) :: nelgv
         integer(kind=C_INT) :: gdim
         type(*) :: comm
         integer(kind=C_INT) :: timeout
       end subroutine c_adios2_initialize
    end interface
 
    call c_adios2_initialize(npts, nelv, nelb, nelgv, gdim, comm, timeout)
  end subroutine fortran_adios2_initialize
 
  subroutine fortran_adios2_finalize()
    use, intrinsic :: iso_c_binding
    implicit none
 
    interface
 
       subroutine c_adios2_finalize() bind(C, name = "adios2_finalize_")
         use, intrinsic :: iso_c_binding
         implicit none
       end subroutine c_adios2_finalize
    end interface
 
    call c_adios2_finalize()
  end subroutine fortran_adios2_finalize
 
  subroutine fortran_adios2_stream(fld)
    use, intrinsic :: iso_c_binding
    implicit none
    real(kind=rp), dimension(:,:,:,:), intent(inout) :: fld
 
    interface
 
       subroutine c_adios2_stream(fld) &
            bind(C, name = "adios2_stream_")
         use, intrinsic :: iso_c_binding
         import c_rp
         implicit none
         real(kind=c_rp), intent(INOUT) :: fld(*)
       end subroutine c_adios2_stream
    end interface
 
    call c_adios2_stream(fld)
  end subroutine fortran_adios2_stream
 
  subroutine fortran_adios2_recieve(fld)
    use, intrinsic :: iso_c_binding
    implicit none
    real(kind=rp), dimension(:,:,:,:), intent(inout) :: fld
 
    interface
 
       subroutine c_adios2_recieve(fld) &
            bind(C, name = "adios2_recieve_")
         use, intrinsic :: iso_c_binding
         import c_rp
         implicit none
         real(kind=c_rp), intent(INOUT) :: fld(*)
       end subroutine c_adios2_recieve
    end interface
 
    call c_adios2_recieve(fld)
  end subroutine fortran_adios2_recieve
 
#endif
 
end module data_streamer