fluid_stats_simcomp.f90

Go to the documentation of this file.

! Copyright (c) 2024-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
module fluid_stats_simcomp
  use num_types, only : rp, dp, sp
  use json_module, only : json_file
  use simulation_component, only : simulation_component_t
  use registry, only : neko_registry
  use time_state, only : time_state_t
  use field, only : field_t
  use fluid_stats, only : fluid_stats_t
  use fluid_stats_output, only : fluid_stats_output_t
  use case, only : case_t
  use coefs, only : coef_t
  use utils, only : neko_fname_len, filename_suffix, neko_varname_len
  use logger, only : log_size, neko_log
  use json_utils, only : json_get, json_get_or_default, &
       json_get_or_lookup_or_default
  use comm, only : neko_comm
  use mpi_f08, only : mpi_wtime, mpi_barrier
  implicit none
  private
 
  type, public, extends(simulation_component_t) :: fluid_stats_simcomp_t
     type(fluid_stats_t) :: stats
     type(fluid_stats_output_t) :: stats_output
     real(kind=dp) :: start_time
     real(kind=dp) :: time
     character(len=:), allocatable :: base_filename
 
   contains
     procedure, pass(this) :: init => fluid_stats_simcomp_init_from_json
     procedure, pass(this) :: init_from_components => &
          fluid_stats_simcomp_init_from_components
     procedure, pass(this) :: free => fluid_stats_simcomp_free
     procedure, pass(this) :: compute_ => fluid_stats_simcomp_compute
     procedure, pass(this) :: output_ => fluid_stats_simcomp_compute
     procedure, pass(this) :: restart_ => fluid_stats_simcomp_restart
  end type fluid_stats_simcomp_t
 
