spalding.f90

Go to the documentation of this file.

! Copyright (c) 2024, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
module spalding
  use field, only: field_t
  use num_types, only : rp
  use json_module, only : json_file
  use coefs, only : coef_t
  use neko_config, only : neko_bcknd_device
  use wall_model, only : wall_model_t
  use wall_sampler, only : wall_sampler_t
  use wall_sampler_fctry, only : wall_sampler_factory
  use user_intf, only : user_t
  use registry, only : neko_registry
  use json_utils, only : json_get_or_default, json_get_or_lookup
  use spalding_cpu, only : spalding_compute_cpu
  use spalding_device, only : spalding_compute_device
  use field_math, only: field_invcol3
  use vector, only : vector_t
  use math, only: masked_gather_copy_0
  use device_math, only: device_masked_gather_copy_0
  use scratch_registry, only : neko_scratch_registry
  use logger, only : log_size, neko_log
 
  implicit none
  private
 
  type, public, extends(wall_model_t) :: spalding_t
     real(kind=rp) :: kappa = 0.41_rp
     real(kind=rp) :: b = 5.2_rp
     type(vector_t) :: nu
     ! The fluid density at the boundary
     type(vector_t) :: rho_w
     type(vector_t) :: u_s, v_s, w_s
   contains
     procedure, pass(this) :: init => spalding_init
     procedure, pass(this) :: partial_init => spalding_partial_init
     procedure, pass(this) :: finalize => spalding_finalize
     procedure, pass(this) :: init_from_components => &
          spalding_init_from_components
     procedure, pass(this) :: free => spalding_free
     procedure, pass(this) :: compute_nu => spalding_compute_nu
     procedure, pass(this) :: compute => spalding_compute
  end type spalding_t
 
