vreman_cpu.f90

Go to the documentation of this file.

! Copyright (c) 2023-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module vreman_cpu
  use num_types, only : rp
  use field_list, only : field_list_t
  use math, only : cadd, neko_eps, col2, vlsc2
  use scratch_registry, only : neko_scratch_registry
  use registry, only : neko_registry
  use field, only : field_t
  use operators, only : dudxyz, grad
  use coefs, only : coef_t
  use gs_ops, only : gs_op_add
  use utils, only : neko_error
  implicit none
  private
 
  public :: vreman_compute_cpu
 
contains
 
  subroutine vreman_compute_cpu(if_ext, t, tstep, coef, nut, delta, c, &
       if_corr, scalar_name, ri_c, ref_temp, g)
    logical, intent(in) :: if_ext, if_corr
    real(kind=rp), intent(in) :: t
    integer, intent(in) :: tstep
    type(coef_t), intent(in) :: coef
    type(field_t), intent(inout) :: nut
    type(field_t), intent(in) :: delta
    character(len=*), intent(in) :: scalar_name
    real(kind=rp), intent(in) :: c, ri_c, ref_temp
    real(kind=rp), intent(in) :: g(3)
    ! This is the alpha tensor in the paper
    type(field_t), pointer :: a11, a12, a13, a21, a22, a23, a31, a32, a33
    type(field_t), pointer :: u, v, w
    type(field_t), pointer :: temperature, dtdx, dtdy, dtdz
 
    real(kind=rp) :: beta11
    real(kind=rp) :: beta12
    real(kind=rp) :: beta13
    real(kind=rp) :: beta22
    real(kind=rp) :: beta23
    real(kind=rp) :: beta33
    real(kind=rp) :: b_beta
    real(kind=rp) :: aijaij
    integer :: temp_indices(9)
    integer :: temp_indices_buoy(3)
    integer :: e, i, j
    real(kind=rp) :: gmag, ri, correction, buoyancy, shear_sq
    real(kind=rp) :: n(3), du_n(3), sh(3)
    real(kind=rp) :: du_parallel
 
    if (if_ext) then
       u => neko_registry%get_field_by_name("u_e")
       v => neko_registry%get_field_by_name("v_e")
       w => neko_registry%get_field_by_name("w_e")
    else
       u => neko_registry%get_field_by_name("u")
       v => neko_registry%get_field_by_name("v")
       w => neko_registry%get_field_by_name("w")
    end if
 
    call neko_scratch_registry%request_field(a11, temp_indices(1), .false.)
    call neko_scratch_registry%request_field(a12, temp_indices(2), .false.)
    call neko_scratch_registry%request_field(a13, temp_indices(3), .false.)
    call neko_scratch_registry%request_field(a21, temp_indices(4), .false.)
    call neko_scratch_registry%request_field(a22, temp_indices(5), .false.)
    call neko_scratch_registry%request_field(a23, temp_indices(6), .false.)
    call neko_scratch_registry%request_field(a31, temp_indices(7), .false.)
    call neko_scratch_registry%request_field(a32, temp_indices(8), .false.)
    call neko_scratch_registry%request_field(a33, temp_indices(9), .false.)
 
 
    ! Compute the derivatives of the velocity (the alpha tensor)
    call dudxyz (a11%x, u%x, coef%drdx, coef%dsdx, coef%dtdx, coef)
    call dudxyz (a12%x, u%x, coef%drdy, coef%dsdy, coef%dtdy, coef)
    call dudxyz (a13%x, u%x, coef%drdz, coef%dsdz, coef%dtdz, coef)
 
    call dudxyz (a21%x, v%x, coef%drdx, coef%dsdx, coef%dtdx, coef)
    call dudxyz (a22%x, v%x, coef%drdy, coef%dsdy, coef%dtdy, coef)
    call dudxyz (a23%x, v%x, coef%drdz, coef%dsdz, coef%dtdz, coef)
 
    call dudxyz (a31%x, w%x, coef%drdx, coef%dsdx, coef%dtdx, coef)
    call dudxyz (a32%x, w%x, coef%drdy, coef%dsdy, coef%dtdy, coef)
    call dudxyz (a33%x, w%x, coef%drdz, coef%dsdz, coef%dtdz, coef)
 
    call coef%gs_h%op(a11, gs_op_add)
    call coef%gs_h%op(a12, gs_op_add)
    call coef%gs_h%op(a13, gs_op_add)
    call coef%gs_h%op(a21, gs_op_add)
    call coef%gs_h%op(a22, gs_op_add)
    call coef%gs_h%op(a23, gs_op_add)
    call coef%gs_h%op(a31, gs_op_add)
    call coef%gs_h%op(a32, gs_op_add)
    call coef%gs_h%op(a33, gs_op_add)
 
    !$omp parallel do private(e, i, beta11, beta12, beta13, beta22, beta23, &
    !$omp& beta33, b_beta, aijaij)
    do e = 1, coef%msh%nelv
       !OCL NORECURRENCE, NOVREC, NOALIAS
       !DIR$ CONCURRENT
       !DIR$ IVDEP
       !GCC$ ivdep
       do i = 1, coef%Xh%lxyz
          ! beta_ij = alpha_mi alpha_mj
          beta11 = a11%x(i,1,1,e)**2 + a21%x(i,1,1,e)**2 + a31%x(i,1,1,e)**2
          beta22 = a12%x(i,1,1,e)**2 + a22%x(i,1,1,e)**2 + a32%x(i,1,1,e)**2
          beta33 = a13%x(i,1,1,e)**2 + a23%x(i,1,1,e)**2 + a33%x(i,1,1,e)**2
          beta12 = a11%x(i,1,1,e)*a12%x(i,1,1,e) + &
               a21%x(i,1,1,e)*a22%x(i,1,1,e) + &
               a31%x(i,1,1,e)*a32%x(i,1,1,e)
          beta13 = a11%x(i,1,1,e)*a13%x(i,1,1,e) + &
               a21%x(i,1,1,e)*a23%x(i,1,1,e) + &
               a31%x(i,1,1,e)*a33%x(i,1,1,e)
          beta23 = a12%x(i,1,1,e)*a13%x(i,1,1,e) + &
               a22%x(i,1,1,e)*a23%x(i,1,1,e) + &
               a32%x(i,1,1,e)*a33%x(i,1,1,e)
 
          b_beta = beta11*beta22 - beta12*beta12 + beta11*beta33 &
               - beta13*beta13 + beta22*beta33 - beta23*beta23
 
          b_beta = max(0.0_rp, b_beta)
 
          ! alpha_ij alpha_ij
          aijaij = beta11 + beta22 + beta33
 
          nut%x(i,1,1,e) = c*delta%x(i,1,1,e)*delta%x(i,1,1,e) &
               * sqrt(b_beta/(aijaij + neko_eps)) &
               * coef%mult(i,1,1,e)
       end do
    end do
    !$omp end parallel do
    if (if_corr) then
       temperature => neko_registry%get_field_by_name(scalar_name)
       call neko_scratch_registry%request_field(dtdx, temp_indices_buoy(1), .false.)
       call neko_scratch_registry%request_field(dtdy, temp_indices_buoy(2), .false.)
       call neko_scratch_registry%request_field(dtdz, temp_indices_buoy(3), .false.)
 
       ! Calculate Richardson number
       gmag = sqrt(vlsc2(g, g, 3))
       if (gmag > neko_eps) then
          n = g / gmag
       else
          call neko_error("The gravity vector must have at least one nonzero component")
       endif
       call grad(dtdx%x, dtdy%x, dtdz%x, temperature%x, coef)
       !$omp parallel do private(e, i, j, buoyancy, du_n, du_parallel, &
       !$omp& sh, shear_sq, ri, correction)
       do e = 1, coef%msh%nelv
          !OCL NORECURRENCE, NOVREC, NOALIAS
          !DIR$ CONCURRENT
          !DIR$ IVDEP
          !GCC$ ivdep
          do i = 1, coef%Xh%lxyz
 
             ! Buoyancy component (numerator in Ri definition)
             buoyancy = (-g(1) * dtdx%x(i,1,1,e) - &
                  g(2) * dtdy%x(i,1,1,e) - &
                  g(3) * dtdz%x(i,1,1,e)) / ref_temp
 
             ! Shear component (denominator in Ri definition)
             ! Directional derivative of velocity
             du_n(1) = a11%x(i,1,1,e)*n(1) + a12%x(i,1,1,e)*n(2) +&
                  a13%x(i,1,1,e)*n(3)
             du_n(2) = a21%x(i,1,1,e)*n(1) + a22%x(i,1,1,e)*n(2) +&
                  a23%x(i,1,1,e)*n(3)
             du_n(3) = a31%x(i,1,1,e)*n(1) + a32%x(i,1,1,e)*n(2) +&
                  a33%x(i,1,1,e)*n(3)
 
             ! Component parallel to n
             du_parallel = du_n(1)*n(1) + du_n(2)*n(2) + du_n(3)*n(3)
 
             ! Perpendicular (shear) components
             do j = 1, 3
                sh(j) = du_n(j) - du_parallel*n(j)
             end do
 
             ! Shear magnitude squared
             shear_sq = sh(1)*sh(1) + sh(2)*sh(2) + sh(3)*sh(3)
 
             ! Richardson number
             ri = buoyancy / (shear_sq + neko_eps)
 
             if (ri .le. ri_c) then
                correction = sqrt(1 - ri/ri_c)
                nut%x(i,1,1,e) = correction * nut%x(i,1,1,e)
             else
                nut%x(i,1,1,e) = neko_eps
             end if
          end do
       end do
       !$omp end parallel do
       call neko_scratch_registry%relinquish_field(temp_indices_buoy)
    end if
 
    call coef%gs_h%op(nut, gs_op_add)
    call col2(nut%x, coef%mult, nut%dof%size())
 
    call neko_scratch_registry%relinquish_field(temp_indices)
  end subroutine vreman_compute_cpu
 
end module vreman_cpu