local_interpolation.f90

Go to the documentation of this file.

! Copyright (c) 2021-2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module local_interpolation
  use tensor, only : triple_tensor_product, tnsr3d_el_list, tnsr3d
  use space, only : space_t, gl, gll
  use num_types, only : rp, xp
  use point, only : point_t
  use math, only : abscmp, neko_eps
  use fast3d, only : fd_weights_full, setup_intp
  use utils, only : neko_error
  use field, only : field_t
  use field_list, only : field_list_t
  use device
  use math, only : matinv3, matinv39
  use device_math, only : device_rzero
  use neko_config, only : neko_bcknd_device
  use, intrinsic :: iso_c_binding
  implicit none
  private
 
  type, public :: local_interpolator_t
     type(space_t), pointer :: xh => null()
     integer :: n_points
     real(kind=rp), allocatable :: weights_r(:,:)
     real(kind=rp), allocatable :: weights_s(:,:)
     real(kind=rp), allocatable :: weights_t(:,:)
     type(c_ptr) :: weights_r_d = c_null_ptr
     type(c_ptr) :: weights_s_d = c_null_ptr
     type(c_ptr) :: weights_t_d = c_null_ptr
   contains
     procedure, pass(this) :: init_3arrays => local_interpolator_init_3arrays
     procedure, pass(this) :: init_1array => local_interpolator_init_1array
     procedure, pass(this) :: free => local_interpolator_free
     procedure, pass(this) :: evaluate => local_interpolator_evaluate
     procedure, pass(this) :: compute_weights => &
          local_interpolator_compute_weights
     generic :: init => init_3arrays, init_1array
 
  end type local_interpolator_t
 
