wall_model_bc.f90

Go to the documentation of this file.

! Copyright (c) 2024-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module wall_model_bc
  use num_types, only : rp
  use, intrinsic :: iso_c_binding, only : c_ptr
  use utils, only : neko_error
  use json_utils, only : json_get
  use coefs, only : coef_t
  use wall_model, only : wall_model_t, wall_model_allocator
  use shear_stress, only : shear_stress_t
  use json_module, only : json_file
  use user_intf, only : user_t
  use time_state, only : time_state_t
  implicit none
  private
 
  type, public, extends(shear_stress_t) :: wall_model_bc_t
     class(wall_model_t), allocatable :: wall_model
     type(user_t), pointer :: user => null()
   contains
     procedure, pass(this) :: init => wall_model_bc_init
     procedure, pass(this) :: free => wall_model_bc_free
     procedure, pass(this) :: finalize => wall_model_bc_finalize
     procedure, pass(this) :: apply_scalar => wall_model_bc_apply_scalar
     procedure, pass(this) :: apply_vector => wall_model_bc_apply_vector
     procedure, pass(this) :: apply_scalar_dev => &
          wall_model_bc_apply_scalar_dev
     procedure, pass(this) :: apply_vector_dev => &
          wall_model_bc_apply_vector_dev
  end type wall_model_bc_t
 
contains
 
  subroutine wall_model_bc_apply_scalar(this, x, n, time, strong)
    class(wall_model_bc_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout), dimension(n) :: x
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
 
    call neko_error("The wall model bc is not applicable to scalar fields.")
 
  end subroutine wall_model_bc_apply_scalar
 
  subroutine wall_model_bc_apply_vector(this, x, y, z, n, time, strong)
    class(wall_model_bc_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout), dimension(n) :: x
    real(kind=rp), intent(inout), dimension(n) :: y
    real(kind=rp), intent(inout), dimension(n) :: z
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    integer :: i, m, k, fid
    real(kind=rp) :: magtau
    logical :: strong_
 
    if (present(strong)) then
       strong_ = strong
    else
       strong_ = .true.
    end if
 
    if (.not. present(time)) then
       call neko_error("wall_model_bc_apply_vector: time is required.")
    end if
 
    if (.not. strong_) then
       ! This runs inside the bc_list parallel region, so the update must be
       ! executed by a single thread; the barrier implied by 'end single' is
       ! what makes the tau field consistent before the Neumann bcs read it.
       !$omp single
       ! Compute the wall stress using the wall model.
       call this%wall_model%compute( real(time%t, kind=rp), time%tstep)
 
       ! Populate the 3D wall stress field for post-processing.
       call this%wall_model%compute_mag_field()
 
       ! Set the computed stress for application by the underlying Neumann
       ! boundary conditions.
       call this%set_stress(this%wall_model%tau_x, this%wall_model%tau_y, &
            this%wall_model%tau_z)
       !$omp end single
    end if
 
    ! Either add the stress to the RHS or apply the non-penetration condition
    call this%shear_stress_t%apply_vector(x, y, z, n, time, strong_)
 
  end subroutine wall_model_bc_apply_vector
 
  subroutine wall_model_bc_apply_scalar_dev(this, x_d, time, strong, strm)
    class(wall_model_bc_t), intent(inout), target :: this
    type(c_ptr), intent(inout) :: x_d
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout) :: strm
 
    call neko_error("The wall model bc is not applicable to scalar fields.")
 
  end subroutine wall_model_bc_apply_scalar_dev
 
  subroutine wall_model_bc_apply_vector_dev(this, x_d, y_d, z_d, time, &
       strong, strm)
    class(wall_model_bc_t), intent(inout), target :: this
    type(c_ptr), intent(inout) :: x_d
    type(c_ptr), intent(inout) :: y_d
    type(c_ptr), intent(inout) :: z_d
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    logical :: strong_
    type(c_ptr), intent(inout) :: strm
 
    if (present(strong)) then
       strong_ = strong
    else
       strong_ = .true.
    end if
 
    if (.not. present(time)) then
       call neko_error("wall_model_bc_apply_vector_dev: time is required.")
    end if
 
    if (.not. strong_) then
       ! Compute the wall stress using the wall model.
       call this%wall_model%compute( real(time%t, kind=rp), time%tstep)
 
       ! Populate the 3D wall stress field for post-processing.
       call this%wall_model%compute_mag_field()
 
       ! Set the computed stress for application by the underlying Neumann
       ! boundary conditions.
       call this%set_stress(this%wall_model%tau_x, this%wall_model%tau_y, &
            this%wall_model%tau_z)
    end if
 
    ! Either add the stress to the RHS or apply the non-penetration condition
    call this%shear_stress_t%apply_vector_dev(x_d, y_d, z_d, &
         time, strong_, strm)
 
  end subroutine wall_model_bc_apply_vector_dev
 
  subroutine wall_model_bc_init(this, coef, json)
    class(wall_model_bc_t), target, intent(inout) :: this
    type(coef_t), target, intent(in) :: coef
    type(json_file), intent(inout) :: json
    character(len=:), allocatable :: scheme_name, type_name
    real(kind=rp) :: value(3) = [0, 0, 0]
 
    call json_get(json, "scheme_name", scheme_name)
    ! Initialize the shear stress base class.
    call this%shear_stress_t%init_from_components(coef, value)
    ! Partial initialization of the wall model by parsing the JSON.
    call json_get(json, "model", type_name)
    call wall_model_allocator(this%wall_model, type_name)
    call this%wall_model%partial_init(coef, scheme_name, json)
  end subroutine wall_model_bc_init
 
  subroutine wall_model_bc_free(this)
    class(wall_model_bc_t), target, intent(inout) :: this
 
    call this%shear_stress_t%free()
    call this%wall_model%free()
 
    if (allocated(this%wall_model)) then
       deallocate(this%wall_model)
    end if
    nullify(this%user)
 
  end subroutine wall_model_bc_free
 
  subroutine wall_model_bc_finalize(this)
    class(wall_model_bc_t), target, intent(inout) :: this
 
    call this%shear_stress_t%finalize()
    call this%wall_model%finalize(this%facet_node_msk, this%facet)
 
    if (associated(this%user)) then
       call this%wall_model%finalize(this%facet_node_msk, this%facet, &
            this%name, this%user)
    else
       call this%wall_model%finalize(this%facet_node_msk, this%facet, this%name)
    end if
  end subroutine wall_model_bc_finalize
 
end module wall_model_bc