user_stats.f90

Go to the documentation of this file.

! Copyright (c) 2024-2025, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
 
module user_stats
  use num_types, only : rp, dp, sp
  use json_module, only : json_file
  use simulation_component, only : simulation_component_t
  use registry, only : neko_registry
  use field, only : field_t
  use case, only : case_t
  use mean_field_output, only : mean_field_output_t
  use json_utils, only : json_get, json_get_or_default, &
      json_get_or_lookup_or_default
  use mean_field, only : mean_field_t
  use coefs, only : coef_t
  use time_state, only : time_state_t
  use time_based_controller, only : time_based_controller_t
  use utils, only : neko_fname_len, filename_suffix, filename_tslash_pos, &
       neko_varname_len
  implicit none
  private
 
  type, public, extends(simulation_component_t) :: user_stats_t
 
     real(kind=rp) :: start_time
     real(kind=rp) :: time
     type(mean_field_t), allocatable :: mean_fields(:)
     integer :: n_avg_fields = 0
     character(len=NEKO_VARNAME_LEN), allocatable :: field_names(:)
     type(mean_field_output_t), private :: output
     logical :: default_fname = .true.
 
   contains
     procedure, pass(this) :: init => user_stats_init_from_json
     generic :: init_from_components => &
          init_from_controllers, init_from_controllers_properties
     procedure, pass(this) :: init_from_controllers => &
          user_stats_init_from_controllers
     procedure, pass(this) :: init_from_controllers_properties => &
          user_stats_init_from_controllers_properties
     procedure, private, pass(this) :: init_common => user_stats_init_common
     procedure, pass(this) :: free => user_stats_free
     procedure, pass(this) :: compute_ => user_stats_compute
     procedure, pass(this) :: restart_ => user_stats_restart
  end type user_stats_t
 