contains
 
  subroutine local_interpolator_init_3arrays(this, Xh, r, s, t, n_points)
    class(local_interpolator_t), intent(inout), target :: this
    type(space_t), intent(in), target :: Xh
    integer, intent(in) :: n_points
    real(kind=rp) :: r(n_points), s(n_points), t(n_points)
    integer :: size_weights
    call this%free()
    if ((xh%t .eq. gl) .or. (xh%t .eq. gll)) then
    else
       call neko_error('Unsupported interpolation')
    end if
 
    this%Xh => xh
    this%n_points = n_points
    allocate(this%weights_r(xh%lx, n_points))
    allocate(this%weights_s(xh%ly, n_points))
    allocate(this%weights_t(xh%lz, n_points))
    call this%compute_weights(r, s, t)
    size_weights = xh%lx * n_points
 
    if (neko_bcknd_device .eq. 1) then
       call device_map(this%weights_r, this%weights_r_d, size_weights)
       call device_map(this%weights_s, this%weights_s_d, size_weights)
       call device_map(this%weights_t, this%weights_t_d, size_weights)
       call device_memcpy(this%weights_r, this%weights_r_d,&
            size_weights, host_to_device, sync = .true.)
       call device_memcpy(this%weights_s, this%weights_s_d,&
            size_weights, host_to_device, sync = .true.)
       call device_memcpy(this%weights_t, this%weights_t_d,&
            size_weights, host_to_device, sync = .true.)
    end if
 
  end subroutine local_interpolator_init_3arrays
 
  subroutine local_interpolator_init_1array(this, Xh, rst, n_points)
    class(local_interpolator_t), intent(inout), target :: this
    type(space_t), intent(in), target :: Xh
    integer, intent(in) :: n_points
    real(kind=rp), intent(in) :: rst(3, n_points)
    real(kind=rp), allocatable :: r(:), s(:), t(:)
    integer :: i
 
    if (allocated(r)) deallocate(r)
    allocate(r(n_points))
    if (allocated(s)) deallocate(s)
    allocate(s(n_points))
    if (allocated(t)) deallocate(t)
    allocate(t(n_points))
 
    do i = 1, n_points
       r(i) = rst(1,i)
       s(i) = rst(2,i)
       t(i) = rst(3,i)
    end do
 
    call this%init_3arrays(xh, r, s, t, n_points)
 
    deallocate(r,s,t)
 
  end subroutine local_interpolator_init_1array
 
 
  subroutine local_interpolator_free(this)
    class(local_interpolator_t), intent(inout) :: this
 
    if (associated(this%Xh)) this%Xh => null()
 
    if (allocated(this%weights_r)) then
       if (neko_bcknd_device .eq. 1) then
          call device_unmap(this%weights_r, this%weights_r_d)
       end if
       deallocate(this%weights_r)
    end if
    if (allocated(this%weights_s)) then
       if (neko_bcknd_device .eq. 1) then
          call device_unmap(this%weights_s, this%weights_s_d)
       end if
       deallocate(this%weights_s)
    end if
    if (allocated(this%weights_t)) then
       if (neko_bcknd_device .eq. 1) then
          call device_unmap(this%weights_t, this%weights_t_d)
       end if
       deallocate(this%weights_t)
    end if
  end subroutine local_interpolator_free
 
  subroutine local_interpolator_compute_weights(this, r, s, t)
    class(local_interpolator_t), intent(inout) :: this
    real(kind=rp), intent(in) :: r(:), s(:), t(:)
 
    integer :: N, i, lx
    lx = this%Xh%lx
    n = size(r)
 
    do i = 1, n
       if ((r(i) <= 1.1_rp .and. r(i) >= -1.1_rp) .and. &
            (s(i) <= 1.1_rp .and. s(i) >= -1.1_rp) .and. &
            (t(i) <= 1.1_rp .and. t(i) >= -1.1_rp)) then
          call fd_weights_full(r(i), this%Xh%zg(:, 1), lx-1, 0, &
               this%weights_r(:, i))
          call fd_weights_full(s(i), this%Xh%zg(:, 2), lx-1, 0, &
               this%weights_s(:, i))
          call fd_weights_full(t(i), this%Xh%zg(:, 3), lx-1, 0, &
               this%weights_t(:, i))
       else
          this%weights_r(:,i) = 0.0_rp
          this%weights_s(:,i) = 0.0_rp
          this%weights_t(:,i) = 0.0_rp
       end if
 
    end do
 
  end subroutine local_interpolator_compute_weights
 
  subroutine local_interpolator_evaluate(this, interp_values, el_list, field, &
       nel, on_host)
    class(local_interpolator_t), intent(inout) :: this
    integer, intent(in) :: el_list(this%n_points)
    integer, intent(in) :: nel
    real(kind=rp), intent(inout) :: interp_values(this%n_points)
    real(kind=rp), intent(inout) :: field(this%Xh%lxyz, nel)
    logical, intent(in) :: on_host
 
    call tnsr3d_el_list(interp_values, 1, field, this%Xh%lx, &
         this%weights_r, this%weights_s, this%weights_t, el_list, &
         this%n_points, on_host)
 
  end subroutine local_interpolator_evaluate
 
  subroutine jacobian(jac, rst, x, y, z, n_pts, Xh)
    integer, intent(in) :: n_pts
    real(kind=rp), intent(inout) :: rst(3, n_pts)
    type(space_t), intent(inout) :: xh
    real(kind=rp), intent(inout) :: x(xh%lx, xh%ly, xh%lz, n_pts)
    real(kind=rp), intent(inout) :: y(xh%lx, xh%ly, xh%lz, n_pts)
    real(kind=rp), intent(inout) :: z(xh%lx, xh%ly, xh%lz, n_pts)
    real(kind=rp), intent(out) :: jac(3,3, n_pts)
    real(kind=rp) :: tmp(3)
    real(kind=rp) :: hr(xh%lx, 2), hs(xh%ly, 2), ht(xh%lz, 2)
    integer :: lx, ly, lz, i
    lx = xh%lx
    ly = xh%ly
    lz = xh%lz
 
    do i = 1, n_pts
       ! Weights
       call fd_weights_full(rst(1,i), xh%zg(:,1), lx-1, 1, hr)
       call fd_weights_full(rst(2,i), xh%zg(:,2), ly-1, 1, hs)
       call fd_weights_full(rst(3,i), xh%zg(:,3), lz-1, 1, ht)
 
       ! d(x,y,z)/dr
       call triple_tensor_product(tmp(1), x(:,:,:,i), lx, hr(:,2), hs(:,1), &
            ht(:,1))
       jac(1,1,i) = tmp(1)
       call triple_tensor_product(tmp(1), y(:,:,:,i), lx, hr(:,2), hs(:,1), &
            ht(:,1))
       jac(1,2,i) = tmp(1)
       call triple_tensor_product(tmp(1), z(:,:,:,i), lx, hr(:,2), hs(:,1), &
            ht(:,1))
       jac(1,3,i) = tmp(1)
 
       ! d(x,y,z)/ds
       call triple_tensor_product(tmp, x(:,:,:,i), y(:,:,:,i), z(:,:,:,i), lx, &
            hr(:,1), hs(:,2), ht(:,1))
       jac(2,:,i) = tmp
 
       ! d(x,y,z)/dt
       call triple_tensor_product(tmp, x(:,:,:,i), y(:,:,:,i), z(:,:,:,i), lx, &
            hr(:,1), hs(:,1), ht(:,2))
       jac(3,:,i) = tmp
    end do
 
  end subroutine jacobian
 
  subroutine jacobian_inverse(jacinv, rst, x, y, z, n_pts, Xh)
    integer :: n_pts
    real(kind=rp), intent(inout) :: rst(3, n_pts)
    type(space_t), intent(inout) :: xh
    real(kind=rp), intent(inout) :: x(xh%lx, xh%ly, xh%lz, n_pts)
    real(kind=rp), intent(inout) :: y(xh%lx, xh%ly, xh%lz, n_pts)
    real(kind=rp), intent(inout) :: z(xh%lx, xh%ly, xh%lz, n_pts)
    real(kind=rp), intent(out) :: jacinv(3,3, n_pts)
    real(kind=rp) :: tmp(3,3)
    integer :: i
 
    call jacobian(jacinv, rst, x, y, z, n_pts, xh)
 
    do i = 1, n_pts
       tmp = matinv3(real(jacinv(:, :, 3), xp))
       jacinv(:, :, i) = tmp
    end do
 
  end subroutine jacobian_inverse
 
end module local_interpolation