contains
 
  subroutine fluid_stats_simcomp_init_from_json(this, json, case)
    class(fluid_stats_simcomp_t), target, intent(inout) :: this
    type(json_file), intent(inout) :: json
    class(case_t), intent(inout), target :: case
    character(len=:), allocatable :: filename
    character(len=NEKO_VARNAME_LEN), allocatable :: fields(:)
    character(len=:), allocatable :: hom_dir
    character(len=:), allocatable :: stat_set
    character(len=:), allocatable :: name
    real(kind=dp) :: start_time
    type(field_t), pointer :: u, v, w, p
    type(coef_t), pointer :: coef
 
    call json_get_or_default(json, "name", name, "fluid_stats")
    call this%init_base(json, case)
    call json_get_or_default(json, 'avg_direction', &
         hom_dir, 'none')
    call json_get_or_lookup_or_default(json, 'start_time', &
         start_time, 0.0_dp)
    call json_get_or_default(json, 'set_of_stats', &
         stat_set, 'full')
 
 
    u => neko_registry%get_field("u")
    v => neko_registry%get_field("v")
    w => neko_registry%get_field("w")
    p => neko_registry%get_field("p")
    coef => case%fluid%c_Xh
    this%name = name
 
    if (json%valid_path("output_filename")) then
       call json_get(json, "output_filename", filename)
       call fluid_stats_simcomp_init_from_components(this, name, u, v, w, p, &
            coef, start_time, hom_dir, stat_set, filename)
    else
       call fluid_stats_simcomp_init_from_components(this, name, u, v, w, p, &
            coef, start_time, hom_dir, stat_set)
    end if
 
    nullify(u, v, w, p, coef)
 
  end subroutine fluid_stats_simcomp_init_from_json
 
  subroutine fluid_stats_simcomp_init_from_components(this, name, u, v, w, p, &
       coef, start_time, hom_dir, stat_set, fname)
    class(fluid_stats_simcomp_t), target, intent(inout) :: this
    character(len=*), intent(in) :: name
    character(len=*), intent(in) :: hom_dir
    character(len=*), intent(in) :: stat_set
    real(kind=dp), intent(in) :: start_time
    type(field_t), intent(in), target :: u, v, w, p
    type(coef_t), intent(in), target :: coef
    character(len=*), intent(in), optional :: fname
    character(len=NEKO_FNAME_LEN) :: stats_fname
    character(len=LOG_SIZE) :: log_buf
    character(len=5) :: prefix
 
    call neko_log%section('Fluid stats')
    write(log_buf, '(A,E15.7)') 'Start time: ', start_time
    call neko_log%message(log_buf)
    write(log_buf, '(A,A)') 'Set of statistics: ', trim(stat_set)
    call neko_log%message(log_buf)
    write(log_buf, '(A,A)') 'Averaging in direction: ', trim(hom_dir)
    call neko_log%message(log_buf)
 
    call this%stats%init(coef, u, v, w, p, stat_set, name)
 
    this%name = name
    this%start_time = start_time
    this%time = start_time
    if (present(fname)) then
       this%base_filename = fname
    else
       this%base_filename = "fluid_stats"
    end if
    stats_fname = trim(this%base_filename) // "0"
 
    call this%stats_output%init(this%stats, this%start_time, &
         hom_dir = hom_dir, name = stats_fname, &
         path = this%case%output_directory)
 
    ! Statistics are averaged over the interval between two writes, so
    ! writing at the very start of the averaging would only produce an
    ! empty file. The schedule is anchored to the start of the averaging.
    call this%case%output_controller%add(this%stats_output, &
         this%output_controller%control_value, &
         this%output_controller%control_mode, &
         start_time = max(this%start_time, this%case%time%start_time), &
         write_at_start = .false.)
 
    call neko_log%end_section()
 
  end subroutine fluid_stats_simcomp_init_from_components
 
  subroutine fluid_stats_simcomp_free(this)
    class(fluid_stats_simcomp_t), intent(inout) :: this
    call this%free_base()
    call this%stats%free()
    call this%stats_output%free()
  end subroutine fluid_stats_simcomp_free
 
  subroutine fluid_stats_simcomp_restart(this, time)
    class(fluid_stats_simcomp_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    character(len=NEKO_FNAME_LEN) :: fname
    character(len=5) :: prefix, suffix
    real(kind=dp) :: t
 
    t = time%t
    if (t .gt. this%time) this%time = t
 
    fname = this%stats_output%file_%get_base_fname()
    write (prefix, '(I0)') &
         this%stats_output%file_%file_type%get_start_counter()
    call filename_suffix(fname, suffix)
    fname = trim(this%case%output_directory) // &
         trim(this%base_filename) // trim(prefix) // "." // trim(suffix)
    call this%stats_output%init_base(fname)
 
  end subroutine fluid_stats_simcomp_restart
 
  subroutine fluid_stats_simcomp_compute(this, time)
    class(fluid_stats_simcomp_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    real(kind=rp) :: delta_t
    real(kind=dp) :: sample_start_time, sample_time, t
    character(len=LOG_SIZE) :: log_buf
    integer :: ierr
 
    if (time%start_time .gt. this%start_time) then
       write(log_buf, '(A)') 'Simulation start time is later than the ' &
            // 'fluid stats start time.'
       call neko_log%warning(log_buf)
       write(log_buf, '(A,E15.7)') 'Simulation start time:', time%start_time
       call neko_log%warning(log_buf)
       write(log_buf, '(A,E15.7)') 'Fluid stats start time:', this%start_time
       call neko_log%warning(log_buf)
       write(log_buf, '(A)') 'Assigning the statistics start time to ' &
            // 'the simulation start time.'
       call neko_log%warning(log_buf)
       this%start_time = time%start_time
       this%time = time%start_time
    end if
 
    t = time%t
 
    if (t .ge. this%start_time) then
       delta_t = real(t - this%time, kind=rp) !This is only a real number
 
       call mpi_barrier(neko_comm, ierr)
 
       sample_start_time = mpi_wtime()
 
       call this%stats%update(delta_t)
       call mpi_barrier(neko_comm, ierr)
       this%time = t
 
       sample_time = mpi_wtime() - sample_start_time
 
       call neko_log%section('Fluid stats')
       write(log_buf, '(A,E15.7)') 'Sampling at time:', t
       call neko_log%message(log_buf)
       write(log_buf, '(A33,E15.7)') 'Simulationtime since last sample:', &
            delta_t
       call neko_log%message(log_buf)
       write(log_buf, '(A,E15.7)') 'Sampling time (s):', sample_time
       call neko_log%message(log_buf)
       call neko_log%end_section()
    end if
 
  end subroutine fluid_stats_simcomp_compute
 
end module fluid_stats_simcomp