flow_ic.f90

Go to the documentation of this file.

! Copyright (c) 2021-2026, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
module flow_ic
  use num_types, only : rp
  use logger, only : neko_log, log_size
  use gather_scatter, only : gs_t, gs_op_add
  use neko_config, only : neko_bcknd_device
  use flow_profile, only : blasius_profile, blasius_linear, blasius_cubic, &
       blasius_quadratic, blasius_quartic, blasius_sin, blasius_tanh
  use import_field_utils, only : import_fields
  use device, only : host_to_device, device_to_host, device_sync
  use field, only : field_t
  use utils, only : neko_error, filename_chsuffix, &
       neko_warning, neko_fname_len, extract_fld_file_index
  use coefs, only : coef_t
  use math, only : col2, cfill, cfill_mask, abscmp
  use device_math, only : device_col2
  use field_math, only : field_cfill, field_glmin
  use user_intf, only : user_initial_conditions_intf
  use json_module, only : json_file
  use json_utils, only : json_get, json_get_or_default, &
       json_get_or_lookup_or_default, json_get_or_lookup, &
       json_get_subdict_or_empty
  use point_zone, only : point_zone_t
  use point_zone_registry, only : neko_point_zone_registry
  use fld_file_data, only : fld_file_data_t
  use fld_file, only : fld_file_t
  use file, only : file_t
  use global_interpolation, only : global_interpolation_t
  use interpolation, only : interpolator_t
  use space, only : space_t, gll
  use field_list, only : field_list_t
  use operators, only : rotate_cyc
  use expression, only : expression_eval_static, neko_expr_len
  implicit none
  private
 
  interface set_flow_ic
     module procedure set_flow_ic_int, set_flow_ic_usr, &
          set_compressible_flow_ic_usr
  end interface set_flow_ic
 
  public :: set_flow_ic, set_flow_ic_fld
 
