source_term_handler.f90

Go to the documentation of this file.

 
! Copyright (c) 2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module source_term_handler
  use neko_config, only: neko_bcknd_device
  use num_types, only: rp
  use source_term, only: source_term_wrapper_t, source_term_t, &
       source_term_factory
  use field, only: field_t
  use field_list, only: field_list_t
  use json_utils, only: json_get, json_extract_item, json_get_or_default
  use json_module, only: json_file
  use coefs, only: coef_t
  use user_intf, only: user_t
  use field_math, only: field_rzero, field_copy, field_add2, field_col2
  use math, only : col2
  use device_math, only : device_col2
  use time_state, only : time_state_t
  use scratch_registry, only : neko_scratch_registry
  implicit none
  private
 
  type, abstract, public :: source_term_handler_t
     class(source_term_wrapper_t), allocatable :: source_terms(:)
     type(field_list_t) :: rhs_fields
     type(coef_t), pointer :: coef
     type(user_t), pointer :: user
     character(len=:), allocatable :: scheme_name
     integer :: n_unextrapolated = 0
 
   contains
     procedure, pass(this) :: init_base => source_term_handler_init_base
     procedure, pass(this) :: free => source_term_handler_free
     procedure, pass(this) :: compute => source_term_handler_compute
     generic :: add => add_source_term, add_json_source_terms
     procedure, pass(this) :: add_source_term => &
          source_term_handler_add_source_term
     procedure, pass(this) :: add_json_source_terms => &
          source_term_handler_add_json_source_terms
     procedure(source_term_handler_init_user_source), &
          nopass, deferred :: init_user_source
  end type source_term_handler_t
 
  abstract interface
     subroutine source_term_handler_init_user_source(source_term, rhs_fields, &
          coef, user, scheme_name)
       import :: source_term_t, field_list_t, coef_t, user_t
       class(source_term_t), allocatable, intent(inout) :: source_term
       type(field_list_t) :: rhs_fields
       type(coef_t), intent(in) :: coef
       type(user_t), intent(in) :: user
       character(len=*), intent(in) :: scheme_name
     end subroutine source_term_handler_init_user_source
  end interface
 
