interpolation.f90

Go to the documentation of this file.

! Copyright (c) 2021-2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module interpolation
  use neko_config, only : neko_bcknd_device
  use num_types, only : rp
  use device
  use fast3d, only : setup_intp
  use tensor, only : tnsr3d
  use tensor_cpu, only : tnsr3d_cpu
  use space, only : space_t, operator(.eq.), gl, gll
  use utils, only : neko_error
  use, intrinsic :: iso_c_binding
  implicit none
  private
 
  type, public :: interpolator_t
     type(space_t), pointer :: xh
     type(space_t), pointer :: yh
     real(kind=rp), allocatable :: xh_to_yh(:,:), xh_to_yht(:,:)
     real(kind=rp), allocatable :: yh_to_xh(:,:), yh_to_xht(:,:)
     type(c_ptr) :: xh_yh_d = c_null_ptr
     type(c_ptr) :: xh_yht_d = c_null_ptr
     type(c_ptr) :: yh_xh_d = c_null_ptr
     type(c_ptr) :: yh_xht_d = c_null_ptr
   contains
 
     procedure, pass(this) :: init => interpolator_init
     procedure, pass(this) :: free => interpolator_free
     procedure, pass(this) :: map => interpolator_map
     procedure, pass(this) :: map_host => interpolator_map_host
 
  end type interpolator_t
 
contains
 
  subroutine interpolator_init(this, Xh, Yh)
    class(interpolator_t), intent(inout), target :: this
    type(space_t), intent(inout), target :: Xh
    type(space_t), intent(inout), target :: Yh
    integer :: deg_derivate
 
    call this%free()
 
    allocate(this%Xh_to_Yh(yh%lx, xh%lx))
    allocate(this%Xh_to_YhT(xh%lx, yh%lx))
    allocate(this%Yh_to_Xh(xh%lx, yh%lx))
    allocate(this%Yh_to_XhT(yh%lx, xh%lx))
 
    if (xh%t .eq. gll .and. yh%t .eq. gll) then
    else if ((xh%t .eq. gl .and. yh%t .eq. gll) .or. &
         (yh%t .eq. gl .and. xh%t .eq. gll)) then
    else
       call neko_error('Unsupported interpolation')
    end if
    deg_derivate = 0
    call setup_intp(this%Xh_to_Yh, this%Xh_to_YhT, &
         yh%zg, xh%zg, yh%lx, xh%lx, deg_derivate)
    call setup_intp(this%Yh_to_Xh, this%Yh_to_XhT, &
         xh%zg, yh%zg, xh%lx, yh%lx, deg_derivate)
 
    this%Xh => xh
    this%Yh => yh
    if (neko_bcknd_device .eq. 1) then
       call device_map(this%Xh_to_Yh, this%Xh_Yh_d, yh%lx*xh%lx)
       call device_map(this%Xh_to_YhT, this%Xh_YhT_d, yh%lx*xh%lx)
       call device_map(this%Yh_to_Xh, this%Yh_Xh_d, yh%lx*xh%lx)
       call device_map(this%Yh_to_XhT, this%Yh_XhT_d, yh%lx*xh%lx)
       call device_memcpy(this%Xh_to_Yh, this%Xh_Yh_d, yh%lx*xh%lx, &
            host_to_device, sync = .false.)
       call device_memcpy(this%Xh_to_YhT, this%Xh_YhT_d, yh%lx*xh%lx, &
            host_to_device, sync = .false.)
       call device_memcpy(this%Yh_to_Xh, this%Yh_Xh_d, yh%lx*xh%lx, &
            host_to_device, sync = .false.)
       call device_memcpy(this%Yh_to_XhT, this%Yh_XhT_d, yh%lx*xh%lx, &
            host_to_device, sync = .true.)
    end if
 
  end subroutine interpolator_init
 
  subroutine interpolator_free(this)
    class(interpolator_t), intent(inout) :: this
 
    if (allocated(this%Xh_to_Yh)) then
       if (neko_bcknd_device .eq. 1) then
          call device_unmap(this%Xh_to_Yh, this%Xh_Yh_d)
       end if
       deallocate(this%Xh_to_Yh)
    end if
    if (allocated(this%Xh_to_YhT)) then
       if (neko_bcknd_device .eq. 1) then
          call device_unmap(this%Xh_to_YhT, this%Xh_YhT_d)
       end if
       deallocate(this%Xh_to_YhT)
    end if
    if (allocated(this%Yh_to_Xh)) then
       if (neko_bcknd_device .eq. 1) then
          call device_unmap(this%Yh_to_Xh, this%Yh_Xh_d)
       end if
       deallocate(this%Yh_to_Xh)
    end if
    if (allocated(this%Yh_to_XhT)) then
       if (neko_bcknd_device .eq. 1) then
          call device_unmap(this%Yh_to_XhT, this%Yh_XhT_d)
       end if
       deallocate(this%Yh_to_XhT)
    end if
 
    nullify(this%Xh)
    nullify(this%Yh)
 
  end subroutine interpolator_free
 
  subroutine interpolator_map(this, y, x, nel, to_space)
    class(interpolator_t), intent(inout) :: this
    integer :: nel
    type(space_t) :: to_space
    real(kind=rp), intent(in) :: x(this%Xh%lx, this%Xh%lx, this%Xh%lx, nel)
    real(kind=rp), intent(inout) :: y(this%Yh%lx, this%Yh%lx, this%Yh%lx, nel)
    if (to_space .eq. this%Yh) then
       call tnsr3d(y, this%Yh%lx, x, &
            this%Xh%lx, this%Yh_to_XhT, &
            this%Yh_to_Xh, this%Yh_to_Xh, nel)
    else if (to_space .eq. this%Xh) then
       call tnsr3d(y, this%Xh%lx, x, &
            this%Yh%lx, this%Yh_to_Xh, &
            this%Yh_to_XhT, this%Yh_to_XhT, nel)
    else
       call neko_error('Invalid interpolation')
    end if
  end subroutine interpolator_map
 
 
  subroutine interpolator_map_host(this, y, x, nel, to_space)
    class(interpolator_t), intent(inout) :: this
    integer :: nel
    type(space_t) :: to_space
    real(kind=rp), intent(inout) :: x(this%Xh%lx, this%Xh%lx, this%Xh%lx, nel)
    real(kind=rp), intent(inout) :: y(this%Yh%lx, this%Yh%lx, this%Yh%lx, nel)
    if (to_space .eq. this%Yh) then
       call tnsr3d_cpu(y, this%Yh%lx, x, &
            this%Xh%lx, this%Yh_to_XhT, &
            this%Yh_to_Xh, this%Yh_to_Xh, nel)
    else if (to_space .eq. this%Xh) then
       call tnsr3d_cpu(y, this%Xh%lx, x, &
            this%Yh%lx, this%Yh_to_Xh, &
            this%Yh_to_XhT, this%Yh_to_XhT, nel)
    else
       call neko_error('Invalid interpolation')
    end if
  end subroutine interpolator_map_host
 
 
end module interpolation