contains
 
  subroutine set_flow_ic_int(u, v, w, p, coef, gs, type, params)
    type(field_t), intent(inout) :: u
    type(field_t), intent(inout) :: v
    type(field_t), intent(inout) :: w
    type(field_t), intent(inout) :: p
    type(coef_t), intent(in) :: coef
    type(gs_t), intent(inout) :: gs
    character(len=*) :: type
    type(json_file), intent(inout) :: params
    real(kind=rp) :: delta
    real(kind=rp), allocatable :: uinf(:)
    real(kind=rp), allocatable :: zone_value(:)
    character(len=:), allocatable :: read_str
    character(len=NEKO_EXPR_LEN), allocatable :: expr_str(:)
 
    select case (trim(type))
    case ('uniform') ! Uniform (Uinf, Vinf, Winf)
 
       call json_get_or_lookup(params, 'value', uinf)
       call set_flow_ic_uniform(u, v, w, uinf)
 
    case ('expression') ! One mathematical expression per velocity component
 
       call json_get(params, 'value', expr_str, filler = '')
       call set_flow_ic_expression(u, v, w, expr_str)
       if (allocated(expr_str)) deallocate(expr_str)
 
    case ('blasius') ! Blasius boundary layer
 
       call json_get_or_lookup(params, 'delta', delta)
       call json_get(params, 'approximation', read_str)
       call json_get_or_lookup(params, 'freestream_velocity', uinf)
 
       call set_flow_ic_blasius(u, v, w, delta, uinf, read_str)
 
    case ('point_zone') ! Point zone initial condition
 
       call json_get_or_lookup(params, 'base_value', uinf)
       call json_get(params, 'zone_name', read_str)
       call json_get_or_lookup(params, 'zone_value', zone_value)
 
       call set_flow_ic_point_zone(u, v, w, uinf, read_str, zone_value)
 
    case ('field') ! Field initial condition (from fld file)
 
       block
         character(len=NEKO_FNAME_LEN) :: fname, mesh_fname
         logical :: interpolate
         type(json_file) :: interp_subdict
 
         call json_get(params, 'file_name', read_str)
         fname = trim(read_str)
 
         call json_get_or_default(params, 'mesh_file_name', read_str, "none")
         mesh_fname = trim(read_str)
 
         call json_get_or_default(params, 'interpolate', interpolate, .false.)
         call json_get_subdict_or_empty(params, "interpolation", interp_subdict)
         call set_flow_ic_fld(u, v, w, p, fname, interpolate, &
              mesh_fname, interp_subdict)
       end block
 
    case default
       call neko_error('Invalid initial condition')
    end select
 
    call set_flow_ic_common(u, v, w, p, coef, gs)
 
  end subroutine set_flow_ic_int
 
  subroutine set_flow_ic_usr(u, v, w, p, coef, gs, user_proc, scheme_name)
    type(field_t), target, intent(inout) :: u
    type(field_t), target, intent(inout) :: v
    type(field_t), target, intent(inout) :: w
    type(field_t), target, intent(inout) :: p
    type(coef_t), intent(in) :: coef
    type(gs_t), intent(inout) :: gs
    procedure(user_initial_conditions_intf) :: user_proc
    character(len=*), intent(in) :: scheme_name
    real(kind=rp) :: um, vm, wm, pm, init
    type(field_list_t) :: fields
 
    call neko_log%message("Type: user")
 
    call fields%init(4)
    call fields%assign_to_field(1, u)
    call fields%assign_to_field(2, v)
    call fields%assign_to_field(3, w)
    call fields%assign_to_field(4, p)
 
    init = -huge(1.0_rp)
    call field_cfill(u, init)
    call field_cfill(v, init)
    call field_cfill(w, init)
    call field_cfill(p, init)
 
    call user_proc(scheme_name, fields)
 
    um = field_glmin(u)
    vm = field_glmin(v)
    wm = field_glmin(w)
    pm = field_glmin(p)
 
    if (abscmp(um, init)) call neko_error('Initial condition did not set u')
    if (abscmp(vm, init)) call neko_error('Initial condition did not set v')
    if (abscmp(wm, init)) call neko_error('Initial condition did not set w')
    if (abscmp(pm, init)) call neko_error('Initial condition did not set p')
 
    call set_flow_ic_common(u, v, w, p, coef, gs)
 
  end subroutine set_flow_ic_usr
 
  subroutine set_compressible_flow_ic_usr(rho, u, v, w, p, coef, gs, &
       user_proc, scheme_name)
    type(field_t), target, intent(inout) :: rho
    type(field_t), target, intent(inout) :: u
    type(field_t), target, intent(inout) :: v
    type(field_t), target, intent(inout) :: w
    type(field_t), target, intent(inout) :: p
    type(coef_t), intent(in) :: coef
    type(gs_t), intent(inout) :: gs
    procedure(user_initial_conditions_intf) :: user_proc
    character(len=*), intent(in) :: scheme_name
    real(kind=rp) :: rhom, um, vm, wm, pm, init
    type(field_list_t) :: fields
 
    call neko_log%message("Type: user (compressible flows)")
 
    call fields%init(5)
    call fields%assign_to_field(1, rho)
    call fields%assign_to_field(2, u)
    call fields%assign_to_field(3, v)
    call fields%assign_to_field(4, w)
    call fields%assign_to_field(5, p)
 
    init = -huge(1.0_rp)
    call field_cfill(rho, init)
    call field_cfill(u, init)
    call field_cfill(v, init)
    call field_cfill(w, init)
    call field_cfill(p, init)
 
    call user_proc(scheme_name, fields)
 
    rhom = field_glmin(rho)
    um = field_glmin(u)
    vm = field_glmin(v)
    wm = field_glmin(w)
    pm = field_glmin(p)
 
    if (abscmp(rhom, init)) call neko_error('Initial condition did not set rho')
    if (abscmp(um, init)) call neko_error('Initial condition did not set u')
    if (abscmp(vm, init)) call neko_error('Initial condition did not set v')
    if (abscmp(wm, init)) call neko_error('Initial condition did not set w')
    if (abscmp(pm, init)) call neko_error('Initial condition did not set p')
 
    call set_flow_ic_common(u, v, w, p, coef, gs)
 
    ! Ensure continuity across elements for initial conditions
    ! These variables are not treated in the common constructor
    call gs%op(p%x, p%dof%size(), gs_op_add)
    call gs%op(rho%x, rho%dof%size(), gs_op_add)
 
    if (neko_bcknd_device .eq. 1) then
       call device_col2(rho%x_d, coef%mult_d, rho%dof%size())
       call device_col2(p%x_d, coef%mult_d, p%dof%size())
    else
       call col2(rho%x, coef%mult, rho%dof%size())
       call col2(p%x, coef%mult, p%dof%size())
    end if
 
  end subroutine set_compressible_flow_ic_usr
 
  subroutine set_flow_ic_common(u, v, w, p, coef, gs)
    type(field_t), intent(inout) :: u
    type(field_t), intent(inout) :: v
    type(field_t), intent(inout) :: w
    type(field_t), intent(inout) :: p
    type(coef_t), intent(in) :: coef
    type(gs_t), intent(inout) :: gs
 
    ! Ensure continuity across elements for initial conditions
    call rotate_cyc(u, v, w, 1, coef)
    call gs%op(u%x, u%dof%size(), gs_op_add)
    call gs%op(v%x, v%dof%size(), gs_op_add)
    call gs%op(w%x, w%dof%size(), gs_op_add)
    call rotate_cyc(u, v, w, 0, coef)
 
    if (neko_bcknd_device .eq. 1) then
       call device_col2(u%x_d, coef%mult_d, u%dof%size())
       call device_col2(v%x_d, coef%mult_d, v%dof%size())
       call device_col2(w%x_d, coef%mult_d, w%dof%size())
    else
       call col2(u%x, coef%mult, u%dof%size())
       call col2(v%x, coef%mult, v%dof%size())
       call col2(w%x, coef%mult, w%dof%size())
    end if
 
  end subroutine set_flow_ic_common
 
  subroutine set_flow_ic_uniform(u, v, w, uinf)
    type(field_t), intent(inout) :: u
    type(field_t), intent(inout) :: v
    type(field_t), intent(inout) :: w
    real(kind=rp), intent(in) :: uinf(3)
    integer :: n, i
    character(len=LOG_SIZE) :: log_buf
 
    call neko_log%message("Type : uniform")
    write (log_buf, '(A, 3(ES12.6, A))') "Value: [", &
         (uinf(i), ", ", i = 1, 2), uinf(3), "]"
    call neko_log%message(log_buf)
 
    call field_cfill(u, uinf(1))
    call field_cfill(v, uinf(2))
    call field_cfill(w, uinf(3))
 
  end subroutine set_flow_ic_uniform
 
  subroutine set_flow_ic_expression(u, v, w, expr)
    type(field_t), target, intent(inout) :: u
    type(field_t), target, intent(inout) :: v
    type(field_t), target, intent(inout) :: w
    character(len=*), intent(in) :: expr(:)
    character(len=1), parameter :: comp(3) = ['u', 'v', 'w']
    type(field_t), pointer :: f
    integer :: i, n
 
    if (size(expr) .ne. 3) then
       call neko_error('The expression initial condition takes exactly ' // &
            'three expressions, one per velocity component')
    end if
 
    call neko_log%message("Type : expression")
    do i = 1, 3
       call neko_log%message(comp(i) // "    : " // trim(expr(i)))
    end do
 
    n = u%dof%size()
 
    do i = 1, 3
       select case (i)
       case (1)
          f => u
       case (2)
          f => v
       case default
          f => w
       end select
 
       call expression_eval_static(expr(i), f%x, n, &
            f%dof%x%x, f%dof%y%x, f%dof%z%x, 'fluid initial condition')
    end do
 
    call u%copy_from(host_to_device, sync = .false.)
    call v%copy_from(host_to_device, sync = .false.)
    call w%copy_from(host_to_device, sync = .true.)
  end subroutine set_flow_ic_expression
 
  subroutine set_flow_ic_blasius(u, v, w, delta, uinf, type)
    type(field_t), intent(inout) :: u
    type(field_t), intent(inout) :: v
    type(field_t), intent(inout) :: w
    real(kind=rp), intent(in) :: delta
    real(kind=rp), intent(in) :: uinf(3)
    character(len=*), intent(in) :: type
    procedure(blasius_profile), pointer :: bla => null()
    integer :: i
    character(len=LOG_SIZE) :: log_buf
 
    call neko_log%message("Type         : blasius")
    write (log_buf, '(A,ES12.6)') "delta        : ", delta
    call neko_log%message(log_buf)
    call neko_log%message("Approximation : " // trim(type))
    write (log_buf, '(A,"[",2(ES12.6,","),ES12.6,"]")') "Value         : ", &
         uinf(1), uinf(2), uinf(3)
    call neko_log%message(log_buf)
 
    select case (trim(type))
    case ('linear')
       bla => blasius_linear
    case ('quadratic')
       bla => blasius_quadratic
    case ('cubic')
       bla => blasius_cubic
    case ('quartic')
       bla => blasius_quartic
    case ('sin')
       bla => blasius_sin
    case ('tanh')
       bla => blasius_tanh
    case default
       call neko_error('Invalid Blasius approximation')
    end select
 
    if ((uinf(1) .gt. 0.0_rp) .and. abscmp(uinf(2), 0.0_rp) &
         .and. abscmp(uinf(3), 0.0_rp)) then
       do i = 1, u%dof%size()
          u%x(i,1,1,1) = bla(u%dof%z%x(i,1,1,1), delta, uinf(1))
          v%x(i,1,1,1) = 0.0_rp
          w%x(i,1,1,1) = 0.0_rp
       end do
    else if (abscmp(uinf(1), 0.0_rp) .and. (uinf(2) .gt. 0.0_rp) &
         .and. abscmp(uinf(3), 0.0_rp)) then
       do i = 1, u%dof%size()
          u%x(i,1,1,1) = 0.0_rp
          v%x(i,1,1,1) = bla(u%dof%x%x(i,1,1,1), delta, uinf(2))
          w%x(i,1,1,1) = 0.0_rp
       end do
    else if (abscmp(uinf(1), 0.0_rp) .and. abscmp(uinf(2), 0.0_rp) &
         .and. (uinf(3) .gt. 0.0_rp)) then
       do i = 1, u%dof%size()
          u%x(i,1,1,1) = 0.0_rp
          v%x(i,1,1,1) = 0.0_rp
          w%x(i,1,1,1) = bla(u%dof%y%x(i,1,1,1), delta, uinf(3))
       end do
    end if
 
    call u%copy_from(host_to_device, sync = .false.)
    call v%copy_from(host_to_device, sync = .false.)
    call w%copy_from(host_to_device, sync = .true.)
 
  end subroutine set_flow_ic_blasius
 
  subroutine set_flow_ic_point_zone(u, v, w, base_value, zone_name, zone_value)
    type(field_t), intent(inout) :: u
    type(field_t), intent(inout) :: v
    type(field_t), intent(inout) :: w
    real(kind=rp), intent(in), dimension(3) :: base_value
    character(len=*), intent(in) :: zone_name
    real(kind=rp), intent(in) :: zone_value(:)
    character(len=LOG_SIZE) :: log_buf
 
    ! Internal variables
    class(point_zone_t), pointer :: zone
    integer :: size
 
    call neko_log%message("Type       : point_zone")
    write (log_buf, '(A,ES12.6)') "Base value : ", base_value
    call neko_log%message(log_buf)
    call neko_log%message("Zone name : " // trim(zone_name))
    write (log_buf, '(A,"[",2(ES12.6,","),ES12.6," ]")') "Value      : ", &
         zone_value(1), zone_value(2), zone_value(3)
    call neko_log%message(log_buf)
 
    size = u%dof%size()
    zone => neko_point_zone_registry%get_point_zone(trim(zone_name))
 
    call cfill(u%x, base_value(1), size)
    call cfill(v%x, base_value(2), size)
    call cfill(w%x, base_value(3), size)
    call cfill_mask(u%x, zone_value(1), size, zone%mask%get(), zone%size)
    call cfill_mask(v%x, zone_value(2), size, zone%mask%get(), zone%size)
    call cfill_mask(w%x, zone_value(3), size, zone%mask%get(), zone%size)
 
    call u%copy_from(host_to_device, sync = .false.)
    call v%copy_from(host_to_device, sync = .false.)
    call w%copy_from(host_to_device, sync = .true.)
 
  end subroutine set_flow_ic_point_zone
 
  subroutine set_flow_ic_fld(u, v, w, p, file_name, &
       interpolate, mesh_file_name, global_interp_subdict)
    type(field_t), target, intent(inout) :: u
    type(field_t), target, intent(inout) :: v
    type(field_t), target, intent(inout) :: w
    type(field_t), target, intent(inout) :: p
    character(len=*), intent(inout) :: file_name
    logical, intent(in) :: interpolate
    character(len=*), intent(inout) :: mesh_file_name
    type(json_file), intent(inout) :: global_interp_subdict
 
    type(field_t), pointer :: us, vs, ws, ps
 
    us => u
    vs => v
    ws => w
    ps => p
 
    if (trim(mesh_file_name) .eq. 'none') then
       call import_fields(file_name, global_interp_subdict, &
            u = us, v = vs, w = ws, p = ps, &
            interpolate = interpolate)
    else
       call import_fields(file_name, global_interp_subdict, mesh_file_name, &
            u = us, v = vs, w = ws, p = ps, &
            interpolate = interpolate)
    end if
 
    nullify(us, vs, ws, ps)
  end subroutine set_flow_ic_fld
 
end module flow_ic