contains
 
  subroutine source_term_handler_init_base(this, rhs_fields, coef, user, &
       scheme_name)
    class(source_term_handler_t), intent(inout) :: this
    type(field_list_t), intent(in) :: rhs_fields
    type(coef_t), target, intent(in) :: coef
    type(user_t), target, intent(in) :: user
    character(len=*), intent(in) :: scheme_name
 
    call this%free()
 
    ! We package the fields for the source term to operate on in a field list.
    this%rhs_fields = rhs_fields
    this%coef => coef
    this%user => user
    this%scheme_name = trim(scheme_name)
 
  end subroutine source_term_handler_init_base
 
 
  subroutine source_term_handler_free(this)
    class(source_term_handler_t), intent(inout) :: this
    integer :: i
 
    call this%rhs_fields%free()
 
    if (allocated(this%source_terms)) then
       do i = 1, size(this%source_terms)
          call this%source_terms(i)%free()
       end do
       deallocate(this%source_terms)
    end if
    this%n_unextrapolated = 0
 
    nullify(this%coef)
    nullify(this%user)
 
    if (allocated(this%scheme_name)) then
       deallocate(this%scheme_name)
    end if
 
  end subroutine source_term_handler_free
 
  subroutine source_term_handler_compute(this, time, extrapolate, scale)
    class(source_term_handler_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    logical, intent(in) :: extrapolate
    type(field_t), intent(in), optional :: scale
    type(field_list_t) :: stash
    type(field_t), pointer :: f, s
    integer, allocatable :: stash_idx(:)
    integer :: i, n_rhs
 
    n_rhs = this%rhs_fields%size()
 
    ! The terms that are not extrapolated are added on top of the
    ! right-hand side, which is stashed in scratch fields meanwhile.
    if (.not. extrapolate) then
       if (this%n_unextrapolated .eq. 0) return
       call stash%init(n_rhs)
       allocate(stash_idx(n_rhs))
       do i = 1, n_rhs
          f => this%rhs_fields%get(i)
          call neko_scratch_registry%request_field(s, stash_idx(i), .false.)
          call field_copy(s, f)
          call stash%assign(i, s)
       end do
    end if
 
    do i = 1, n_rhs
       f => this%rhs_fields%get(i)
       call field_rzero(f)
    end do
 
    ! Add contribution from the selected source terms. If time permits.
    if (allocated(this%source_terms)) then
 
       do i = 1, size(this%source_terms)
          if (this%source_terms(i)%source_term%extrapolate .neqv. &
               extrapolate) cycle
          call this%source_terms(i)%source_term%compute(time)
       end do
 
       ! Multiply by mass matrix and scale
       do i = 1, n_rhs
          f => this%rhs_fields%get(i)
          if (neko_bcknd_device .eq. 1) then
             call device_col2(f%x_d, this%coef%B_d, f%size())
          else
             call col2(f%x, this%coef%B, f%size())
          end if
          if (present(scale)) call field_col2(f, scale)
       end do
 
    end if
 
    ! Add back the stashed right-hand side
    if (.not. extrapolate) then
       do i = 1, n_rhs
          f => this%rhs_fields%get(i)
          s => stash%get(i)
          call field_add2(f, s)
       end do
       call neko_scratch_registry%relinquish_field(stash_idx)
       call stash%free()
       deallocate(stash_idx)
    end if
 
  end subroutine source_term_handler_compute
 
  subroutine source_term_handler_count_unextrapolated(this)
    class(source_term_handler_t), intent(inout) :: this
    integer :: i
 
    this%n_unextrapolated = 0
    if (.not. allocated(this%source_terms)) return
 
    do i = 1, size(this%source_terms)
       if (.not. this%source_terms(i)%source_term%extrapolate) then
          this%n_unextrapolated = this%n_unextrapolated + 1
       end if
    end do
 
  end subroutine source_term_handler_count_unextrapolated
 
  subroutine source_term_handler_add_json_source_terms(this, json, name)
    class(source_term_handler_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    character(len=*), intent(in) :: name
 
    class(source_term_wrapper_t), dimension(:), allocatable :: temp
 
    ! A single source term as its own json_file.
    type(json_file) :: source_subdict
    character(len=:), allocatable :: type
    integer :: n_sources, i, i0
 
    if (json%valid_path(name)) then
       ! Get the number of source terms.
       call json%info(name, n_children = n_sources)
 
       if (allocated(this%source_terms)) then
          i0 = size(this%source_terms)
          call move_alloc(this%source_terms, temp)
          allocate(this%source_terms(i0 + n_sources))
          if (allocated(temp)) then
             do i = 1, i0
                call move_alloc(temp(i)%source_term, &
                     this%source_terms(i)%source_term)
             end do
          end if
       else
          i0 = 0
          allocate(this%source_terms(n_sources))
       end if
 
       do i = 1, n_sources
          ! Create a new json containing just the subdict for this source.
          call json_extract_item(json, name, i, source_subdict)
          call json_get(source_subdict, "type", type)
 
          ! The user source is treated separately
          if (trim(type) .eq. "user") then
 
             call this%init_user_source(this%source_terms(i+ i0)%source_term, &
                  this%rhs_fields, this%coef, this%user, this%scheme_name)
 
             call json_get_or_default(source_subdict, "start_time", &
                  this%source_terms(i + i0)%source_term%start_time, 0.0_rp)
             call json_get_or_default(source_subdict, "end_time", &
                  this%source_terms(i + i0)%source_term%end_time, huge(0.0_rp))
          else
             call source_term_factory(this%source_terms(i + i0)%source_term, &
                  source_subdict, this%rhs_fields, this%coef, &
                  this%scheme_name)
          end if
       end do
 
       call source_term_handler_count_unextrapolated(this)
    end if
 
  end subroutine source_term_handler_add_json_source_terms
 
  subroutine source_term_handler_add_source_term(this, source_term)
    class(source_term_handler_t), intent(inout) :: this
    class(source_term_t), intent(in) :: source_term
    class(source_term_wrapper_t), dimension(:), allocatable :: temp
 
    integer :: n_sources, i
 
    if (allocated(this%source_terms)) then
       n_sources = size(this%source_terms)
    else
       n_sources = 0
    end if
 
    call move_alloc(this%source_terms, temp)
    allocate(this%source_terms(n_sources + 1))
 
    if (allocated(temp)) then
       do i = 1, n_sources
          call move_alloc(temp(i)%source_term, &
               this%source_terms(i)%source_term)
       end do
    end if
 
    this%source_terms(n_sources + 1)%source_term = source_term
 
    call source_term_handler_count_unextrapolated(this)
 
  end subroutine source_term_handler_add_source_term
end module source_term_handler