contains
 
  subroutine user_stats_init_from_json(this, json, case)
    class(user_stats_t), intent(inout), target :: this
    type(json_file), intent(inout) :: json
    class(case_t), intent(inout), target :: case
    character(len=:), allocatable :: filename
    character(len=:), allocatable :: avg_dir
    character(len=:), allocatable :: name
 
    call json_get_or_default(json, "name", name, "user_stats")
    call this%init_base(json, case)
 
    call json%info('fields', n_children = this%n_avg_fields)
    call json_get(json, 'fields', this%field_names)
    call json_get_or_lookup_or_default(json, 'start_time', this%start_time, 0.0_rp)
    call json_get_or_default(json, 'avg_direction', avg_dir, 'none')
 
    if (json%valid_path('output_filename')) then
       call json_get(json, 'output_filename', filename)
       call user_stats_init_common(this, name, this%start_time, &
            case%fluid%c_Xh, avg_dir, filename = filename)
    else
       call user_stats_init_common(this, name, this%start_time, &
            case%fluid%c_Xh, avg_dir)
    end if
 
  end subroutine user_stats_init_from_json
 
  subroutine user_stats_restart(this, time)
    class(user_stats_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    character(len=NEKO_FNAME_LEN) :: fname
    character(len=5) :: prefix, suffix
    integer :: last_slash_pos
    real(kind=rp) :: t
    t = time%t
    if (t .gt. this%time) this%time = t
    if (this%default_fname) then
       fname = this%output%file_%get_base_fname()
       write (prefix, '(I5)') &
            this%output%file_%file_type%get_start_counter()
       call filename_suffix(fname, suffix)
       last_slash_pos = &
            filename_tslash_pos(fname)
       if (last_slash_pos .ne. 0) then
          fname = &
               trim(fname(1:last_slash_pos))// &
               "user_stats"//trim(adjustl(prefix))//"."//suffix
       else
          fname = "user_stats"// &
               trim(adjustl(prefix))//"."//suffix
       end if
       call this%output%init_base(fname)
    end if
  end subroutine user_stats_restart
 
  subroutine user_stats_init_from_controllers(this, name, case, order, &
       preprocess_controller, compute_controller, output_controller, &
       start_time, coef, avg_dir, filename, precision)
    class(user_stats_t), intent(inout) :: this
    character(len=*), intent(in) :: name
    class(case_t), intent(inout), target :: case
    integer :: order
    type(time_based_controller_t), intent(in) :: preprocess_controller
    type(time_based_controller_t), intent(in) :: compute_controller
    type(time_based_controller_t), intent(in) :: output_controller
    real(kind=rp), intent(in) :: start_time
    character(len=*), intent(in) :: avg_dir
    type(coef_t), intent(inout) :: coef
    character(len=*), intent(in), optional :: filename
    integer, intent(in), optional :: precision
 
    call this%init_base_from_components(case, order, preprocess_controller, &
         compute_controller, output_controller)
    call this%init_common(name, start_time, coef, avg_dir, filename, precision)
 
  end subroutine user_stats_init_from_controllers
 
  subroutine user_stats_init_from_controllers_properties(this, name, &
       case, order, preprocess_control, preprocess_value, compute_control, &
       compute_value, output_control, output_value, start_time, coef, avg_dir, &
       filename, precision)
    class(user_stats_t), intent(inout) :: this
    character(len=*), intent(in) :: name
    class(case_t), intent(inout), target :: case
    integer :: order
    character(len=*), intent(in) :: preprocess_control
    real(kind=rp), intent(in) :: preprocess_value
    character(len=*), intent(in) :: compute_control
    real(kind=rp), intent(in) :: compute_value
    character(len=*), intent(in) :: output_control
    real(kind=rp), intent(in) :: output_value
    real(kind=rp), intent(in) :: start_time
    character(len=*), intent(in) :: avg_dir
    type(coef_t), intent(inout) :: coef
    character(len=*), intent(in), optional :: filename
    integer, intent(in), optional :: precision
 
    call this%init_base_from_components(case, order, preprocess_control, &
         preprocess_value, compute_control, compute_value, output_control, &
         output_value)
    call this%init_common(name, start_time, coef, avg_dir, filename, precision)
 
  end subroutine user_stats_init_from_controllers_properties
 
 
  subroutine user_stats_init_common(this, name, start_time, coef, avg_dir, &
       filename, precision)
    class(user_stats_t), intent(inout) :: this
    character(len=*), intent(in) :: name
    character(len=*), intent(in), optional :: filename
    integer, intent(in), optional :: precision
    real(kind=rp), intent(in) :: start_time
    character(len=*), intent(in) :: avg_dir
    type(coef_t), intent(inout) :: coef
    integer :: i
    type(field_t), pointer :: field_to_avg
    character(len=1024) :: unique_name
    unique_name = name // "/"
 
    this%name = name
    this%start_time = start_time
    this%time = start_time
 
    if (present(filename)) then
       this%default_fname = .false.
    else
       this%default_fname = .true.
    end if
 
    allocate(this%mean_fields(this%n_avg_fields))
    do i = 1, this%n_avg_fields
       field_to_avg => neko_registry%get_field(trim(this%field_names(i)))
       call this%mean_fields(i)%init(field_to_avg, trim(unique_name) // &
            "mean_" // trim(this%field_names(i)))
    end do
 
    call this%output%init(this%mean_fields, this%n_avg_fields, &
         this%start_time, coef, avg_dir, name = filename, &
         path = this%case%output_directory)
    call this%case%output_controller%add(this%output, &
         this%output_controller%control_value, &
         this%output_controller%control_mode)
 
    nullify(field_to_avg)
 
  end subroutine user_stats_init_common
 
  subroutine user_stats_free(this)
    class(user_stats_t), intent(inout) :: this
    integer :: i
 
    call this%free_base()
 
    if (allocated(this%mean_fields)) then
       do i = 1, this%n_avg_fields
          call this%mean_fields(i)%free()
       end do
       deallocate(this%mean_fields)
    end if
 
    if (allocated(this%field_names)) then
       deallocate(this%field_names)
    end if
 
  end subroutine user_stats_free
 
  subroutine user_stats_compute(this, time)
    class(user_stats_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    integer :: i
 
    if (time%t .ge. this%start_time) then
       do i = 1, this%n_avg_fields
          call this%mean_fields(i)%update(time%t - this%time)
       end do
       this%time = time%t
    end if
 
  end subroutine user_stats_compute
 
end module user_stats