contains
  subroutine spalding_init(this, scheme_name, coef, msk, facet, json)
    class(spalding_t), intent(inout) :: this
    character(len=*), intent(in) :: scheme_name
    type(coef_t), intent(in) :: coef
    integer, intent(in) :: msk(:)
    integer, intent(in) :: facet(:)
    type(json_file), intent(inout) :: json
    real(kind=rp) :: kappa, b
    class(wall_sampler_t), allocatable :: sampler
 
    call json_get_or_lookup(json, "kappa", kappa)
    call json_get_or_lookup(json, "B", b)
 
    call wall_sampler_factory(sampler, json)
    call this%init_from_components(scheme_name, coef, msk, facet, sampler, &
         kappa, b)
  end subroutine spalding_init
 
  subroutine spalding_partial_init(this, coef, scheme_name, json)
    class(spalding_t), intent(inout) :: this
    type(coef_t), intent(in) :: coef
    character(len=*), intent(in) :: scheme_name
    type(json_file), intent(inout) :: json
    character(len=LOG_SIZE) :: log_buf
 
    call this%partial_init_base(coef, scheme_name, json)
    call json_get_or_lookup(json, "kappa", this%kappa)
    call json_get_or_lookup(json, "B", this%B)
 
    call neko_log%section('Wall model')
    write(log_buf, '(A)') 'Model : Spalding'
    call neko_log%message(log_buf)
    write(log_buf, '(A, E15.7)') 'kappa : ', this%kappa
    call neko_log%message(log_buf)
    write(log_buf, '(A, E15.7)') 'B : ', this%B
    call neko_log%message(log_buf)
    call neko_log%end_section()
 
  end subroutine spalding_partial_init
 
  subroutine spalding_finalize(this, msk, facet, bc_name, user)
    class(spalding_t), intent(inout) :: this
    integer, intent(in) :: msk(:)
    integer, intent(in) :: facet(:)
    character(len=*), optional, intent(in) :: bc_name
    type(user_t), target, optional, intent(in) :: user
 
    call this%finalize_base(msk, facet, bc_name, user)
    call this%nu%init(this%n_nodes)
    call this%rho_w%init(this%n_nodes)
    call this%validate_single_sample()
    call this%u_s%init(this%n_nodes)
    call this%v_s%init(this%n_nodes)
    call this%w_s%init(this%n_nodes)
  end subroutine spalding_finalize
 
  subroutine spalding_init_from_components(this, scheme_name, coef, msk, &
       facet, sampler, kappa, B)
    class(spalding_t), intent(inout) :: this
    character(len=*), intent(in) :: scheme_name
    type(coef_t), intent(in) :: coef
    integer, intent(in) :: msk(:)
    integer, intent(in) :: facet(:)
    class(wall_sampler_t), allocatable, intent(inout) :: sampler
    real(kind=rp), intent(in) :: kappa
    real(kind=rp), intent(in) :: b
 
    call this%free()
    call this%init_base(scheme_name, coef, msk, facet, sampler)
 
    this%kappa = kappa
    this%B = b
 
    call this%nu%init(this%n_nodes)
    call this%rho_w%init(this%n_nodes)
    call this%validate_single_sample()
    call this%u_s%init(this%n_nodes)
    call this%v_s%init(this%n_nodes)
    call this%w_s%init(this%n_nodes)
  end subroutine spalding_init_from_components
 
  subroutine spalding_compute_nu(this)
    class(spalding_t), intent(inout) :: this
    type(field_t), pointer :: temp
    integer :: idx
 
    call neko_scratch_registry%request_field(temp, idx, .false.)
    call field_invcol3(temp, this%mu, this%rho)
 
    if (neko_bcknd_device .eq. 1) then
       call device_masked_gather_copy_0(this%nu%x_d, temp%x_d, this%msk_d, &
            temp%size(), this%nu%size())
       call device_masked_gather_copy_0(this%rho_w%x_d, this%rho%x_d, &
            this%msk_d, &
            this%rho%size(), this%rho_w%size())
    else
       call masked_gather_copy_0(this%nu%x, temp%x, this%msk, temp%size(), &
            this%nu%size())
       call masked_gather_copy_0(this%rho_w%x, this%rho%x, this%msk, &
            this%rho%size(), this%rho_w%size())
    end if
 
    call neko_scratch_registry%relinquish_field(idx)
  end subroutine spalding_compute_nu
 
  subroutine spalding_free(this)
    class(spalding_t), intent(inout) :: this
 
    call this%nu%free()
    call this%rho_w%free()
    call this%u_s%free()
    call this%v_s%free()
    call this%w_s%free()
    call this%free_base()
 
  end subroutine spalding_free
 
  subroutine spalding_compute(this, t, tstep)
    class(spalding_t), intent(inout) :: this
    real(kind=rp), intent(in) :: t
    integer, intent(in) :: tstep
    type(field_t), pointer :: u
    type(field_t), pointer :: v
    type(field_t), pointer :: w
 
    call this%compute_nu()
 
    u => neko_registry%get_field("u")
    v => neko_registry%get_field("v")
    w => neko_registry%get_field("w")
 
    call this%sampler%sample(u, this%u_s)
    call this%sampler%sample(v, this%v_s)
    call this%sampler%sample(w, this%w_s)
 
    if (neko_bcknd_device .eq. 1) then
       call spalding_compute_device(this%u_s%x_d, this%v_s%x_d, &
            this%w_s%x_d, &
            this%n_x%x_d, this%n_y%x_d, this%n_z%x_d, &
            this%nu%x_d, this%rho_w%x_d, this%sampler%h%x_d, &
            this%tau_x%x_d, this%tau_y%x_d, this%tau_z%x_d, &
            this%n_nodes, &
            this%kappa, this%B, tstep)
    else
       call spalding_compute_cpu(this%u_s%x, this%v_s%x, this%w_s%x, &
            this%n_x%x, this%n_y%x, this%n_z%x, &
            this%nu%x, this%rho_w%x, this%sampler%h%x, &
            this%tau_x%x, this%tau_y%x, this%tau_z%x, &
            this%n_nodes, &
            this%kappa, this%B, tstep)
    end if
 
    nullify(u, v, w)
 
  end subroutine spalding_compute
end module spalding