field_array.f90

Go to the documentation of this file.

! Copyright (c) 2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module field_array
  use, intrinsic :: iso_fortran_env, only : error_unit
  use field, only : field_wrapper_t, field_t
  use iso_c_binding, only : c_ptr
  use num_types, only : rp
  use space, only : space_t
  use dofmap, only : dofmap_t
  use mesh, only : mesh_t
  use utils, only : neko_error
  use comm, only : pe_rank
  implicit none
  private
 
  type, public :: field_array_t
     type(field_wrapper_t), allocatable :: items(:)
   contains
     procedure, pass(this) :: init => field_array_init
     procedure, pass(this) :: free => field_array_free
     procedure, pass(this) :: append => field_array_append
     generic :: get => get_by_index, get_by_name
     procedure, pass(this) :: get_by_index => field_array_get_by_index
     procedure, pass(this) :: get_by_name => field_array_get_by_name
     generic :: assign => assign_to_field, assign_to_field_wrapper
     procedure, pass(this) :: assign_to_field => field_array_assign_to_field
     procedure, pass(this) :: assign_to_field_wrapper => &
          field_array_assign_to_field_wrapper
 
     procedure, pass(this) :: x_d => field_array_x_d
     procedure, pass(this) :: x => field_array_x
     procedure, pass(this) :: size => field_array_size
     procedure, pass(this) :: item_size => field_array_item_size
     procedure, pass(this) :: dof => field_array_dof
     procedure, pass(this) :: xh => field_array_space
     procedure, pass(this) :: msh => field_array_msh
     procedure, pass(this) :: internal_dofmap => field_array_internal_dofmap
     procedure, pass(this) :: name => field_array_name
  end type field_array_t
 
contains
  subroutine field_array_init(this, size)
    class(field_array_t), intent(inout) :: this
    integer, intent(in) :: size
 
    call this%free()
 
    allocate(this%items(size))
  end subroutine field_array_init
 
  pure function field_array_size(this) result(n)
    class(field_array_t), intent(in) :: this
    integer :: n
    n = size(this%items)
  end function field_array_size
 
  function field_array_get_by_index(this, i) result(f)
    class(field_array_t), intent(inout) :: this
    type(field_t), pointer :: f
    integer, intent(in) :: i
    f => this%items(i)%field
  end function field_array_get_by_index
 
  function field_array_get_by_name(this, name) result(f)
    class(field_array_t), intent(inout) :: this
    type(field_t), pointer :: f
    character(len=*), intent(in) :: name
    integer :: i
 
    nullify(f)
 
    do i = 1, this%size()
       if (this%name(i) .eq. trim(name)) then
          f => this%items(i)%field
          return
       end if
    end do
 
    if (pe_rank .eq. 0) then
       write(error_unit,*) "Current field list contents:"
 
       do i = 1, this%size()
          write(error_unit,*) "- ", this%name(i)
       end do
    end if
 
    call neko_error("No field with name " // trim(name) // " found in list")
  end function field_array_get_by_name
 
  subroutine field_array_append(this, f)
    class(field_array_t), intent(inout) :: this
    class(field_t), intent(in) :: f
    type(field_wrapper_t), allocatable :: tmp(:)
    integer :: len
 
    len = size(this%items)
 
    allocate(tmp(len+1))
    tmp(1:len) = this%items
    call move_alloc(tmp, this%items)
    call this%items(len+1)%init(f)
 
  end subroutine field_array_append
 
  subroutine field_array_free(this)
    class(field_array_t), intent(inout) :: this
    integer :: i, n_fields
 
    if (allocated(this%items)) then
       n_fields = this%size()
       do i = 1, n_fields
          call this%items(i)%free()
       end do
       deallocate(this%items)
    end if
 
  end subroutine field_array_free
 
  function field_array_x_d(this, i) result(x_d)
    class(field_array_t), intent(in) :: this
    integer, intent(in) :: i
    type(c_ptr) :: x_d
 
    x_d = this%items(i)%field%x_d
  end function field_array_x_d
 
  function field_array_x(this, i) result(x)
    class(field_array_t), target, intent(in) :: this
    real(kind=rp), pointer, contiguous :: x(:,:,:,:)
    integer, intent(in) :: i
    x => this%items(i)%field%x
  end function field_array_x
 
  function field_array_item_size(this, i) result(size)
    class(field_array_t), target, intent(in) :: this
    integer, intent(in) :: i
    integer :: size
 
    size = this%items(i)%field%size()
 
  end function field_array_item_size
 
  subroutine field_array_assign_to_field(this, i, f)
    class(field_array_t), intent(inout) :: this
    integer, intent(in) :: i
    type(field_t), intent(in) :: f
 
    call this%items(i)%init(f)
 
  end subroutine field_array_assign_to_field
 
  subroutine field_array_assign_to_field_wrapper(this, i, wrapper)
    class(field_array_t), intent(inout) :: this
    integer, intent(in) :: i
    type(field_wrapper_t), target, intent(in) :: wrapper
 
    call this%items(i)%init(wrapper%field)
  end subroutine field_array_assign_to_field_wrapper
 
  function field_array_dof(this, i) result(result)
    class(field_array_t), target, intent(in) :: this
    integer, intent(in) :: i
    type(dofmap_t), pointer :: result
 
    result => this%items(i)%field%dof
  end function field_array_dof
 
  function field_array_space(this, i) result(result)
    class(field_array_t), target, intent(in) :: this
    integer, intent(in) :: i
    type(space_t), pointer :: result
 
    result => this%items(i)%field%Xh
  end function field_array_space
 
  function field_array_msh(this, i) result(result)
    class(field_array_t), target, intent(in) :: this
    integer, intent(in) :: i
    type(mesh_t), pointer :: result
 
    result => this%items(i)%field%msh
  end function field_array_msh
 
  function field_array_internal_dofmap(this, i) result(result)
    class(field_array_t), target, intent(in) :: this
    integer, intent(in) :: i
    logical :: result
 
    result = this%items(i)%field%internal_dofmap
  end function field_array_internal_dofmap
 
  function field_array_name(this, i) result(result)
    class(field_array_t), target, intent(in) :: this
    integer, intent(in) :: i
    character(len=80) :: result
 
    result = this%items(i)%field%name
  end function field_array_name
 
end module field_array